app-text/tree: drop homebrew bash-completion

>=app-shells/bash-completion-2.13.0 installs its own superior one,
so go for that, rather than an old Gentoo-local one.

Bug: https://bugs.gentoo.org/931129
Signed-off-by: Sam James <sam@gentoo.org>

app-text/tree/tree-2.1.1-r1.ebuild

@@ -0,0 +1,30 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs flag-o-matic
+
+DESCRIPTION="Lists directories recursively, and produces an indented listing of files"
+HOMEPAGE="https://mama.indstate.edu/users/ice/tree/ https://gitlab.com/OldManProgrammer/unix-tree"
+SRC_URI="https://gitlab.com/OldManProgrammer/unix-${PN}/-/archive/${PV}/unix-${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~x64-macos"
+
+S=${WORKDIR}/unix-${P}
+
+src_compile() {
+	append-lfs-flags
+	emake \
+		CC="$(tc-getCC)" \
+		CFLAGS="${CFLAGS} ${CPPFLAGS}" \
+		LDFLAGS="${LDFLAGS}"
+}
+
+src_install() {
+	dobin tree
+	doman doc/tree*.1
+	einstalldocs
+}