dev-util/cvise: Bump to 1.8.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-util/cvise/Manifest

@@ -1,2 +1,3 @@
 DIST cvise-1.6.0.tar.gz 243050 BLAKE2B 64c305426dbeaf2e3f3a92a902209b35fcc76b5f5a6d2e48fcc8e24d1325badc0839e70afa1381c6d1412c22a7e9dd41ca03d6ca714fa5082958378cc8863000 SHA512 9d4ee043c34748b600b49ac4f00463b853faff2809f8b581e9b07433a8f3bef4436d0e5d5a9dbff1b2d7c3a8ab1d6d4823e78787eb3e911a683808703b2e24b6
 DIST cvise-1.7.0.tar.gz 248515 BLAKE2B b1a2ca8abc7a09c240a7ae39400e3e60ca641dd0dff4edb34f43d755619ec47bb7a0d25fd6b4461bf80a3be14a63c6e56d0e3e758827ca7c2ef90370aba5d539 SHA512 2e0115355c0ca3cdf593ad4a8d0079ea0ea193234ff4fcae8bdc7c0244cc7b8672025682821279b826fda97f80dc71455390d709836acb671c19772f13156de5
+DIST cvise-1.8.0.tar.gz 248744 BLAKE2B 5196a2bb68c0f9ca1a8219ee0dccae80aa7adac64df5bc4c7601a8ef81048875bfa3d8fb2e8c407cfa8f238739733ad4fbdf08bb14a72ec208d562bd7e69ba84 SHA512 eaef3506f0fcd54953271494ebdbd043c028cd98c4a976bc2d978112c28d27d5d307527db52c2a3f8f153b52430ba9c61ad072dcae5a6e0b9bfb8be844a50bab

dev-util/cvise/cvise-1.8.0.ebuild

@@ -0,0 +1,60 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+: ${CMAKE_MAKEFILE_GENERATOR=ninja}
+PYTHON_COMPAT=( python3_{6..9} )
+inherit cmake llvm python-single-r1
+
+DESCRIPTION="Super-parallel Python port of the C-Reduce"
+HOMEPAGE="https://github.com/marxin/cvise/"
+SRC_URI="
+	https://github.com/marxin/cvise/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="UoI-NCSA"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+LLVM_MAX_SLOT=12
+DEPEND="
+	|| (
+		sys-devel/clang:12
+		sys-devel/clang:11
+		sys-devel/clang:10
+	)
+	<=sys-devel/clang-$(( LLVM_MAX_SLOT + 1 )):="
+RDEPEND="${DEPEND}
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		dev-python/pebble[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+	')
+	dev-util/unifdef
+	sys-devel/flex"
+BDEPEND="
+	${PYTHON_DEPS}
+	sys-devel/flex
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/pebble[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+		')
+	)"
+
+llvm_check_deps() {
+	has_version "sys-devel/clang:${LLVM_SLOT}"
+}
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	llvm_pkg_setup
+}
+
+src_test() {
+	cd "${BUILD_DIR}" || die
+	pytest -vv || die
+}