media-video/mkvtoolnix: Bump to 13.0.0

Package-Manager: Portage-2.3.6, Repoman-2.3.2

media-video/mkvtoolnix/Manifest

@@ -1,2 +1,3 @@
 DIST mkvtoolnix-12.0.0.tar.xz 4480308 SHA256 5c2401d1cc36d8a2d57cb791a5a22f3cda69cb0824c6cee35326b35e7f94b536 SHA512 ccb9c0e368f7fb9cfb2bebaa9f4ef248ccb1aca78136b4e653d32a4319316281d4dd63cfd935c6aa18f1294a17493f61462d13f0552d257b058245019cfe6935 WHIRLPOOL 81616f93eb0a123958628386023bb4aa358d2b8620efa3af6ed6239794b1d5d0d3c9216a59d6b7403ccee0054a4bd81abc39e552634c283d7e2caeb5be3e3f2b
+DIST mkvtoolnix-13.0.0.tar.xz 4486156 SHA256 855e4ea7b0d5a7066dc8db6f8f54a1d9da8ed5616d9c1cea8bc198d4adb57642 SHA512 acf61c9bdb8665678930d820546b0d158cf171c55facecc6cd41b07bb8c70750c26d67b3dfe96fe34020ea9e1917a98498c875b84811fd25a4027bfae70458a7 WHIRLPOOL 2120e10aad78388cf557f88695315e802567c81c113bd891b8ca5af90002ca3afe74542051c994a4440f1afc57129ffc60cf5586d2a9d0c9e81027ceae1cd471
 DIST mkvtoolnix-9.6.0.tar.xz 3810216 SHA256 ebab8dcc59533d248b127d375286eb47880a222ef68ff7a10e1c87d49dbd86bb SHA512 5f469215a10dc865e51f77c43961705d70b1b0e38d70b930e5065d8d89b8379734d9826a63e2cb7ae9cb6723ed8a1d16793df35bad6244cedaa19bc4df49b436 WHIRLPOOL f90056b595402315651754bf4428762a99a665f8ce78d7eb8d6d5ad3bb8bc95e19b130c154c52c2d1281028ebf78c5834abedf068601382a3fcca9ea2c37aa2a

media-video/mkvtoolnix/mkvtoolnix-13.0.0.ebuild

@@ -0,0 +1,99 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit toolchain-funcs versionator multiprocessing autotools
+
+DESCRIPTION="Tools to create, alter, and inspect Matroska files"
+HOMEPAGE="http://www.bunkus.org/videotools/mkvtoolnix"
+SRC_URI="http://www.bunkus.org/videotools/mkvtoolnix/sources/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="debug pch test qt5"
+
+RDEPEND="
+	>=dev-libs/boost-1.46.0:=
+	>=dev-libs/libebml-1.3.3:=
+	dev-libs/jsoncpp:=
+	dev-libs/pugixml
+	media-libs/flac
+	>=media-libs/libmatroska-1.4.4:=
+	media-libs/libogg
+	media-libs/libvorbis
+	sys-apps/file
+	sys-libs/zlib
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtconcurrent:5
+		dev-qt/qtmultimedia:5
+	)
+"
+DEPEND="${RDEPEND}
+	dev-ruby/rake
+	sys-devel/gettext
+	virtual/pkgconfig
+	dev-libs/libxslt
+	app-text/docbook-xsl-stylesheets
+	app-text/po4a
+	test? ( dev-cpp/gtest )
+"
+
+pkg_pretend() {
+	# https://bugs.gentoo.org/419257
+	local ver=4.6
+	local msg="You need at least GCC ${ver}.x for C++11 range-based 'for' and nullptr support."
+	if ! version_is_at_least ${ver} $(gcc-version); then
+		eerror ${msg}
+		die ${msg}
+	fi
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myconf
+
+	if use qt5 ; then
+		# ac/qt5.m4 finds default Qt version set by qtchooser, bug #532600
+		myconf+=(
+			--with-moc=/usr/$(get_libdir)/qt5/bin/moc
+			--with-uic=/usr/$(get_libdir)/qt5/bin/uic
+			--with-rcc=/usr/$(get_libdir)/qt5/bin/rcc
+			--with-qmake=/usr/$(get_libdir)/qt5/bin/qmake
+		)
+	fi
+
+	econf \
+		$(use_enable debug) \
+		$(use_enable qt5 qt) \
+		$(usex pch "" --disable-precompiled-headers) \
+		"${myconf[@]}" \
+		--disable-optimization \
+		--docdir="${EPREFIX}"/usr/share/doc/${PF} \
+		--with-boost="${EPREFIX}"/usr \
+		--with-boost-libdir="${EPREFIX}"/usr/$(get_libdir)
+}
+
+src_compile() {
+	rake V=1 -j$(makeopts_jobs) || die
+}
+
+src_test() {
+	rake V=1 -j$(makeopts_jobs) tests:unit || die
+	rake V=1 -j$(makeopts_jobs) tests:run_unit || die
+}
+
+src_install() {
+	DESTDIR="${D}" rake -j$(makeopts_jobs) install || die
+
+	dodoc AUTHORS ChangeLog README.md
+	doman doc/man/*.1
+}