dev-python/subunit: Bump to 1.4.3

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/subunit/Manifest

@@ -1 +1,2 @@
 DIST subunit-1.4.2.gh.tar.gz 112283 BLAKE2B 195318de120f1fd7cff7173ba056bf5b37983db3527ca7d0f6be7ae9889b99e9c143c92a71d7bd1bada9458b7af402bfbee4153292e58a546e88ca2212ee547b SHA512 21413f0ed26f5f0572249ff4bcf948ea25d9185a1df73421836b9b21e11f323300f93a0275f0d64dc7c81a8e038fa0661a34f818bb038abf79c0637e051bc69e
+DIST subunit-1.4.3.gh.tar.gz 105275 BLAKE2B a203d1fc7851cbfe50c419dd9547353912dac2f49f6182f56f424dd839e635aefa00080d1476e589249286215b53f3393a654a062e4c264ddd8915ee4bc6f929 SHA512 831d435963de9e5e58961b0d97b628ac48855fd956c3618ba53b5e372a967e33a2572755869838f9d5e1ff2b206ffc5b93fecb0738b922d23dfb9c7216efdcf1

dev-python/subunit/subunit-1.4.3.ebuild

@@ -0,0 +1,91 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit distutils-r1 multilib-minimal autotools
+
+DESCRIPTION="A streaming protocol for test results"
+HOMEPAGE="
+	https://launchpad.net/subunit/
+	https://pypi.org/project/python-subunit/
+"
+SRC_URI="
+	https://github.com/testing-cabal/subunit/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0 BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="static-libs test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/testtools-0.9.34[${PYTHON_USEDEP}]
+	dev-python/iso8601[${PYTHON_USEDEP}]
+"
+DEPEND="
+	${RDEPEND}
+	>=dev-libs/check-0.9.11[${MULTILIB_USEDEP}]
+	>=dev-util/cppunit-1.13.2[${MULTILIB_USEDEP}]
+	>=virtual/pkgconfig-0-r1
+	test? (
+		dev-python/fixtures[${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		dev-python/testscenarios[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/subunit-1.4.0-werror.patch"
+)
+
+src_prepare() {
+	mv all_tests.py python/ || die
+
+	distutils-r1_src_prepare
+	eautoreconf
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE=${S} \
+	econf \
+		--enable-shared \
+		$(use_enable static-libs static)
+}
+
+multilib_src_compile() {
+	default
+	multilib_is_native_abi && distutils-r1_src_compile
+}
+
+python_test() {
+	cd python || die
+	"${EPYTHON}" -m testtools.run -v all_tests.test_suite ||
+		die "Testing failed with ${EPYTHON}"
+}
+
+multilib_src_test() {
+	multilib_is_native_abi && distutils-r1_src_test
+}
+
+multilib_src_install() {
+	local targets=(
+		install-include_subunitHEADERS
+		install-pcdataDATA
+		install-libLTLIBRARIES
+	)
+	emake DESTDIR="${D}" "${targets[@]}"
+
+	multilib_is_native_abi && distutils-r1_src_install
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${D}" -name '*.la' -delete || die
+}