net-analyzer/arpon: bump CMake minimum version for CMake 4

Closes: https://bugs.gentoo.org/952092
Signed-off-by: NHOrus <jy6x2b32pie9@yahoo.com>
Closes: https://github.com/gentoo/gentoo/pull/41310
Signed-off-by: Sam James <sam@gentoo.org>

net-analyzer/arpon/arpon-3.0-r1.ebuild

@@ -0,0 +1,43 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+MY_PN="ArpON"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="ArpON (Arp handler inspectiON) is a portable Arp handler"
+HOMEPAGE="https://arpon.sourceforge.io/"
+SRC_URI="https://downloads.sourceforge.net/${PN}/${MY_P}-ng.tar.gz"
+S="${WORKDIR}/${MY_P}-ng"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="
+	dev-libs/libdnet
+	net-libs/libnet:1.1
+	net-libs/libpcap
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.0-CFLAGS.patch
+	"${FILESDIR}"/${PN}-3.0-gentoo.patch
+	"${FILESDIR}"/${PN}-3.0-cmake4.patch
+)
+
+DOCS=( AUTHOR CHANGELOG README THANKS )
+
+src_install() {
+	cmake_src_install
+
+	newinitd "${FILESDIR}"/${PN}.initd-3 ${PN}
+	newconfd "${FILESDIR}"/${PN}.confd-3 ${PN}
+
+	rm -r "${ED}"/var/{log,run} || die
+	mv "${ED}"/usr/share/doc/{${PN},${PF}} || die
+}

net-analyzer/arpon/files/arpon-3.0-cmake4.patch

@@ -0,0 +1,13 @@
+Fix build failures with CMake 4
+https://bugs.gentoo.org/952092
+--- a/CMakeLists.txt	2025-03-26 21:03:28.124742115 +0300
++++ b/CMakeLists.txt	2025-03-26 21:03:56.696915295 +0300
+@@ -40,7 +40,7 @@
+ #                        By default ArpON will be installed to / path.
+ #
+ 
+-cmake_minimum_required(VERSION 2.6)
++cmake_minimum_required(VERSION 3.5...4.0)
+ 
+ project(ArpON C)
+ set(AUTHOR "Andrea Di Pasquale <spikey.it@gmail.com>" INTERNAL "Author")