gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-17 02:39:08 -07:00
Code Issues Projects Releases Wiki Activity

dev-embedded/esptool: add 5.4.0

Browse Source 
Signed-off-by: Martin Dummer <martin.dummer@gmx.net>
Part-of: https://github.com/gentoo/gentoo/pull/46748
Closes: https://github.com/gentoo/gentoo/pull/46748
Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
Martin Dummer
2026-09-03 22:53:29 +02:00
committed by Sam James
parent c54a683d67
commit 53c1943c3b
2 changed files with 78 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-embedded/esptool/Manifest
View File

@@ -2,3 +2,4 @@ DIST esptool-4.10.0.tar.gz 5961194 BLAKE2B 153d57ec90dee53a237dcdf694e6add85d380
DIST esptool-4.12.0.tar.gz 6013292 BLAKE2B 49a6abc7fd6fec84ba3ec08087f7fbf6a27f2adf16fc6b1dffef8ece09b04f84bf128ecbece1cc0f2fde819bb5033d856c282fee40dcd5791bc5054302c28954 SHA512 af8ccb2abdbb0671ff475e61070dd2e18ea676391449ea1333aa60377b5267bb11297d71319dba32712006a7dbeccdebbdea3cd178a670a0e90d2ba7b0481322
DIST esptool-5.3.0.tar.gz 6106512 BLAKE2B bf831cc2b91675dc0bf83eb2042ad86bcfbe36d8fbd8c39c4c855413b157283d31c77b6c84ab4cc262d688cbbe77da109977e5213e32d5d9d05eb7c6aeac8be0 SHA512 b7c357c73f0fe7c24636bdf0752ec4fb9352a2e2fe5021e62d716f6fdee09e5e49780901275dcba7c408d7ebcfe03a4fa8c6b8ca0bf2376988788cc2756e8bbb
DIST esptool-5.3.1.tar.gz 6108667 BLAKE2B 458fd7b5b750ebdcfcce9e2fee3d7f23ba5b8392b7478475a31b33f3dd2ffa88bcaf50cda3aee5ae323ec29f5b1f8cc979c5559195e76e006ef9b64fbdbdf7d9 SHA512 55ffd439b6a2f938c7459d1c570ce2d97518b49626166909d6f8d628bb5a0c0f9352585404e36cc774778348380afeff7f336f86ced80752a5bef30dfd866165
DIST esptool-5.4.0.tar.gz 6168116 BLAKE2B 830a9906fec992ec6b16a6396b0c2f796b1430b478100266f0826a038846565b75a7d395d8571213cd6893e4c6c9368af4682b589cfcf7e4e21b020bdb9bb5a1 SHA512 5c19af9c1052596d262436586834f3dbc78909dd50db0afa0307e935b16e6e278f5795d236d480943646b41d677c09f307e7df6d82ddceaa5e49401b287414d2

77
dev-embedded/esptool/esptool-5.4.0.ebuild Normal file
View File

@@ -0,0 +1,77 @@
# Copyright 2021-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{12..15} )
DISTUTILS_USE_PEP517=setuptools
DISTUTILS_SINGLE_IMPL=1
inherit distutils-r1 eapi9-ver
DESCRIPTION="Serial utility for flashing and interacting with Espressif ESP8266 and ESP32"
HOMEPAGE="https://github.com/espressif/esptool"
SRC_URI="https://github.com/espressif/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64"
RDEPEND="
$(python_gen_cond_dep '
dev-python/bitstring[${PYTHON_USEDEP}]
dev-python/cryptography[${PYTHON_USEDEP}]
dev-python/esp-pylib[${PYTHON_USEDEP}]
dev-python/intelhex[${PYTHON_USEDEP}]
dev-python/pyserial[${PYTHON_USEDEP}]
dev-python/pyyaml[${PYTHON_USEDEP}]
dev-python/reedsolo[${PYTHON_USEDEP}]
dev-python/rich-click[${PYTHON_USEDEP}]
')
"
BDEPEND="
$(python_gen_cond_dep '
dev-python/wheel[${PYTHON_USEDEP}]
')
test? ( $(python_gen_cond_dep '
dev-python/pyelftools[${PYTHON_USEDEP}]
dev-python/pytest[${PYTHON_USEDEP}]
') )
"
EPYTEST_PLUGINS=( )
distutils_enable_tests pytest
EPYTEST_DESELECT=(
# need real hardware connected
test/test_esptool.py
# need network
test/test_uf2_ids.py
)
src_prepare() {
default
# test_espsecure_hsm.py needs setup of a "Soft HSM" or real hardware. remove.
rm test/test_espsecure_hsm.py || die
}
pkg_postinst() {
if ver_replacing -lt 4; then
ewarn "${P} - new 4.x release with breaking changes:"
ewarn " - Public API has been defined by limiting access to internals that have been refactored into multiple source files"
ewarn " - If active security features are detected, the default behavior changes to prevent unintentional bricking"
ewarn " - Flash parameters in an image header can now be changed only when no SHA256 digest is appended"
ewarn " - The ESP8684 alias has been removed, ESP32-C2 has to be used"
ewarn " - Megabit flash sizes have been deprecated, use megabyte units from now on"
fi
if ver_replacing -lt 5; then
ewarn "${P} - new 5.x release with breaking changes:"
ewarn " - The .py suffix is deprecated for the following scripts:"
ewarn " - esptool"
ewarn " - espefuse"
ewarn " - espsecure"
ewarn " - esp_rfc2217_server"
ewarn " - execute-scripts command is removed"
ewarn ""
ewarn "The official announcement of the changes can be found here: https://developer.espressif.com/blog/2025/04/esptool-v5/"
fi
}