mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 04:59:14 -07:00
dev-python/twisted: bump to 19.10.0
* Remove net-misc/openssh version constraint * dev-python/bcrypt is now in DEPEND * Drop all patches which are no longer required * Clean python_test() per previous comment Package is still not compatible with py3.8 but is very close. We should see full support soon. Most tests pass with py3.8. Additionally, dev-python/automat will require a bump to >=0.8.0 in order to support py3.8 within twisted. Bug: https://bugs.gentoo.org/661258 Bug: https://bugs.gentoo.org/662340 Bug: https://bugs.gentoo.org/677226 Bug: https://bugs.gentoo.org/690790 Bug: https://bugs.gentoo.org/683910 Signed-off-by: Aaron Bauman <bman@gentoo.org>
This commit is contained in:
Aaron Bauman
@@ -3,4 +3,5 @@ DIST Twisted-17.1.0.tar.bz2 2997334 BLAKE2B 54bd9813fb265f3561be7bc42a3ca6fc36aa
|
||||
DIST Twisted-17.9.0.tar.bz2 3019243 BLAKE2B a79fade6c84a99303df803ad80f02c63562e7064d5b79db39c08bd0ac9a62d61f1388932b36348aa106aa409a51b2d49dc0eb5b1007ce10f196a34c2f963b8e5 SHA512 0fb854db1044bfdb208594a379a0f8df0193326a9974e193266e82113488d49220648d4a50b323fa144654e94976f5848e1d60efed13ab2668b02cc795720345
|
||||
DIST Twisted-18.4.0.tar.bz2 3037019 BLAKE2B 6fc32f7591493ccc4fe03233307b566899b82cd035ba3329b3faaf950339a6653de697ba3873b37b22f9d7f8a66109694b80496917bf61e79c56eeb7e351ac87 SHA512 3733a6df0196ea580187da3576f5fd08f287437528a4e19813056d019cca213c61b62d879d80a12eef38661d3505ba33aac9a4fc956b19afa6da7d37a6465c83
|
||||
DIST Twisted-18.7.0.tar.bz2 3063847 BLAKE2B a71e7f0f2888eab2849b90405350194091731730e8507172744212b9af73ba440a0c21d5c5a45ae987752c813c07c4dbb06e0e27a8c8e436d7ea6f7c3026137e SHA512 feefa578bc1787648df07e4a53bd6fe29b43c4357472e4fba37526f075be9263e8c671b6781ce6ad3569c1b1666cb702efbee903f597714a749971695018f826
|
||||
DIST Twisted-19.10.0.tar.bz2 3118485 BLAKE2B a0d532b67177aa017e463bf823d7842d4f6ff694f78cd7600865718ffe861023a53ea6a922f7de232133edba26f5255074d7ef277ce8f3bdf02d556ccf4abf41 SHA512 de8d7fd0b2081cebeff68b060c8469377011648bc563a94a993d3530fb007ed42c3a54925c9a10c465ee7a3065cc9108ace12d10d358223fab13494becb9ac4b
|
||||
DIST twisted-regen-cache.gz 911 BLAKE2B ffd3fcda6c67ffe6fd3ef581c8d507548396b66ed0708e9a5c790095e579c0d5f0f71596acf05712989da2ddef2b8d437eca973bc4d80ef8a9fa852915f38305 SHA512 95a9b931c73017d16d1b5e6b41345dddffe62b6af1a8e93b5e40d06d3d15be17b0dd0181c767ffeeb791534d463764ef9e066fa6c2ee2ac4b53c86d1da8fce03
|
||||
|
||||
173
dev-python/twisted/twisted-19.10.0.ebuild
Normal file
173
dev-python/twisted/twisted-19.10.0.ebuild
Normal file
@@ -0,0 +1,173 @@
|
||||
# Copyright 1999-2019 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=7
|
||||
|
||||
PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
|
||||
PYTHON_REQ_USE="threads(+)"
|
||||
|
||||
inherit distutils-r1
|
||||
|
||||
TWISTED_PN="Twisted"
|
||||
TWISTED_P="${TWISTED_PN}-${PV}"
|
||||
TWISTED_RELEASE=$(ver_cut 1-2)
|
||||
|
||||
DESCRIPTION="An asynchronous networking framework written in Python"
|
||||
HOMEPAGE="https://www.twistedmatrix.com/trac/"
|
||||
SRC_URI="https://twistedmatrix.com/Releases/${TWISTED_PN}"
|
||||
SRC_URI="${SRC_URI}/${TWISTED_RELEASE}/${TWISTED_P}.tar.bz2
|
||||
https://dev.gentoo.org/~mgorny/dist/twisted-regen-cache.gz"
|
||||
|
||||
KEYWORDS="~amd64 ~arm ~mips ~s390 ~sh ~amd64-linux ~x86-linux"
|
||||
|
||||
LICENSE="MIT"
|
||||
SLOT="0"
|
||||
IUSE="conch crypt http2 serial +soap test"
|
||||
RESTRICT="!test? ( test )"
|
||||
|
||||
RDEPEND="
|
||||
>=dev-python/attrs-17.4.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/automat-0.3.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/constantly-15.1.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/hyperlink-17.1.1[${PYTHON_USEDEP}]
|
||||
>=dev-python/incremental-16.10.1[${PYTHON_USEDEP}]
|
||||
>=dev-python/pyhamcrest-1.9.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/zope-interface-4.4.2[${PYTHON_USEDEP}]
|
||||
conch? (
|
||||
dev-python/pyasn1[${PYTHON_USEDEP}]
|
||||
>=dev-python/cryptography-1.5.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/appdirs-1.4.0[${PYTHON_USEDEP}]
|
||||
)
|
||||
crypt? (
|
||||
>=dev-python/pyopenssl-16.0.0[${PYTHON_USEDEP}]
|
||||
dev-python/service_identity[${PYTHON_USEDEP}]
|
||||
>=dev-python/idna-0.6[${PYTHON_USEDEP}]
|
||||
)
|
||||
serial? ( >=dev-python/pyserial-3.0[${PYTHON_USEDEP}] )
|
||||
soap? ( $(python_gen_cond_dep 'dev-python/soappy[${PYTHON_USEDEP}]' python2_7) )
|
||||
http2? (
|
||||
>=dev-python/hyper-h2-3.0.0[${PYTHON_USEDEP}]
|
||||
<dev-python/hyper-h2-4.0.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/priority-1.1.0[${PYTHON_USEDEP}]
|
||||
<dev-python/priority-2.0[${PYTHON_USEDEP}]
|
||||
)
|
||||
!dev-python/twisted-core
|
||||
!dev-python/twisted-conch
|
||||
!dev-python/twisted-lore
|
||||
!dev-python/twisted-mail
|
||||
!dev-python/twisted-names
|
||||
!dev-python/twisted-news
|
||||
!dev-python/twisted-pair
|
||||
!dev-python/twisted-runner
|
||||
!dev-python/twisted-words
|
||||
!dev-python/twisted-web
|
||||
"
|
||||
DEPEND="
|
||||
dev-python/bcrypt
|
||||
>=dev-python/incremental-16.10.1[${PYTHON_USEDEP}]
|
||||
test? (
|
||||
dev-python/gmpy[${PYTHON_USEDEP}]
|
||||
dev-python/pyasn1[${PYTHON_USEDEP}]
|
||||
>=dev-python/cryptography-0.9.1[${PYTHON_USEDEP}]
|
||||
>=dev-python/appdirs-1.4.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/pyopenssl-0.13[${PYTHON_USEDEP}]
|
||||
dev-python/service_identity[${PYTHON_USEDEP}]
|
||||
dev-python/idna[${PYTHON_USEDEP}]
|
||||
dev-python/pyserial[${PYTHON_USEDEP}]
|
||||
>=dev-python/constantly-15.1.0[${PYTHON_USEDEP}]
|
||||
net-misc/openssh
|
||||
)
|
||||
"
|
||||
|
||||
S=${WORKDIR}/${TWISTED_P}
|
||||
|
||||
python_prepare_all() {
|
||||
# No allowed tests are garaunteed to work on py3.5 or py3.8
|
||||
if use test ; then
|
||||
# Remove since this is an upstream distribution test for making releases
|
||||
rm src/twisted/python/test/test_release.py || die "rm src/twisted/python/test/test_release.py FAILED"
|
||||
|
||||
# Remove these as they are known to fail -- fix (py2.7 - py3.6)
|
||||
rm src/twisted/conch/test/test_ckeygen.py || die "rm src/twisted/conch/test/test_ckeygen.py FAILED"
|
||||
rm src/twisted/pair/test/test_tuntap.py || die "rm src/twisted/pair/test/test_tuntap.py FAILED"
|
||||
rm src/twisted/test/test_log.py || die "rm src/twisted/test/test_log.py FAILED"
|
||||
|
||||
# This test fails only on py3.7
|
||||
rm src/twisted/internet/test/test_process.py || die " rm src/twisted/internet/test/test_process.py FAILED"
|
||||
fi
|
||||
distutils-r1_python_prepare_all
|
||||
}
|
||||
|
||||
python_test() {
|
||||
distutils_install_for_testing
|
||||
|
||||
# workaround for the eclass not installing the entry points
|
||||
# in the test environment. copy the old 16.3.2 start script
|
||||
# to run the tests with
|
||||
cp "${FILESDIR}"/trial "${TEST_DIR}" || die
|
||||
chmod +x "${TEST_DIR}"/trial || die
|
||||
|
||||
pushd "${TEST_DIR}" > /dev/null || die
|
||||
|
||||
if ! "${TEST_DIR}"/trial twisted; then
|
||||
die "Tests failed with ${EPYTHON}"
|
||||
fi
|
||||
|
||||
if ! "${TEST_DIR}"/trial twisted.test.test_twistd.DaemonizeTests; then
|
||||
die "DaemonizeTests failed with ${EPYTHON}"
|
||||
fi
|
||||
|
||||
if ! "${TEST_DIR}"/trial twisted.test.test_reflect.SafeStrTests; then
|
||||
die "SafeStrTests failed with ${EPYTHON}"
|
||||
fi
|
||||
|
||||
popd > /dev/null || die
|
||||
}
|
||||
|
||||
python_install() {
|
||||
distutils-r1_python_install
|
||||
|
||||
cd "${D%}$(python_get_sitedir)" || die
|
||||
|
||||
# own the dropin.cache so we don't leave orphans
|
||||
touch twisted/plugins/dropin.cache || die
|
||||
|
||||
python_doscript "${WORKDIR}"/twisted-regen-cache
|
||||
}
|
||||
|
||||
python_install_all() {
|
||||
distutils-r1_python_install_all
|
||||
|
||||
newconfd "${FILESDIR}/twistd.conf" twistd
|
||||
newinitd "${FILESDIR}/twistd.init" twistd
|
||||
}
|
||||
|
||||
python_postinst() {
|
||||
twisted-regen-cache || die
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
python_foreach_impl python_postinst
|
||||
|
||||
einfo "Install complete"
|
||||
if use test ; then
|
||||
einfo ""
|
||||
einfo "Some tests have been disabled during testing due to"
|
||||
einfo "known incompatibilities with the emerge sandboxes and/or"
|
||||
einfo "not runnable as the root user."
|
||||
einfo "For a complete test suite run on the code."
|
||||
einfo "Run the tests as a normal user for each python it is installed to."
|
||||
einfo " ie: $ python3.6 /usr/bin/trial twisted"
|
||||
fi
|
||||
}
|
||||
|
||||
python_postrm() {
|
||||
rm -f "${ROOT%}$(python_get_sitedir)/twisted/plugins/dropin.cache" || die
|
||||
}
|
||||
|
||||
pkg_postrm(){
|
||||
# if we're removing the last version, remove the cache file
|
||||
if [[ ! ${REPLACING_VERSIONS} ]]; then
|
||||
python_foreach_impl python_postrm
|
||||
fi
|
||||
}
|
||||
Reference in New Issue
Block a user