mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-24 06:48:18 -07:00
dev-dotnet/dotnet-sdk-bin: bump to 10.0.107
Signed-off-by: Maciej Barć <xgqt@gentoo.org>
This commit is contained in:
Maciej Barć
@@ -4,6 +4,12 @@ DIST dotnet-sdk-10.0.103-linux-musl-arm.tar.gz 233495912 BLAKE2B 7ab9f539a6fda0b
|
||||
DIST dotnet-sdk-10.0.103-linux-musl-arm64.tar.gz 232770769 BLAKE2B 8db278ab3aca0011c847248047c01f9d24587a11dd880079be21df7c8629e20e5fa655e884681101059e4128bce08a514904693c4213b520afc2cc5d8d135b27 SHA512 905fd3a0d53193de10b4b0bd2eef05adda22ad4090cae335f7bbf064e33ca23a754855ec7f2db61703abacf142fbb9f3fb27e1a6fe69eef1f8186fa0fd96ee28
|
||||
DIST dotnet-sdk-10.0.103-linux-musl-x64.tar.gz 240366677 BLAKE2B e4999fd9a230247bb157fcecdd64d8f39be0297cd9adfcb4498d139b574e8eeb76dbfbd887e6072504e4c29dcd07e27c36175c4620b72d503cd026adcaa3854d SHA512 fccb361461d8bf30bfef01d3c69cffaeea9f13724f48805a6ac5a39e9c7de67141b3f9302ccf4c79e3a441c9bda3d4b92ea84817f8d155cfd912f9357c291d6e
|
||||
DIST dotnet-sdk-10.0.103-linux-x64.tar.gz 240189641 BLAKE2B f7030fe9633e710e780be5a9b1b04c9c8a55d69026dee935fd7b61da65094475ed37da4f809228a999bcf2d9ae8859d715bc66859eec1f3b019a2536d5d33df1 SHA512 bab94f13c57b2ac821d4924fe66084be9b44c41761ff7ff64522c8f7aba345659d31258401dcec31cc3cf6ccae1d012623075aca1c9b9165bcfe5ba9abda1c0c
|
||||
DIST dotnet-sdk-10.0.107-linux-arm.tar.gz 233558494 BLAKE2B b8102cdaa78d00f44465a50eef7319d32590e69cec79839eaf912658d2572e0e895ee32170555f5adee9ce1bc470828a49375cca10cb73c718cefd88dcf9d952 SHA512 bd21343295e414f98e70922d112cff6bca2f36f6754825c7852c6f541e5c9c37c8a447dbceef546faed119c2adad62edc03ffc62e75f2324f8436bac6d74876b
|
||||
DIST dotnet-sdk-10.0.107-linux-arm64.tar.gz 232720728 BLAKE2B 4b83b7ff76eae787b3ac9b2333e026d88430975d4b6bd772660271e6ac7187c70474c2dd7a954e558bff4a2901ca8cf5479161ba82b6ed98c9c7018bab320076 SHA512 cf5ecad4078a25d3bb7006b6e49d1e861c71d25f611b609a2d1d326dae9fae73dfaa00290bc05627696d03b395263b1205207df40008219d48d567a35092b4de
|
||||
DIST dotnet-sdk-10.0.107-linux-musl-arm.tar.gz 233596576 BLAKE2B cb6d62bdcbc24aff8f814c805077eb65434f5d2b31d21e5e7892cc5f3a69a8432cac8b5477291044dc561ca083184a536743d29bd039afc3ee8d72920b195905 SHA512 a217197222fc475560d17f85b16b1e3f2682a84871f07d1eb93b8f0c84e93555d0ca0274b8920e0e5b9ad016cf4807a8c0d422dd4eed93ae911400fb30ad5a85
|
||||
DIST dotnet-sdk-10.0.107-linux-musl-arm64.tar.gz 232716924 BLAKE2B 2ee59a039dfca28d5ebe05af35cf75124333c4795c7327a418876e315a4abae428d022842363ce2431f5360d55e22b6f93bb6fbf4e9e2b95799e6b4a730f0e7e SHA512 21083dafe38e70591cf69f8fcf7dd1882aff11966f2f2a162ba9df8dc322904a8b0a1eac198051b2b506086ae066d2fafbe064a2975e5fa4bd9ec3c701edba17
|
||||
DIST dotnet-sdk-10.0.107-linux-musl-x64.tar.gz 240222462 BLAKE2B 8ab32fb035f8f61bab34dd8c3586b0392d72869edd10e73cf258d8c8007e77fd8d0b51ad3d3cfa7d9882597a4eacca4ccd9ae4270ef2cf49a4c5a603ca849ad7 SHA512 c0a033f21a1261304e5f15cfe1e07b6b5eb922247e555fb16797ea227e79aa29cc2aa9f07cc9bb2aeb408cbc6db970877aeca6ec2756b8182afc4b95c86b4cc0
|
||||
DIST dotnet-sdk-10.0.107-linux-x64.tar.gz 240184168 BLAKE2B bb6d2e699f2f5b718171d77c295155b0fa3a5947c524358430234a28504851671dec72276f942e61be3443eee8628eecb28c654661f193efaea70b2632c39853 SHA512 a92ed9b9c81902c54b5e05fa10effcd325976bab2b0b3ab412889723056e9c8b83714b4e956b00f8d2ee316431287b74af398817a6725c406c612146d0ac116a
|
||||
DIST dotnet-sdk-6.0.417-linux-arm.tar.gz 182268907 BLAKE2B fef6b9845d6ba6fd19cbe580f3a868ad48872fc919d119123886a9c975281ed0ab407cfe24421da1fb6bc6cc907c3d693278e0a3ab05f4382c10203095710c6e SHA512 f14d5d24d6611139cff313275599923856307c3afe57d2439eb95e2a89da5fb54fdb6ce5b0d7a243f2d031af4eb0c277ce1914725f8b9dcff4002fcc05489f08
|
||||
DIST dotnet-sdk-6.0.417-linux-arm64.tar.gz 179979647 BLAKE2B 069d6afc216b6ed3ebe3093e933f88af4d51f6a994fc4aeaae85658583a5cabf5e8ab08a0e1cfe53f7f19743769a9183b9e3d64b5464d6d96288ba51d983f261 SHA512 39cada75d9b92797de304987437498d853e1a525b38fa72d0d2949932a092fcf6036b055678686db42682b5b79cdc5ec5995cb01aa186762e081eb1ed38d2364
|
||||
DIST dotnet-sdk-6.0.417-linux-musl-arm.tar.gz 182168816 BLAKE2B b5e149074cb6076e03aaa90545d3916c072e9d1c46f6831633786658424fb8cbf12e72c3f497cb49755696668acb027534606152514f09d3417336aa7eb44eab SHA512 86bff3ab8cecfd16f3d9d26da87b6cbeffd2041d474c56602ee5d77f6883fa64cfe85a19291fdc5afaab438fa5871e366f754b211ece161887f53c637473b661
|
||||
|
||||
175
dev-dotnet/dotnet-sdk-bin/dotnet-sdk-bin-10.0.107.ebuild
Normal file
175
dev-dotnet/dotnet-sdk-bin/dotnet-sdk-bin-10.0.107.ebuild
Normal file
@@ -0,0 +1,175 @@
|
||||
# Copyright 1999-2026 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=9
|
||||
|
||||
SDK_SLOT="$(ver_cut 1-2)"
|
||||
RUNTIME_SLOT="${SDK_SLOT}.7"
|
||||
|
||||
DESCRIPTION=".NET is a free, cross-platform, open-source developer platform"
|
||||
HOMEPAGE="https://dotnet.microsoft.com/
|
||||
https://github.com/dotnet/dotnet/"
|
||||
SRC_URI="
|
||||
amd64? (
|
||||
elibc_glibc? (
|
||||
https://builds.dotnet.microsoft.com/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-x64.tar.gz
|
||||
)
|
||||
elibc_musl? (
|
||||
https://builds.dotnet.microsoft.com/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-musl-x64.tar.gz
|
||||
)
|
||||
)
|
||||
arm? (
|
||||
elibc_glibc? (
|
||||
https://builds.dotnet.microsoft.com/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-arm.tar.gz
|
||||
)
|
||||
elibc_musl? (
|
||||
https://builds.dotnet.microsoft.com/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-musl-arm.tar.gz
|
||||
)
|
||||
)
|
||||
arm64? (
|
||||
elibc_glibc? (
|
||||
https://builds.dotnet.microsoft.com/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-arm64.tar.gz
|
||||
)
|
||||
elibc_musl? (
|
||||
https://builds.dotnet.microsoft.com/dotnet/Sdk/${PV}/dotnet-sdk-${PV}-linux-musl-arm64.tar.gz
|
||||
)
|
||||
)
|
||||
"
|
||||
S="${WORKDIR}"
|
||||
|
||||
LICENSE="MIT"
|
||||
SLOT="${SDK_SLOT}/${RUNTIME_SLOT}"
|
||||
# See bug https://bugs.gentoo.org/932377
|
||||
KEYWORDS="~amd64 ~arm ~arm64"
|
||||
|
||||
# STRIP="llvm-strip" corrupts some executables when using the patchelf hack,
|
||||
# bug https://bugs.gentoo.org/923430
|
||||
RESTRICT="splitdebug strip"
|
||||
|
||||
CURRENT_NUGETS_DEPEND="
|
||||
~dev-dotnet/dotnet-runtime-nugets-${RUNTIME_SLOT}
|
||||
"
|
||||
EXTRA_NUGETS_DEPEND="
|
||||
~dev-dotnet/dotnet-runtime-nugets-6.0.36
|
||||
~dev-dotnet/dotnet-runtime-nugets-7.0.20
|
||||
~dev-dotnet/dotnet-runtime-nugets-8.0.26
|
||||
~dev-dotnet/dotnet-runtime-nugets-9.0.15
|
||||
"
|
||||
NUGETS_DEPEND="
|
||||
${CURRENT_NUGETS_DEPEND}
|
||||
${EXTRA_NUGETS_DEPEND}
|
||||
"
|
||||
|
||||
RDEPEND="
|
||||
app-crypt/mit-krb5:0/0
|
||||
dev-libs/icu
|
||||
|| (
|
||||
dev-util/lttng-ust-compat:0/2.12
|
||||
dev-util/lttng-ust:0/2.12
|
||||
)
|
||||
virtual/zlib:0/1
|
||||
"
|
||||
BDEPEND="
|
||||
dev-util/patchelf
|
||||
"
|
||||
IDEPEND="
|
||||
app-eselect/eselect-dotnet
|
||||
"
|
||||
PDEPEND="
|
||||
${NUGETS_DEPEND}
|
||||
"
|
||||
|
||||
QA_PREBUILT="*"
|
||||
|
||||
MUSL_BAD_LINKS=(
|
||||
apphost
|
||||
createdump
|
||||
dotnet
|
||||
libSystem.Globalization.Native.so
|
||||
libSystem.IO.Compression.Native.so
|
||||
libSystem.Native.so
|
||||
libSystem.Net.Security.Native.so
|
||||
libSystem.Security.Cryptography.Native.OpenSsl.so
|
||||
libclrgc.so
|
||||
libclrjit.so
|
||||
libcoreclr.so
|
||||
libcoreclrtraceptprovider.so
|
||||
libdbgshim.so
|
||||
libhostfxr.so
|
||||
libhostpolicy.so
|
||||
libmscordaccore.so
|
||||
libmscordbi.so
|
||||
libnethost.so
|
||||
singlefilehost
|
||||
)
|
||||
MUSL_BAD_SONAMES=(
|
||||
libc.musl-aarch64.so.1
|
||||
libc.musl-armv7.so.1
|
||||
libc.musl-x86_64.so.1
|
||||
)
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
# Fix musl libc SONAME links, bug https://bugs.gentoo.org/894760
|
||||
if use elibc_musl ; then
|
||||
local musl_bad_link
|
||||
local musl_bad_link_path
|
||||
local musl_bad_soname
|
||||
|
||||
for musl_bad_link in "${MUSL_BAD_LINKS[@]}" ; do
|
||||
while read -r musl_bad_link_path ; do
|
||||
# Skip if file either does not end with ".so" or is not executable.
|
||||
# Using "case" here for easier matching in case we have to add
|
||||
# a special exception.
|
||||
case "${musl_bad_link_path}" in
|
||||
*.so )
|
||||
:
|
||||
;;
|
||||
* )
|
||||
if [[ ! -x "${musl_bad_link_path}" ]] ; then
|
||||
continue
|
||||
fi
|
||||
;;
|
||||
esac
|
||||
|
||||
einfo "Fixing musl libc link for ${musl_bad_link_path}"
|
||||
|
||||
for musl_bad_soname in "${MUSL_BAD_SONAMES[@]}" ; do
|
||||
patchelf --remove-needed "${musl_bad_soname}" "${musl_bad_link_path}" || die
|
||||
done
|
||||
|
||||
patchelf --add-needed libc.so "${musl_bad_link_path}" || die
|
||||
done < <(find . -type f -name "${musl_bad_link}")
|
||||
done
|
||||
fi
|
||||
|
||||
# Remove static libraries, bug https://bugs.gentoo.org/825774
|
||||
find ./packs -type f -name "libnethost.a" -delete || die
|
||||
}
|
||||
|
||||
src_install() {
|
||||
local dest="opt/${PN}-${SDK_SLOT}"
|
||||
dodir "${dest%/*}"
|
||||
|
||||
# Create a magic workloads file, bug #841896
|
||||
local featureband="$(( $(ver_cut 3) / 100 * 100 ))" # e.g. 404 -> 400
|
||||
local workloads="metadata/workloads/${SDK_SLOT}.${featureband}"
|
||||
|
||||
mkdir -p "${S}/${workloads}" || die
|
||||
touch "${S}/${workloads}/userlocal" || die
|
||||
|
||||
mv "${S}" "${ED}/${dest}" || die
|
||||
mkdir "${S}" || die
|
||||
|
||||
fperms 0755 "/${dest}"
|
||||
dosym "../../${dest}/dotnet" "/usr/bin/dotnet-bin-${SDK_SLOT}"
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
eselect dotnet update ifunset
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
eselect dotnet update ifunset
|
||||
}
|
||||
Reference in New Issue
Block a user