mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 04:59:14 -07:00
sys-cluster/ceph: Remove old
Copyright: Sony Interactive Entertainment Inc. Package-Manager: Portage-2.3.65, Repoman-2.3.12 Signed-off-by: Patrick McLean <chutzpah@gentoo.org>
This commit is contained in:
Patrick McLean
committed by
Patrick McLean
Patrick McLean
parent
6d0a3b797e
commit
53199345ac
@@ -2,5 +2,4 @@ DIST ceph-12.2.11.tar.gz 79009034 BLAKE2B d8b1c188fe39603e90511eb436100ba14c0a9c
|
||||
DIST ceph-12.2.12.tar.gz 77467762 BLAKE2B a5224432121db9ef49c1e22771d847399df2f7881cd9c2e185eca12096efb79d21578659d248eb5bae678924983d57452d370e23ab7e78663764d7bea834a461 SHA512 e694c9a8c1f9836c08fb74b54423bdc16d4900252e34643c56cf1a615d4dacddfb13df06a6a9f68bb9d438f5f07069ed358f9fa4b5a362640a3046f9c7722dcc
|
||||
DIST ceph-12.2.8.tar.gz 77243685 BLAKE2B 37c34396a0c276b8d79735e14934ac70da024822c2a060061531c234e03e5d41aad6c41dc64b05c2ce47f03287d0cae9ef9bed67e4a0861b6380c8ce1de4ea69 SHA512 91c5c11aaeef701b3e31c9f8a1192b6b79fd34f3b96c61595c65173c98bfce0009c5b7c9b29764f5e4d4b1f5ac2ca7109fed5ae598c176aba717a34a132fabac
|
||||
DIST ceph-13.2.5.tar.gz 91006057 BLAKE2B 68551e2f54d78aff7b0e9ec3c62e6a3394dd7c23e80924a5b400cd9666a05a42e5f22445deee4040f1b78201c6a6660b283109878d4c92d845821bff831c8a5e SHA512 6daea524523f829e725609328ea71f416b2c3a9530fa8956720a7bc69dc08e55a169654f500704579dc9ba693f04eedd7e04614c0850e9ab1169cd45f19039f8
|
||||
DIST ceph-14.2.0.tar.gz 118882504 BLAKE2B e650d99dceb11c7b035480c8cdd9f63ee4a5f81ffea27988e180a2956433e3e4b34e496a73bf5992c428eff859311c623b92a6f006eb694ebf928d8204dc9b06 SHA512 c86a335714fd5678988133ec0e60cb10cd948250a133c073d1ed055c5bba232fa6f1e102dd7fcb0c70b37a07c9c2d1220d4a1713720e4dcab9659152ee577480
|
||||
DIST ceph-14.2.1.tar.gz 117111511 BLAKE2B c00181223c6e02e7fe696ed4226f1751eca48e799f8b5377a06621eb3300f81b58dc20f325b455df04fcbd0c28b981fae1cfc778a8d69414247ddd206d0c6175 SHA512 fccde341344c721fbfc7f7cb73db4f65933d7fcacc9495398b55b37d1e208f0bad0cd78a4da08a3b5e26cca3175e7707f7dfb76fae5aa094f58afaed8603c866
|
||||
|
||||
@@ -1,344 +0,0 @@
|
||||
# Copyright 1999-2019 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=7
|
||||
PYTHON_COMPAT=( python{2_7,3_{5,6,7}} )
|
||||
DISTUTILS_OPTIONAL=1
|
||||
|
||||
inherit check-reqs bash-completion-r1 cmake-utils distutils-r1 flag-o-matic \
|
||||
multiprocessing python-r1 udev user readme.gentoo-r1 toolchain-funcs \
|
||||
systemd
|
||||
|
||||
if [[ ${PV} == *9999* ]]; then
|
||||
inherit git-r3
|
||||
EGIT_REPO_URI="https://github.com/ceph/ceph.git"
|
||||
SRC_URI=""
|
||||
else
|
||||
SRC_URI="https://download.ceph.com/tarballs/${P}.tar.gz"
|
||||
KEYWORDS="~amd64 ~arm64 ~x86"
|
||||
fi
|
||||
|
||||
DESCRIPTION="Ceph distributed filesystem"
|
||||
HOMEPAGE="https://ceph.com/"
|
||||
|
||||
LICENSE="LGPL-2.1 CC-BY-SA-3.0 GPL-2 BSD Boost-1.0 MIT"
|
||||
SLOT="0"
|
||||
|
||||
CPU_FLAGS_X86=(sse{,2,3,4_1,4_2} ssse3)
|
||||
|
||||
IUSE="babeltrace cephfs dpdk fuse grafana jemalloc kerberos ldap libressl"
|
||||
IUSE+=" lttng +mgr numa rabbitmq +radosgw +ssl static-libs +system-boost"
|
||||
IUSE+=" systemd +tcmalloc test xfs zfs"
|
||||
IUSE+=" $(printf "cpu_flags_x86_%s\n" ${CPU_FLAGS_X86[@]})"
|
||||
|
||||
COMMON_DEPEND="
|
||||
virtual/libudev:=
|
||||
app-arch/bzip2:=[static-libs?]
|
||||
app-arch/lz4:=[static-libs?]
|
||||
app-arch/snappy:=[static-libs?]
|
||||
app-arch/zstd:=[static-libs?]
|
||||
app-misc/jq:=[static-libs?]
|
||||
dev-libs/crypto++:=[static-libs?]
|
||||
dev-libs/leveldb:=[snappy,static-libs?,tcmalloc?]
|
||||
dev-libs/libaio:=[static-libs?]
|
||||
dev-libs/libxml2:=[static-libs?]
|
||||
dev-libs/nss:=
|
||||
sys-auth/oath-toolkit:=
|
||||
sys-apps/keyutils:=[static-libs?]
|
||||
sys-apps/util-linux:=[static-libs?]
|
||||
sys-libs/ncurses:0=[static-libs?]
|
||||
sys-libs/zlib:=[static-libs?]
|
||||
babeltrace? ( dev-util/babeltrace )
|
||||
ldap? ( net-nds/openldap:=[static-libs?] )
|
||||
lttng? ( dev-util/lttng-ust:= )
|
||||
fuse? ( sys-fs/fuse:0=[static-libs?] )
|
||||
kerberos? ( virtual/krb5 )
|
||||
rabbitmq? ( net-libs/rabbitmq-c:=[static-libs?] )
|
||||
ssl? (
|
||||
!libressl? ( dev-libs/openssl:=[static-libs?] )
|
||||
libressl? ( dev-libs/libressl:=[static-libs?] )
|
||||
)
|
||||
xfs? ( sys-fs/xfsprogs:=[static-libs?] )
|
||||
zfs? ( sys-fs/zfs:=[static-libs?] )
|
||||
radosgw? (
|
||||
dev-libs/expat:=[static-libs?]
|
||||
!libressl? (
|
||||
dev-libs/openssl:=[static-libs?]
|
||||
net-misc/curl:=[curl_ssl_openssl,static-libs?]
|
||||
)
|
||||
libressl? (
|
||||
dev-libs/libressl:=[static-libs?]
|
||||
net-misc/curl:=[curl_ssl_libressl,static-libs?]
|
||||
)
|
||||
)
|
||||
system-boost? (
|
||||
~dev-libs/boost-1.67:=[threads,context,python,static-libs?,${PYTHON_USEDEP}]
|
||||
)
|
||||
jemalloc? ( dev-libs/jemalloc:=[static-libs?] )
|
||||
!jemalloc? ( >=dev-util/google-perftools-2.4:=[static-libs?] )
|
||||
${PYTHON_DEPS}
|
||||
"
|
||||
DEPEND="${COMMON_DEPEND}
|
||||
amd64? ( dev-lang/yasm )
|
||||
x86? ( dev-lang/yasm )
|
||||
dev-python/cython[${PYTHON_USEDEP}]
|
||||
dev-python/sphinx
|
||||
dev-util/cunit
|
||||
test? (
|
||||
dev-python/coverage[${PYTHON_USEDEP}]
|
||||
dev-python/virtualenv[${PYTHON_USEDEP}]
|
||||
sys-apps/grep[pcre]
|
||||
sys-fs/btrfs-progs
|
||||
)
|
||||
"
|
||||
BDEPEND=" app-arch/cpio
|
||||
>=dev-util/cmake-3.5.0
|
||||
dev-util/gperf
|
||||
dev-util/valgrind
|
||||
sys-apps/which
|
||||
sys-devel/bc
|
||||
virtual/pkgconfig
|
||||
"
|
||||
RDEPEND="${COMMON_DEPEND}
|
||||
net-misc/socat
|
||||
sys-apps/gptfdisk
|
||||
sys-block/parted
|
||||
sys-fs/cryptsetup
|
||||
sys-fs/lvm2[-device-mapper-only(-)]
|
||||
!<sys-apps/openrc-0.26.3
|
||||
dev-python/bcrypt[${PYTHON_USEDEP}]
|
||||
dev-python/cherrypy[${PYTHON_USEDEP}]
|
||||
dev-python/flask[${PYTHON_USEDEP}]
|
||||
dev-python/jinja[${PYTHON_USEDEP}]
|
||||
dev-python/pecan[${PYTHON_USEDEP}]
|
||||
dev-python/prettytable[${PYTHON_USEDEP}]
|
||||
dev-python/pyopenssl[${PYTHON_USEDEP}]
|
||||
dev-python/requests[${PYTHON_USEDEP}]
|
||||
dev-python/werkzeug[${PYTHON_USEDEP}]
|
||||
"
|
||||
REQUIRED_USE="
|
||||
${PYTHON_REQUIRED_USE}
|
||||
|| ( $(python_gen_useflags 'python3*') )
|
||||
?? ( jemalloc tcmalloc )
|
||||
rabbitmq? ( radosgw )
|
||||
"
|
||||
|
||||
# the tests need root access
|
||||
RESTRICT="test? ( userpriv )"
|
||||
|
||||
# distribution tarball does not include everything needed for tests
|
||||
RESTRICT+=" test"
|
||||
|
||||
# false positives unless all USE flags are on
|
||||
CMAKE_WARN_UNUSED_CLI="no"
|
||||
|
||||
UNBUNDLE_LIBS=(
|
||||
src/erasure-code/jerasure/jerasure
|
||||
src/erasure-code/jerasure/gf-complete
|
||||
)
|
||||
|
||||
PATCHES=(
|
||||
"${FILESDIR}/ceph-12.2.0-use-provided-cpu-flag-values.patch"
|
||||
"${FILESDIR}/ceph-14.2.0-cflags.patch"
|
||||
"${FILESDIR}/ceph-12.2.4-boost-build-none-options.patch"
|
||||
"${FILESDIR}/ceph-13.2.0-cflags.patch"
|
||||
"${FILESDIR}/ceph-14.2.0-mgr-python-version.patch"
|
||||
"${FILESDIR}/ceph-14.2.0-no-virtualenvs.patch"
|
||||
"${FILESDIR}/ceph-13.2.2-dont-install-sysvinit-script.patch"
|
||||
"${FILESDIR}/ceph-14.2.0-dpdk-cflags.patch"
|
||||
"${FILESDIR}/ceph-14.2.0-link-crc32-statically.patch"
|
||||
"${FILESDIR}/ceph-14.2.0-cython-0.29.patch"
|
||||
"${FILESDIR}/ceph-14.2.1-ncurses-tinfo.patch"
|
||||
)
|
||||
|
||||
# dpdk and ninja don't get along
|
||||
CMAKE_MAKEFILE_GENERATOR="emake"
|
||||
|
||||
check-reqs_export_vars() {
|
||||
if use amd64; then
|
||||
CHECKREQS_DISK_BUILD="12G"
|
||||
CHECKREQS_DISK_USR="460M"
|
||||
else
|
||||
CHECKREQS_DISK_BUILD="1400M"
|
||||
CHECKREQS_DISK_USR="450M"
|
||||
fi
|
||||
|
||||
export CHECKREQS_DISK_BUILD CHECKREQS_DISK_USR
|
||||
}
|
||||
|
||||
user_setup() {
|
||||
enewgroup ceph ${CEPH_GID}
|
||||
enewuser ceph "${CEPH_UID:--1}" -1 /var/lib/ceph ceph
|
||||
}
|
||||
|
||||
pkg_pretend() {
|
||||
check-reqs_export_vars
|
||||
check-reqs_pkg_pretend
|
||||
}
|
||||
|
||||
pkg_setup() {
|
||||
python_setup 'python3*'
|
||||
check-reqs_export_vars
|
||||
check-reqs_pkg_setup
|
||||
user_setup
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
cmake-utils_src_prepare
|
||||
|
||||
if use system-boost; then
|
||||
eapply "${FILESDIR}/ceph-14.2.0-boost-sonames.patch"
|
||||
fi
|
||||
|
||||
sed -i -r "s:DESTINATION .+\\):DESTINATION $(get_bashcompdir)\\):" \
|
||||
src/bash_completion/CMakeLists.txt || die
|
||||
|
||||
# remove tests that need root access
|
||||
rm src/test/cli/ceph-authtool/cap*.t || die
|
||||
|
||||
#rm -rf "${UNBUNDLE_LIBS[@]}"
|
||||
}
|
||||
|
||||
ceph_src_configure() {
|
||||
local flag
|
||||
local mycmakeargs=(
|
||||
-DWITH_BABELTRACE=$(usex babeltrace)
|
||||
-DWITH_CEPHFS=$(usex cephfs)
|
||||
-DWITH_DPDK=$(usex dpdk)
|
||||
-DWITH_FUSE=$(usex fuse)
|
||||
-DWITH_LTTNG=$(usex lttng)
|
||||
-DWITH_GSSAPI=$(usex kerberos)
|
||||
-DWITH_GRAFANA=$(usex grafana)
|
||||
-DWITH_MGR=$(usex mgr)
|
||||
-DWITH_MGR_DASHBOARD_FRONTEND=NO
|
||||
-DWITH_NUMA=$(usex numa)
|
||||
-DWITH_OPENLDAP=$(usex ldap)
|
||||
-DWITH_RADOSGW=$(usex radosgw)
|
||||
-DWITH_RADOSGW_AMQP_ENDPOINT=$(usex rabbitmq)
|
||||
-DWITH_SSL=$(usex ssl)
|
||||
-DWITH_SYSTEMD=$(usex systemd)
|
||||
-DWITH_TESTS=$(usex test)
|
||||
-DWITH_XFS=$(usex xfs)
|
||||
-DWITH_ZFS=$(usex zfs)
|
||||
-DENABLE_SHARED=$(usex static-libs '' 'ON' 'OFF')
|
||||
-DALLOCATOR=$(usex tcmalloc 'tcmalloc' "$(usex jemalloc 'jemalloc' 'libc')")
|
||||
-DWITH_SYSTEM_BOOST=$(usex system-boost)
|
||||
-DBOOST_J=$(makeopts_jobs)
|
||||
-DWITH_RDMA=no
|
||||
-DWITH_TBB=no
|
||||
-DSYSTEMD_UNITDIR=$(systemd_get_systemunitdir)
|
||||
-DEPYTHON_VERSION="${EPYTHON#python}"
|
||||
-DCMAKE_INSTALL_DOCDIR="${EPREFIX}/usr/share/doc/${PN}"
|
||||
-DCMAKE_INSTALL_SYSCONFDIR="${EPREFIX}/etc"
|
||||
-Wno-dev
|
||||
)
|
||||
if use amd64 || use x86; then
|
||||
for flag in ${CPU_FLAGS_X86[@]}; do
|
||||
mycmakeargs+=("$(usex cpu_flags_x86_${flag} "-DHAVE_INTEL_${flag^^}=1")")
|
||||
done
|
||||
fi
|
||||
|
||||
rm -f "${BUILD_DIR:-${S}}/CMakeCache.txt"
|
||||
cmake-utils_src_configure
|
||||
|
||||
# bug #630232
|
||||
sed -i "s:\"${T//:\\:}/${EPYTHON}/bin/python\":\"${PYTHON}\":" \
|
||||
"${BUILD_DIR:-${S}}"/include/acconfig.h \
|
||||
|| die "sed failed"
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
ceph_src_configure
|
||||
}
|
||||
|
||||
python_compile() {
|
||||
local CMAKE_USE_DIR="${S}"
|
||||
ceph_src_configure
|
||||
|
||||
pushd "${BUILD_DIR}/src/pybind" >/dev/null || die
|
||||
emake VERBOSE=1 clean
|
||||
emake VERBOSE=1 all
|
||||
|
||||
# python modules are only compiled with "make install" so we need to do this to
|
||||
# prevent doing a bunch of compilation in src_install
|
||||
DESTDIR="${T}" emake VERBOSE=1 install
|
||||
popd >/dev/null || die
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
cmake-utils_src_make VERBOSE=1 all
|
||||
|
||||
# we have to do this here to prevent from building everything multiple times
|
||||
python_copy_sources
|
||||
python_foreach_impl python_compile
|
||||
}
|
||||
|
||||
src_test() {
|
||||
make check || die "make check failed"
|
||||
}
|
||||
|
||||
python_install() {
|
||||
local CMAKE_USE_DIR="${S}"
|
||||
pushd "${BUILD_DIR}/src/pybind" >/dev/null || die
|
||||
DESTDIR="${ED}" emake install
|
||||
popd >/dev/null || die
|
||||
}
|
||||
|
||||
src_install() {
|
||||
cmake-utils_src_install
|
||||
python_foreach_impl python_install
|
||||
|
||||
find "${ED}" -name '*.la' -type f -delete || die
|
||||
|
||||
exeinto /usr/$(get_libdir)/ceph
|
||||
newexe "${BUILD_DIR}/bin/init-ceph" init-ceph
|
||||
|
||||
insinto /etc/logrotate.d/
|
||||
newins "${FILESDIR}"/ceph.logrotate-r2 ${PN}
|
||||
|
||||
keepdir /var/lib/${PN}{,/tmp} /var/log/${PN}/stat
|
||||
|
||||
fowners -R ceph:ceph /var/lib/ceph /var/log/ceph
|
||||
|
||||
newinitd "${FILESDIR}/rbdmap.initd" rbdmap
|
||||
newinitd "${FILESDIR}/${PN}.initd-r11" ${PN}
|
||||
newconfd "${FILESDIR}/${PN}.confd-r5" ${PN}
|
||||
|
||||
insinto /etc/sysctl.d
|
||||
newins "${FILESDIR}"/sysctld 90-${PN}.conf
|
||||
|
||||
use tcmalloc && newenvd "${FILESDIR}"/envd-tcmalloc 99${PN}-tcmalloc
|
||||
|
||||
# units aren't installed by the build system unless systemd is enabled
|
||||
# so no point installing these with the USE flag disabled
|
||||
if use systemd; then
|
||||
systemd_install_serviced "${FILESDIR}/ceph-mds_at.service.conf" \
|
||||
"ceph-mds@.service"
|
||||
|
||||
systemd_install_serviced "${FILESDIR}/ceph-osd_at.service.conf" \
|
||||
"ceph-osd@.service"
|
||||
fi
|
||||
|
||||
udev_dorules udev/*.rules
|
||||
|
||||
readme.gentoo_create_doc
|
||||
|
||||
python_setup 'python3*'
|
||||
|
||||
# bug #630232
|
||||
sed -i -r "s:${T//:/\\:}/${EPYTHON}:/usr:" "${ED}"/usr/bin/ceph \
|
||||
|| die "sed failed"
|
||||
|
||||
python_fix_shebang "${ED}"/usr/{,s}bin/
|
||||
|
||||
# python_fix_shebang apparently is not idempotent
|
||||
sed -i -r 's:(/usr/lib/python-exec/python[0-9]\.[0-9]/python)[0-9]\.[0-9]:\1:' \
|
||||
"${ED}"/usr/sbin/{mount.*,ceph-volume{,-systemd}} || die "sed failed"
|
||||
|
||||
local -a rados_classes=( "${D}/usr/$(get_libdir)/rados-classes"/* )
|
||||
dostrip -x "${rados_classes[@]#${D}}"
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
readme.gentoo_print_elog
|
||||
}
|
||||
Reference in New Issue
Block a user