net-libs/glib-networking: bump to 2.60.3

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

net-libs/glib-networking/Manifest

@@ -1 +1,2 @@
 DIST glib-networking-2.58.0.tar.xz 172632 BLAKE2B 2b1e478ecac7ffb25f0d4e319fc71f7a0c6d9bd4181a5e8abb310d11774491312b0ff1c81b9d8b383ae0b236ece89253d6bd222740199d816c94ea557b4e3511 SHA512 d9cfd97ef9905eceb1f807a7d18c648fcf148214bf3fc55c718c5bcd6fb0afc429ab5b7bf72e83cf959d5ce7f145ce17952c1288d4225cc99d3c6ad66e4494ff
+DIST glib-networking-2.60.3.tar.xz 185132 BLAKE2B 8bbe2b8afb779bac99bd554c384bdbf9e197e9b71dc6fe213cdd4352d95ce19d1c9786747ba5c721fc35bdda3e1325e9620c1ef15ca1fa1e294aad9ab3f9a4bc SHA512 06a50aee1a563f5e992549e963d3980b02c9068976a244ce4a84eb0aca064b2ab7e8d50e3ef26dbd0d8d5edbddc82c5ce83d4a93bfaa0822b79465f0d3b8609f

net-libs/glib-networking/glib-networking-2.60.3.ebuild

@@ -0,0 +1,72 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org gnome2-utils meson multilib-minimal xdg
+
+DESCRIPTION="Network-related giomodules for glib"
+HOMEPAGE="https://git.gnome.org/browse/glib-networking/"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+IUSE="+gnome +libproxy +ssl test"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+RDEPEND="
+	>=dev-libs/glib-2.55.1:2[${MULTILIB_USEDEP}]
+	libproxy? ( >=net-libs/libproxy-0.4.11-r1:=[${MULTILIB_USEDEP}] )
+	>=net-libs/gnutls-3.4.6:=[${MULTILIB_USEDEP}]
+	ssl? ( app-misc/ca-certificates )
+	gnome? ( gnome-base/gsettings-desktop-schemas )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	>=sys-devel/gettext-0.19.8
+	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
+	test? ( sys-apps/dbus )
+"
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Dgnutls=enabled
+		-Dopenssl=disabled
+		$(meson_feature libproxy)
+		$(meson_feature gnome gnome_proxy)
+		-Dinstalled_tests=false
+		-Dstatic_modules=false
+	)
+	meson_src_configure
+}
+
+multilib_src_compile() {
+	meson_src_compile
+}
+
+multilib_src_install() {
+	meson_src_install
+}
+
+multilib_src_test() {
+	dbus-run-session meson test -C "${BUILD_DIR}" || die 'tests failed'
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	multilib_pkg_postinst() {
+		gnome2_giomodule_cache_update \
+			|| die "Update GIO modules cache failed (for ${ABI})"
+	}
+	multilib_foreach_abi multilib_pkg_postinst
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+
+	multilib_pkg_postrm() {
+		gnome2_giomodule_cache_update \
+			|| die "Update GIO modules cache failed (for ${ABI})"
+	}
+	multilib_foreach_abi multilib_pkg_postrm
+}