mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-09 18:47:16 -08:00
www-client/opera: automated bump (127.0.5778.14)
Signed-off-by: Matt Jolly <kangie@gentoo.org>
This commit is contained in:
Matt Jolly
@@ -1 +1,2 @@
|
||||
DIST opera-stable_126.0.5750.59_amd64.deb 131431736 BLAKE2B 7f713e0533ebc314b1c404f48a7045108bd8eeb3719cc3c3342cd39634952bef107ce0a4da1ad07ad9e029e2ebdbf0c3cc4b3290f55247f6de630d45cbffb9b5 SHA512 58fe05613efa06d4a0df659338c90966c7789d3dfe0d41613181334451b263b4b35f1ec27bd2a4f5a29a817d4ec119f60182131779eb0cf96f40ea070b280032
|
||||
DIST opera-stable_127.0.5778.14_amd64.deb 131854360 BLAKE2B b41cf4b172c4bacf24261fc4792b1f9ccce0b271752360a0130fbaea77b865e867aefa77339666e9a9b61bf2485c59bb88e48e13695194a48c000353874d4606 SHA512 ed742c9b66de7be6f84af304624611bc697045cb17158acd819f850cc6cf2691bee92d028a708ccc59ee691b6ed2f2c0fc9ee882367f1a69264ab228189266bc
|
||||
|
||||
@@ -0,0 +1,143 @@
|
||||
# Copyright 1999-2026 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
CHROMIUM_LANGS="
|
||||
bg bn ca cs da de el en-GB en-US es-419 es fil fi fr hi hr hu id
|
||||
it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
|
||||
zh-CN zh-TW
|
||||
"
|
||||
|
||||
inherit chromium-2 pax-utils unpacker xdg
|
||||
|
||||
DESCRIPTION="A fast and secure web browser"
|
||||
HOMEPAGE="https://www.opera.com/"
|
||||
|
||||
SRC_URI_BASE=(
|
||||
"https://download1.operacdn.com/pub/${PN}"
|
||||
"https://download2.operacdn.com/pub/${PN}"
|
||||
"https://download3.operacdn.com/pub/${PN}"
|
||||
"https://download4.operacdn.com/pub/${PN}"
|
||||
)
|
||||
|
||||
if [[ ${PN} == opera ]]; then
|
||||
MY_PN=${PN}-stable
|
||||
SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
|
||||
else
|
||||
MY_PN=${PN}
|
||||
fi
|
||||
|
||||
# Commit ref from `strings libffmpeg.so | grep -F "FFmpeg version"` matches this Chromium version
|
||||
# or use Chromicler to handle bumps.
|
||||
# Does not _need_ to be updated for every new version of Opera, only when it breaks.
|
||||
CHROMIUM_VERSION="143"
|
||||
SRC_URI="${SRC_URI_BASE[*]/%//${PV}/linux/${MY_PN}_${PV}_amd64.deb}"
|
||||
S=${WORKDIR}
|
||||
|
||||
LICENSE="OPERA-2018"
|
||||
SLOT="0"
|
||||
KEYWORDS="-* ~amd64"
|
||||
IUSE="+ffmpeg-chromium +proprietary-codecs +suid qt6"
|
||||
RESTRICT="bindist mirror strip"
|
||||
|
||||
RDEPEND="
|
||||
>=app-accessibility/at-spi2-core-2.46.0:2
|
||||
dev-libs/expat
|
||||
dev-libs/glib:2
|
||||
dev-libs/nspr
|
||||
dev-libs/nss
|
||||
gnome-base/gsettings-desktop-schemas
|
||||
media-libs/alsa-lib
|
||||
media-libs/mesa[gbm(+)]
|
||||
net-misc/curl
|
||||
net-print/cups
|
||||
sys-apps/dbus
|
||||
sys-libs/glibc
|
||||
x11-libs/cairo
|
||||
x11-libs/gdk-pixbuf
|
||||
x11-libs/gtk+:3
|
||||
x11-libs/libdrm
|
||||
x11-libs/libxcb
|
||||
x11-libs/libxkbcommon
|
||||
x11-libs/libxshmfence
|
||||
x11-libs/libX11
|
||||
x11-libs/libXcomposite
|
||||
x11-libs/libXdamage
|
||||
x11-libs/libXext
|
||||
x11-libs/libXfixes
|
||||
x11-libs/libXrandr
|
||||
x11-libs/pango
|
||||
proprietary-codecs? (
|
||||
!ffmpeg-chromium? ( >=media-video/ffmpeg-6.1-r1:0/58.60.60[chromium] )
|
||||
ffmpeg-chromium? ( media-video/ffmpeg-chromium:${CHROMIUM_VERSION} )
|
||||
)
|
||||
qt6? ( dev-qt/qtbase:6[gui,widgets] )
|
||||
"
|
||||
|
||||
QA_PREBUILT="*"
|
||||
OPERA_HOME="opt/${MY_PN}"
|
||||
|
||||
pkg_pretend() {
|
||||
# Protect against people using autounmask overzealously
|
||||
use amd64 || die "opera only works on amd64"
|
||||
}
|
||||
|
||||
pkg_setup() {
|
||||
chromium_suid_sandbox_check_kernel_config
|
||||
}
|
||||
|
||||
src_unpack() {
|
||||
:
|
||||
}
|
||||
|
||||
src_install() {
|
||||
dodir /
|
||||
cd "${ED}" || die
|
||||
unpacker
|
||||
|
||||
# move to /opt, bug #573052
|
||||
mkdir opt || die
|
||||
mv "usr/lib/x86_64-linux-gnu/${MY_PN}" "${OPERA_HOME}" || die
|
||||
rm -r "usr/lib" || die
|
||||
|
||||
# disable auto update
|
||||
rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
|
||||
|
||||
rm -r "usr/share/lintian" || die
|
||||
|
||||
# fix docs
|
||||
mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
|
||||
gzip -d usr/share/doc/${PF}/changelog.gz || die
|
||||
|
||||
# fix desktop file
|
||||
sed -i \
|
||||
-e 's|^TargetEnvironment|X-&|g' \
|
||||
usr/share/applications/${PN}.desktop || die
|
||||
|
||||
# remove unused language packs
|
||||
pushd "${OPERA_HOME}/localization" > /dev/null || die
|
||||
chromium_remove_language_paks
|
||||
popd > /dev/null || die
|
||||
|
||||
# setup opera symlink
|
||||
rm "usr/bin/${PN}" || die
|
||||
dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
|
||||
|
||||
# install proprietary codecs
|
||||
rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
|
||||
if use proprietary-codecs; then
|
||||
dosym ../../usr/$(get_libdir)/chromium/libffmpeg.so$(usex ffmpeg-chromium .${CHROMIUM_VERSION} "") \
|
||||
/${OPERA_HOME}/libffmpeg.so
|
||||
fi
|
||||
|
||||
rm "${OPERA_HOME}/libqt5_shim.so" || die
|
||||
if ! use qt6; then
|
||||
rm "${OPERA_HOME}/libqt6_shim.so" || die
|
||||
fi
|
||||
|
||||
# pax mark opera, bug #562038
|
||||
pax-mark m "${OPERA_HOME}/opera"
|
||||
# enable suid sandbox if requested
|
||||
use suid && fperms 4711 "/${OPERA_HOME}/opera_sandbox"
|
||||
}
|
||||
Reference in New Issue
Block a user