xfce-extra/xfce4-sensors-plugin: Bump to 1.4.5

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-extra/xfce4-sensors-plugin/Manifest

@@ -1 +1,2 @@
 DIST xfce4-sensors-plugin-1.4.4.tar.bz2 472187 BLAKE2B ab59dea6dd2252c23ee7a74567c16ab040152bbe0012349078d306dcad2c699d6e55b32f7d084c6cdf26f51ff324bcac817ea6f01e3957c74cd7799bddd0a147 SHA512 45a5df383cc950f05f33d3d658b4847890e4136d6c72708a4218f1460a27d44a07a3f726d6c509bc706b963041a5dab3259dd94127636fb196d47ab9a0d6f702
+DIST xfce4-sensors-plugin-1.4.5.tar.bz2 633276 BLAKE2B 3c916d57a013c3a0e1b0952180b8d70a1c1f0e1727531addddd63032a9dc6a8cc5c4a333dde040412badf565c1470bb84a5564e232ef2f4a78c0d37039bd1c81 SHA512 f47007e1673b0309865a786240b64b4f1392e94035dc524beb09196d3309fd9a5b49fd3c2b5532a0b3c514b85f6345ec127c01f85ade170ae26ed2bbbe3fa299

xfce-extra/xfce4-sensors-plugin/xfce4-sensors-plugin-1.4.5.ebuild

@@ -0,0 +1,72 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit xdg-utils
+
+DESCRIPTION="A panel plug-in for acpi, lm-sensors and hddtemp sensors"
+HOMEPAGE="
+	https://docs.xfce.org/panel-plugins/xfce4-sensors-plugin/start
+	https://gitlab.xfce.org/panel-plugins/xfce4-sensors-plugin/
+"
+SRC_URI="https://archive.xfce.org/src/panel-plugins/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="+acpi hddtemp libnotify lm-sensors video_cards_nvidia"
+REQUIRED_USE="|| ( hddtemp lm-sensors acpi )"
+
+DEPEND="
+	>=x11-libs/gtk+-3.22.0:3
+	>=xfce-base/libxfce4ui-4.16.0:=
+	>=xfce-base/libxfce4util-4.17.2:=
+	>=xfce-base/xfce4-panel-4.16.0:=
+	hddtemp? (
+		app-admin/hddtemp
+		|| (
+			net-analyzer/openbsd-netcat
+			net-analyzer/netcat
+		)
+	)
+	libnotify? ( >=x11-libs/libnotify-0.7:= )
+	lm-sensors? ( >=sys-apps/lm-sensors-3.1.0:= )
+	video_cards_nvidia? ( x11-drivers/nvidia-drivers[tools,static-libs] )
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local myconf=(
+		--libexecdir="${EPREFIX}"/usr/$(get_libdir)
+		$(use_enable lm-sensors libsensors)
+		$(use_enable hddtemp)
+		$(use_enable hddtemp netcat)
+		$(use_enable acpi procacpi)
+		$(use_enable acpi sysfsacpi)
+		$(use_enable video_cards_nvidia xnvctrl)
+		$(use_enable libnotify notification)
+		--disable-pathchecks
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}