dev-python/pygame: Bump to 2.0.3

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/pygame/Manifest

@@ -3,3 +3,4 @@ DIST pygame-2.0.0.dev10.tar.gz 5567274 BLAKE2B 7d78f260318cfabeb33f1073ae210f890
 DIST pygame-2.0.0.tar.gz 5522621 BLAKE2B 49773979af53595d3ff2db1a18e4bcd217e26db3ec28d6129d2a588f23a1bd5326fa79fab32c25aa796738cde0e68f5741bee58f62432e86f89cd49ee17a8f14 SHA512 3f65924d0e1d2863b84118a4e468b521a289e2cf174405c6f3ee2b2a2ed399cde7f9f310d57c4166351f84caaea02dd7408ee852dbcee7c205bb2955b6078fda
 DIST pygame-2.0.1.tar.gz 5536907 BLAKE2B b27cb9001499a00da62dac0486a72079ff4e60ca609be444b04f547cb2372090da91d2670307ce7068b964458e6ac1284402439bb7809c9735135d5e93a71d78 SHA512 1535a872c43e5f75acdfa7d325fcfa0f0f826e18602b28b228cfdbe068a382678c21568d80873f7af4f0b318e693adb38afa4d632f8294f716a47188abe5245a
 DIST pygame-2.0.2.tar.gz 6309459 BLAKE2B 0cb23b4226d8d86f938cba08b67ab3bd847c9e4122f5f6cce4d8810b239df672ab282e1b77dd7d71423f805c7c0418e54050347dfb9e506b799eb8e0b4f16856 SHA512 2cef4669e5bd81759c9886293ebc1b82e1ed3b4576a3632437f66cb353af330e15dd39e7378f2be8fd25838f202529dc550208a031aec77e1d05443a070638c8
+DIST pygame-2.0.3.tar.gz 5804279 BLAKE2B fb58dd57a9288bdff3c0d01389e363968ebddd4b2b0fa92335c825297026c5858da4f73a870f84e0c3c7cf302bd9f4163807c97a348d581658df7e7695fcb4fb SHA512 1d2b4cb1e577f0244c2b92511b8fa0ab7bcd689d04a4451ced41e6d97758ba380d7e681e60abed26c81b96bd49d505cf481c67a466437b3cfdb547e744f22949

dev-python/pygame/pygame-2.0.3.ebuild

@@ -0,0 +1,91 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1
+
+MY_PV=${PV/_pre/.dev}
+MY_P=${PN}-${MY_PV}
+
+DESCRIPTION="Python bindings for SDL multimedia library"
+HOMEPAGE="https://www.pygame.org/"
+SRC_URI="
+	https://github.com/pygame/pygame/releases/download/${MY_PV}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc examples midi opengl test X"
+RESTRICT="!test? ( test )"
+
+RDEPEND="dev-python/numpy[${PYTHON_USEDEP}]
+	media-libs/freetype
+	media-libs/libpng:0=
+	>=media-libs/sdl2-image-1.2.2
+	>=media-libs/sdl2-mixer-1.2.4
+	>=media-libs/sdl2-ttf-2.0.6
+	>=media-libs/smpeg2-0.4.4-r1
+	virtual/jpeg
+	midi? ( media-libs/portmidi )
+	X? ( >=media-libs/libsdl2-1.2.5[opengl?,threads,video,X] )
+	!X? ( >=media-libs/libsdl2-1.2.5[threads] )"
+DEPEND="${RDEPEND}
+	test? (
+		media-libs/sdl2-image[gif,jpeg,png]
+		media-libs/sdl2-mixer[mp3,vorbis,wav]
+	)"
+# fontconfig used for fc-list
+RDEPEND+="
+	media-libs/fontconfig"
+# util-linux provides script
+BDEPEND="
+	test? (
+		media-libs/fontconfig
+		sys-apps/util-linux
+	)"
+
+src_prepare() {
+	if ! use midi; then
+		rm test/midi_test.py || die
+	fi
+	distutils-r1_src_prepare
+}
+
+python_configure() {
+	PORTMIDI_INC_PORTTIME=1 LOCALBASE="${EPREFIX}/usr" \
+		"${EPYTHON}" "${S}"/buildconfig/config.py -auto || die
+
+	# Disable automagic dependency on PortMidi.
+	if ! use midi; then
+		sed -e "s:^pypm :#&:" -i Setup || die "sed failed"
+	fi
+}
+
+python_test() {
+	local -x PYTHONPATH=${BUILD_DIR}/install/lib
+	local -x SDL_VIDEODRIVER=dummy
+	local -x SDL_AUDIODRIVER=disk
+	distutils_install_for_testing --via-root
+	script -eqc "${EPYTHON} -m pygame.tests" || die
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Bug #497720
+	rm -fr "${D}"$(python_get_sitedir)/pygame/{docs,examples,tests}/ || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use doc; then
+		docinto html
+		dodoc -r docs/*
+	fi
+
+	use examples && dodoc -r examples
+}