dev-python/magic-wormhole-transit-relay: Bump to 0.4.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/magic-wormhole-transit-relay/Manifest

@@ -1 +1,2 @@
 DIST magic-wormhole-transit-relay-0.3.1.gh.tar.gz 63304 BLAKE2B ab6706e7265eab69376e9490e328e0a81a414c3667eaaac3a6e2c62f983e5beaf3e0f25da12b815703ae0ade69984f015153709ccae95871a6bf37f99b23d63c SHA512 3611ee140f421234e2e5805baf4d26a64879f067c8a75db1a44041c0f9ebe1d3cca7b202752f5bd423e6784ab5a6961fe27423564633dba9f09e92b14d370275
+DIST magic-wormhole-transit-relay-0.4.0.gh.tar.gz 62333 BLAKE2B 16415af2b9927cf2717c1c38be4b498d666db271c4e7b907bcf0fae9d5d100ee341358d2f04e72ba1a7f930dbc4fd9e797b20d6915d21955ef6963520d9b406a SHA512 ee0f40460277abc1ad550e070d8b70329da8c1311852f7a2eaaef036cfee7fcf018be7e6bad6f416392a602326ac436c33039d577af8cee2cfb09736749e956d

dev-python/magic-wormhole-transit-relay/magic-wormhole-transit-relay-0.4.0.ebuild

@@ -0,0 +1,68 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1
+
+DESCRIPTION="Transit relay server for magic-wormhole"
+HOMEPAGE="
+	https://magic-wormhole.readthedocs.io/en/latest/
+	https://github.com/magic-wormhole/magic-wormhole-transit-relay/
+	https://pypi.org/project/magic-wormhole-transit-relay/
+"
+SRC_URI="
+	https://github.com/magic-wormhole/magic-wormhole-transit-relay/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/autobahn-21.3.1[${PYTHON_USEDEP}]
+	>=dev-python/twisted-21.2.0[ssl,${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/versioneer[${PYTHON_USEDEP}]
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+	rm versioneer.py || die
+}
+
+python_test() {
+	local -x PATH=${T}/bin:${PATH}
+	mkdir -p "${T}"/bin || die
+	# the script is apparently run with PATH wiped, sigh
+	cat > "${T}"/bin/twistd <<-EOF || die
+		#!$(type -P python)
+		import sys
+		from twisted.scripts.twistd import run
+		sys.exit(run())
+	EOF
+	chmod +x "${T}"/bin/twistd || die
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+
+	find "${BUILD_DIR}/install" -name dropin.cache -delete || die
+}
+
+pkg_postinst() {
+	python_foreach_impl twisted-regen-cache
+}
+
+pkg_postrm() {
+	python_foreach_impl twisted-regen-cache
+}