dev-ruby/ruby-ldap: EAPI 8; add ruby30; fix extension install

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Hans de Graaff <graaff@gentoo.org>

dev-ruby/ruby-ldap/ruby-ldap-0.9.20-r1.ebuild

@@ -0,0 +1,34 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby26 ruby27 ruby30"
+
+inherit ruby-fakegem
+
+RUBY_FAKEGEM_TASK_TEST=""
+RUBY_FAKEGEM_EXTENSIONS=(./extconf.rb)
+RUBY_FAKEGEM_EXTRADOC="ChangeLog FAQ NOTES README TODO"
+
+DESCRIPTION="A Ruby interface to some LDAP libraries"
+HOMEPAGE="https://github.com/bearded/ruby-ldap"
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86"
+IUSE="ssl"
+DEPEND=">=net-nds/openldap-2
+	dev-libs/cyrus-sasl
+	ssl? ( dev-libs/openssl:0 )"
+RDEPEND="${DEPEND}"
+
+# Current test set is interactive due to certificate generation and requires
+# running LDAP daemon
+RESTRICT="test"
+
+each_ruby_configure() {
+	local myconf="--with-openldap2"
+	if ! use ssl ; then
+		myconf="${myconf} --without-libcrypto --without-libssl"
+	fi
+	RUBY_FAKEGEM_EXTENSION_OPTIONS=${myconf} each_fakegem_configure
+}