games-emulation/mupen64plus-input-sdl: Remove old

Signed-off-by: Michał Górny <mgorny@gentoo.org>

games-emulation/mupen64plus-input-sdl/Manifest

@@ -1,2 +1 @@
-DIST mupen64plus-input-sdl-src-2.5.9.tar.gz 56403 BLAKE2B 56d6c390783aa4a7f25f72a5295eb11f1ca2a69f2ffe4f0232d4a0c329e9c0eba0a2cbf46e66adfdf0462d2ec5337f7c6c4587ae29de346cd4cfe1d240f4d5fd SHA512 b613396ee05e82aaaf15e955f83b5cb4e854df1fdb34d5e1c96cf0fddf0af79aa5af2ceb19cc9cfeaef707c2ecafd25e0814e3d7715a20b740482d0ece273f2f
 DIST mupen64plus-input-sdl-src-2.6.0.tar.gz 61800 BLAKE2B c09ebf5534172e92e7aa8833a9c2cc708406754fa3a133ac55f2c0b1029d6d3a0c801a8f771d00439cc3832c21b4b3053479526b74e86c2769131ef9d36154de SHA512 ad818ad3da3f30fbf30d08bc2a15319b58d65e91d8460b8d13825947a1f688b0d51daaf797992fa9c3683ff8ba9b4314ddccbb577b9d77656107ab7d8716a479

games-emulation/mupen64plus-input-sdl/mupen64plus-input-sdl-2.5.9.ebuild

@@ -1,76 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-MY_P=${PN}-src-${PV}
-inherit toolchain-funcs
-
-DESCRIPTION="A fork of Mupen64 Nintendo 64 emulator, SDL input plugin"
-HOMEPAGE="https://www.mupen64plus.org/"
-SRC_URI="https://github.com/mupen64plus/${PN}/releases/download/${PV}/${MY_P}.tar.gz"
-
-LICENSE="GPL-2+"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE=""
-
-RDEPEND=">=games-emulation/mupen64plus-core-${PV}:0=
-	media-libs/libsdl2:0=[joystick]"
-DEPEND="${RDEPEND}"
-BDEPEND="virtual/pkgconfig"
-
-S=${WORKDIR}/${MY_P}
-
-src_prepare() {
-	default
-
-	# avoid implicitly appending CPU flags
-	sed -i -e 's:-mmmx::g' -e 's:-msse::g' projects/unix/Makefile || die
-}
-
-src_compile() {
-	MAKEARGS=(
-		# Note: please keep this in sync in all of mupen64plus-* packages
-
-		-C projects/unix
-
-		# this basically means: GNU userspace
-		UNAME=Linux
-
-		# verbose output
-		V=1
-
-		CROSS_COMPILE="${CHOST}-"
-		CC="$(tc-getCC)"
-		CXX="$(tc-getCXX)"
-		PKG_CONFIG="$(tc-getPKG_CONFIG)"
-		# usual CFLAGS, CXXFLAGS and LDFLAGS are respected
-		# so we can leave OPTFLAGS empty
-		OPTFLAGS=
-
-		# paths, some of them are used at compile time
-		PREFIX=/usr
-		LIBDIR=/usr/$(get_libdir)
-
-		# disable unwanted magic
-		LDCONFIG=:
-		INSTALL_STRIP_FLAG=
-
-		# Package-specific stuff
-
-		# CROSS_COMPILE causes it to look for ${CHOST}-sdl2-config...
-		SDL_CFLAGS="$($(tc-getPKG_CONFIG) --cflags sdl2)"
-		SDL_LDLIBS="$($(tc-getPKG_CONFIG) --libs sdl2)"
-	)
-
-	use amd64 && MAKEARGS+=( HOST_CPU=x86_64 )
-	use x86 && MAKEARGS+=( HOST_CPU=i386 )
-
-	emake "${MAKEARGS[@]}" all
-}
-
-src_install() {
-	emake "${MAKEARGS[@]}" DESTDIR="${D}" install
-	dodoc AUTHORS README.md RELEASE
-}