app-text/paper-clip: bump to 5.5.2

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

app-text/paper-clip/Manifest

@@ -1 +1,2 @@
 DIST paper-clip-5.5.1.tar.gz 183419 BLAKE2B 18af0f18d8d3da9f6d6f4cea57aa817e902666ee60f851ec54adc64506d3f4a8508895f64ace28424b0a3018e6bdf0b80cd40a602d226b09e83d1efa2e82daf4 SHA512 5cca56b2cc6f3619c40b202b8e53e3e01834fb10dcf1769553fb6904d50297736c9dcaad376422d2ea49203f40b32fb24d64a1f161a49868e446459d94f08138
+DIST paper-clip-5.5.2.gh.tar.gz 193271 BLAKE2B 77ba7056c9e82b766e5a14e13d887b966403cd3790ecc0772da4ae7c3546ae2f6c81d076ba37cf88614dba780bc66b81f0f63abe8ea8c2be5e542538dad7a979 SHA512 57d8a4559434acb99e23593dd7718bcfc67e80c49b0aaf958f597a3e8d611afc20276606c328bb500adc0adb6cd4642a3f0b79f460d4504942095865025dcc10

app-text/paper-clip/paper-clip-5.5.2.ebuild

@@ -0,0 +1,70 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+APP_PN="Paper-Clip"
+
+inherit gnome2-utils meson vala xdg
+
+DESCRIPTION="Edit the title, author, keywords and more details of PDF documents"
+HOMEPAGE="https://github.com/Diego-Ivan/Paper-Clip/"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/Diego-Ivan/${APP_PN}.git"
+else
+	SRC_URI="https://github.com/Diego-Ivan/${APP_PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+	S="${WORKDIR}/${APP_PN}-${PV}"
+
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+RESTRICT="test"  # Only validations, the appdata one fails.
+
+RDEPEND="
+	>=gui-libs/gtk-4.12.5:4
+	>=gui-libs/libadwaita-1.5.0:1[introspection,vala]
+	app-text/poppler:=[cairo,introspection]
+	dev-libs/glib:2
+	dev-libs/gobject-introspection
+	dev-libs/libportal:=[gtk,introspection,vala]
+	media-libs/exempi
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	$(vala_depend)
+	dev-libs/appstream-glib
+	dev-util/desktop-file-utils
+"
+
+DOCS=( README.md )
+
+src_prepare() {
+	default
+	vala_setup
+}
+
+src_install() {
+	meson_src_install
+	einstalldocs
+
+	# Symlink "pdf-metadata-editor" (old name?) to "${PN}".
+	dosym -r /usr/bin/pdf-metadata-editor "/usr/bin/${PN}"
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_pkg_postrm
+}