gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/python-lsp-server: add version 1.3.1, enable py3.10

Browse Source 
Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Andrew Ammerlaan <andrewammerlaan@gentoo.org>
This commit is contained in:
Andrew Ammerlaan
2021-11-24 22:12:04 +01:00
parent 4aa741dac2
commit 4f9ffe0027
2 changed files with 92 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/python-lsp-server/Manifest
View File

@@ -1 +1,2 @@
DIST python-lsp-server-1.2.4.tar.gz 62073 BLAKE2B b1426d71a4da5ac29fa6b3e956010625d594eee7924a51eb5074933866254189a9738895bc5dd4aae8acc1733b9f162b73646d9a3eee3ac17a587456f2da00e4 SHA512 862d59426c6e7c19f9d3d2766ec5f9ec818d29988ee72cde9553e4b1725fbbe4230ed2f6d7e8d08983c9ef1ced8d5afe42d6751ea529d3d8799c8930b1e10a26
DIST python-lsp-server-1.3.1.tar.gz 62464 BLAKE2B 89bcd96aab49c1819df29f5535d527669ce6a1face08647247fb9fe3700882b95afb4c32e8c5b6cab81148476b71b5645a6290a2ab2252fdeb93691430dd7b4b SHA512 45327254b0826d2883d0838734eb97a53fb4c6f61fe72c397de903107dbb852834a4c363aa34189a06a5f40cadb3644cb940fd69c969210c287cd3c21b81283c

91
dev-python/python-lsp-server/python-lsp-server-1.3.1.ebuild Normal file
View File

@@ -0,0 +1,91 @@
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{8..10} )
DISTUTILS_USE_SETUPTOOLS=rdepend
inherit distutils-r1 optfeature
DESCRIPTION="Python Language Server for the Language Server Protocol"
HOMEPAGE="https://github.com/python-lsp/python-lsp-server"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~x86"
IUSE="all-plugins"
BDEPEND="
test? (
>=dev-python/autopep8-1.6.0[${PYTHON_USEDEP}]
<dev-python/autopep8-1.7.0[${PYTHON_USEDEP}]
dev-python/flaky[${PYTHON_USEDEP}]
>=dev-python/flake8-4.0.0[${PYTHON_USEDEP}]
<dev-python/flake8-4.1.0[${PYTHON_USEDEP}]
dev-python/matplotlib[${PYTHON_USEDEP}]
>=dev-python/mccabe-0.6.0[${PYTHON_USEDEP}]
<dev-python/mccabe-0.7.0[${PYTHON_USEDEP}]
dev-python/numpy[${PYTHON_USEDEP}]
dev-python/pandas[${PYTHON_USEDEP}]
>=dev-python/pycodestyle-2.8.0[${PYTHON_USEDEP}]
<dev-python/pycodestyle-2.9.0[${PYTHON_USEDEP}]
>=dev-python/pydocstyle-2.0.0[${PYTHON_USEDEP}]
>=dev-python/pyflakes-2.4.0[${PYTHON_USEDEP}]
<dev-python/pyflakes-2.5.0[${PYTHON_USEDEP}]
>=dev-python/pylint-2.5.0[${PYTHON_USEDEP}]
dev-python/QtPy[gui,testlib,${PYTHON_USEDEP}]
>=dev-python/rope-0.10.5[${PYTHON_USEDEP}]
dev-python/yapf[${PYTHON_USEDEP}]
)"
RDEPEND="
>=dev-python/jedi-0.17.2[${PYTHON_USEDEP}]
<dev-python/jedi-0.19.0[${PYTHON_USEDEP}]
>=dev-python/python-lsp-jsonrpc-1.0.0[${PYTHON_USEDEP}]
dev-python/pluggy[${PYTHON_USEDEP}]
all-plugins? (
>=dev-python/autopep8-1.6.0[${PYTHON_USEDEP}]
<dev-python/autopep8-1.7.0[${PYTHON_USEDEP}]
>=dev-python/flake8-4.0.0[${PYTHON_USEDEP}]
<dev-python/flake8-4.1.0[${PYTHON_USEDEP}]
>=dev-python/mccabe-0.6.0[${PYTHON_USEDEP}]
<dev-python/mccabe-0.7.0[${PYTHON_USEDEP}]
>=dev-python/pycodestyle-2.8.0[${PYTHON_USEDEP}]
<dev-python/pycodestyle-2.9.0[${PYTHON_USEDEP}]
>=dev-python/pydocstyle-2.0.0[${PYTHON_USEDEP}]
>=dev-python/pyflakes-2.4.0[${PYTHON_USEDEP}]
<dev-python/pyflakes-2.5.0[${PYTHON_USEDEP}]
>=dev-python/pylint-2.5.0[${PYTHON_USEDEP}]
>=dev-python/rope-0.10.5[${PYTHON_USEDEP}]
dev-python/yapf[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
python_prepare_all() {
# remove pytest-cov dep
sed -i -e '0,/addopts/I!d' setup.cfg || die
# This fails with py3.10, but it is not important. Instead of
# 'invalid syntax' we now get 'syntax-error'
sed -i -e 's/test_syntax_error_pylint_py3/_&/' \
test/plugins/test_pylint_lint.py || die
distutils-r1_python_prepare_all
}
pkg_postinst() {
optfeature "Automatically formats Python code to conform to the PEP 8 style guide" dev-python/autopep8
optfeature "A wrapper around PyFlakes, pep8 & mccabe" dev-python/flake8
optfeature "flake8 plugin: McCabe complexity checker" dev-python/mccabe
optfeature "Python style guide checker (fka pep8)" dev-python/pycodestyle
optfeature "Python docstring style checker" dev-python/pydocstyle
optfeature "Passive checker for Python programs" dev-python/pyflakes
optfeature "Python code static checker" dev-python/pylint
optfeature "Python refactoring library" dev-python/rope
optfeature "A formatter for Python files" dev-python/yapf
}