xfce-extra/xfce4-pulseaudio-plugin: Bump to 0.4.4

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-extra/xfce4-pulseaudio-plugin/Manifest

@@ -1 +1,2 @@
 DIST xfce4-pulseaudio-plugin-0.4.3.tar.bz2 431773 BLAKE2B 2c0de4ea0ab9304b737fe4ce570bcd8427f983845fe898dbe7e053a5fe79793223df6882a931b186664d8c95d4c767daf39ba36a98dc58595ba77e8a18c13a6c SHA512 d3214b2b7c35a0a87ea60a5d843f5027d1b09f320d4d24c6bf89a8936de92226223cb4dc5368edf4c0a1aedb3b8796510981eeadee8e836e764569d9284f0efa
+DIST xfce4-pulseaudio-plugin-0.4.4.tar.bz2 389978 BLAKE2B 36f990aeac3fb07c19fe421ebe5172bfc5d87b4281d6dc921b7173a0cee70693f9ecfed6675b128bb617d78d4920694aac44d8846bcd1f49d5c4cf415a513074 SHA512 5e7f024be6283523d0a0c0c3e7ba1d632b1521c442d9468980e0811a6b4c7bbcdcaff27999410b83a967d16105f6c09f6e0718719654ccc9f1109066d8964b59

xfce-extra/xfce4-pulseaudio-plugin/xfce4-pulseaudio-plugin-0.4.4.ebuild

@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit xdg-utils
+
+DESCRIPTION="A panel plug-in for PulseAudio volume control"
+HOMEPAGE="https://git.xfce.org/panel-plugins/xfce4-pulseaudio-plugin/"
+SRC_URI="https://archive.xfce.org/src/panel-plugins/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="+keybinder libnotify wnck"
+
+DEPEND="
+	>=dev-libs/glib-2.42.0
+	media-sound/pulseaudio:=[glib]
+	>=x11-libs/gtk+-3.20.0:3
+	>=xfce-base/exo-0.11:=
+	>=xfce-base/libxfce4ui-4.11.0:=[gtk3(+)]
+	>=xfce-base/libxfce4util-4.9.0:=
+	>=xfce-base/xfce4-panel-4.11.0:=
+	>=xfce-base/xfconf-4.6.0:=
+	keybinder? ( dev-libs/keybinder:3 )
+	libnotify? ( x11-libs/libnotify )
+	wnck? ( x11-libs/libwnck:3 )
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-util/intltool
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local myconf=(
+		$(use_enable keybinder)
+		$(use_enable libnotify)
+		$(use_enable wnck)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+
+	if ! has_version media-sound/pavucontrol; then
+		elog "For the 'audio mixer...' shortcut to work, you need to install"
+		elog "an external mixer application. Please either install:"
+		elog
+		elog "	media-sound/pavucontrol"
+		elog
+		elog "or specify another application to use in the 'Properties' dialog."
+	fi
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}