mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-22 10:57:07 -08:00
x11-themes/kvantum: add 1.1.5
Closes: https://bugs.gentoo.org/949317 Closes: https://bugs.gentoo.org/743052 Signed-off-by: Johannes Huber <johu@gmx.de> Part-of: https://github.com/gentoo/gentoo/pull/42191 Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
@@ -1 +1,2 @@
|
||||
DIST kvantum-1.1.2.tar.gz 3041246 BLAKE2B 7587adb7858fad2e4e3cf953fd4419d8a518d0e4b641afc426bc0c5417b91ff2d174af9c1e6d198d8eb979130f4704fb475bc0a84766957500e8913b6738706d SHA512 71c714df902ac4d7ac707e26842e2227eb7eeddad03af0bbd1ab1fcfa132204a9dd0453eafac3000cd3187dcb4ff03d64f01674c442f5a225e0c9b3652277f0e
|
||||
DIST kvantum-1.1.5.tar.gz 3246160 BLAKE2B 9f044587810f5d369ea5f88e22f2a9e0a4ce60e163d11848762a5eff62561f3d5cfc490b2f21cccd8deb82572367a5d062f9b11c30d25c5cb131d73de4dcea5c SHA512 14552236c05af0d7a075d58d4ba5e7f81bd89e7f7b06dee81aed2814e7c34ec359c63fadf562735b4fce30a07ce1d9d55398f694fb3327b60fa1386381e2243c
|
||||
|
||||
@@ -0,0 +1,76 @@
|
||||
# Copyright 1999-2025 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
# minimum taken from Kvantum/style/CMakeLists.txt
|
||||
# increased downstream to ensure sane upgrades
|
||||
QTMIN="6.8.2"
|
||||
KFMIN="6.13.0"
|
||||
inherit cmake multibuild xdg
|
||||
|
||||
DESCRIPTION="SVG-based theme engine for Qt, KDE Plasma and LXQt"
|
||||
HOMEPAGE="https://github.com/tsujan/Kvantum"
|
||||
SRC_URI="https://github.com/tsujan/${PN^}/archive/V${PV}.tar.gz -> ${P}.tar.gz"
|
||||
S=${WORKDIR}/${PN^}-${PV}/${PN^}
|
||||
|
||||
LICENSE="GPL-3"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
|
||||
IUSE="kde qt5"
|
||||
|
||||
RESTRICT="test" # no tests
|
||||
|
||||
RDEPEND="
|
||||
>=dev-qt/qtbase-${QTMIN}:6[gui,widgets,X]
|
||||
>=dev-qt/qtsvg-${QTMIN}:6
|
||||
x11-libs/libX11
|
||||
kde? ( >=kde-frameworks/kwindowsystem-${KFMIN}:6 )
|
||||
qt5? (
|
||||
dev-qt/qtcore:5
|
||||
dev-qt/qtgui:5
|
||||
dev-qt/qtsvg:5
|
||||
dev-qt/qtwidgets:5
|
||||
dev-qt/qtx11extras:5
|
||||
)
|
||||
"
|
||||
DEPEND="${RDEPEND}
|
||||
x11-base/xorg-proto
|
||||
"
|
||||
BDEPEND="
|
||||
dev-qt/qttools:6[linguist]
|
||||
qt5? ( dev-qt/linguist-tools:5 )
|
||||
"
|
||||
|
||||
pkg_setup() {
|
||||
MULTIBUILD_VARIANTS=( $(usev qt5) qt6 )
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
my_src_configure() {
|
||||
local mycmakeargs=(
|
||||
-DENABLE_QT4=OFF
|
||||
)
|
||||
if [[ ${MULTIBUILD_VARIANT} = qt5 ]]; then
|
||||
mycmakeargs+=(
|
||||
-DENABLE_QT5=ON
|
||||
)
|
||||
elif [[ ${MULTIBUILD_VARIANT} = qt6 ]]; then
|
||||
mycmakeargs+=(
|
||||
-DENABLE_QT5=OFF
|
||||
-DWITHOUT_KF=$(usex !kde)
|
||||
)
|
||||
fi
|
||||
cmake_src_configure
|
||||
}
|
||||
|
||||
multibuild_foreach_variant my_src_configure
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
multibuild_foreach_variant cmake_src_compile
|
||||
}
|
||||
|
||||
src_install() {
|
||||
multibuild_foreach_variant cmake_src_install
|
||||
}
|
||||
Reference in New Issue
Block a user