www-client/opera-gx: automated bump (139.0.6053.63)

Signed-off-by: Matt Jolly <kangie@gentoo.org>
This commit is contained in:
Matt Jolly
2026-11-13 07:10:30 +10:00
parent ce388300d6
commit 4e67e30788
2 changed files with 138 additions and 0 deletions
+1
View File
@@ -1,3 +1,4 @@
DIST opera-gx-stable_138.0.6044.45_amd64.deb 186197490 BLAKE2B 123b75f307beb8a56c3f13b68c919885219d8c6fb8f0f9e1567d39b77f1ee51b0ac136d62d0810b2304099ecca54d50442039ac7ccfc5d76d7e3e50f5571bc2a SHA512 5321b98c95c12cb6b6d30107c69f644141d6153521a25bc80b5810c4c0109434cf0316a85fca58fc4a471b3d46587f3813d0449d1d6ce7047d2c6398a1119385
DIST opera-gx-stable_138.0.6044.65_amd64.deb 186177962 BLAKE2B 26088e0787d14bfac02cb196d190db40ca161c8216c79a8b01ab7cacebf9c3f0ff5aa741e960d95e1c2e02302b3b3099a89f3b7c54f514b8a842a4649475eb79 SHA512 f30af6d9d9e6d9dead8c28c754e6c03880ec6102bc80ce02d021e674c9e45e16513691f192116df26d23a9f725df6678c27807fb47c8d5219b4ed79b82e568b3
DIST opera-gx-stable_139.0.6053.42_amd64.deb 188972004 BLAKE2B f7740b612481f86e5831a912315a0b32b3d0a56d6a169340992ea84bcf4e60c076630b1bf2634bbc783ccef0929df65e839041c842aa8131843f155ee3f190a5 SHA512 c64095831570e97e22bf946a7d01ecf6b1cd14fb619daaf7c9ef52daad518cc7ef4f457769f952c266d85d8061f0945ba095a543836eea4cdafca0a5ef486cc8
DIST opera-gx-stable_139.0.6053.63_amd64.deb 189003378 BLAKE2B 6812e99968a067ce3cc97d67e17cc52cf99c2d90280512b6056fde968ac2058d805ee222d5da5991c90e56d65807b05dbc083cf6b60d899cf12d131125d4313d SHA512 d6c770d030d4e1741aa11dfd4999a3f84dff4689e2be7321be2d65e89a13d3ef8a596a0f15990dadf4925e0577805afb5c2d88fb008c1f034eb681cd7dddb725
@@ -0,0 +1,137 @@
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
CHROMIUM_LANGS="
bg bn ca cs da de el en-GB en-US es-419 es fil fi fr hi hr hu id
it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
zh-CN zh-TW
"
inherit chromium-2 pax-utils unpacker xdg
DESCRIPTION="Opera, but for 'gamers'"
HOMEPAGE="https://www.opera.com/gx"
SRC_URI_BASE=(
"https://download1.operacdn.com/pub/${PN//-/_}"
"https://download2.operacdn.com/pub/${PN//-/_}"
"https://download3.operacdn.com/pub/${PN//-/_}"
"https://download4.operacdn.com/pub/${PN//-/_}"
)
if [[ ${PN} == opera-gx ]]; then
MY_PN=${PN}-stable
else
MY_PN=${PN}
fi
# Commit ref from `strings libffmpeg.so | grep -F "FFmpeg version"` matches this Chromium version
# or use Chromicler to handle bumps.
# Does not _need_ to be updated for every new version of Opera, only when it breaks.
CHROMIUM_VERSION="155"
SRC_URI="${SRC_URI_BASE[*]/%//${PV}/linux/${MY_PN}_${PV}_amd64.deb}"
S=${WORKDIR}
LICENSE="OPERA-2020"
SLOT="0"
KEYWORDS="-* ~amd64"
IUSE="+ffmpeg-chromium +proprietary-codecs +suid qt6"
RESTRICT="bindist mirror strip"
RDEPEND="
>=app-accessibility/at-spi2-core-2.46.0:2
dev-libs/expat
dev-libs/glib:2
dev-libs/nspr
dev-libs/nss
gnome-base/gsettings-desktop-schemas
media-libs/alsa-lib
media-libs/mesa[gbm(+)]
net-misc/curl
net-print/cups
sys-apps/dbus
sys-libs/glibc
x11-libs/cairo
x11-libs/gdk-pixbuf
x11-libs/gtk+:3
x11-libs/libdrm
x11-libs/libxcb
x11-libs/libxkbcommon
x11-libs/libxshmfence
x11-libs/libX11
x11-libs/libXcomposite
x11-libs/libXdamage
x11-libs/libXext
x11-libs/libXfixes
x11-libs/libXrandr
x11-libs/pango
proprietary-codecs? (
!ffmpeg-chromium? ( >=media-video/ffmpeg-6.1-r1:0/58.60.60[chromium] )
ffmpeg-chromium? ( media-video/ffmpeg-chromium:${CHROMIUM_VERSION} )
)
qt6? ( dev-qt/qtbase:6[gui,widgets] )
"
QA_PREBUILT="*"
OPERA_HOME="opt/${MY_PN}"
pkg_pretend() {
# Protect against people using autounmask overzealously
use amd64 || die "opera only works on amd64"
}
pkg_setup() {
chromium_suid_sandbox_check_kernel_config
}
src_unpack() {
:
}
src_install() {
dodir /
cd "${ED}" || die
unpacker
# move to /opt, bug #573052
mkdir opt || die
mv "usr/lib/x86_64-linux-gnu/${MY_PN}" "${OPERA_HOME}" || die
rm -r "usr/lib" || die
# disable auto update
rm "${OPERA_HOME}/opera_autoupdate"{,.licenses,.version} || die
rm -r "usr/share/lintian" || die
# fix docs
mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
gzip -d usr/share/doc/${PF}/changelog.gz || die
# remove unused language packs
pushd "${OPERA_HOME}/localization" > /dev/null || die
chromium_remove_language_paks
popd > /dev/null || die
# setup opera symlink
rm "usr/bin/${PN}" || die
dosym "../../${OPERA_HOME}/opera" "/usr/bin/${PN}"
# install proprietary codecs
rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
if use proprietary-codecs; then
dosym ../../usr/$(get_libdir)/chromium/libffmpeg.so$(usex ffmpeg-chromium .${CHROMIUM_VERSION} "") \
/${OPERA_HOME}/libffmpeg.so
fi
rm "${OPERA_HOME}/libqt5_shim.so" || die
if ! use qt6; then
rm "${OPERA_HOME}/libqt6_shim.so" || die
fi
# pax mark opera, bug #562038
pax-mark m "${OPERA_HOME}/opera"
# enable suid sandbox if requested
use suid && fperms 4711 "/${OPERA_HOME}/opera_sandbox"
}