games-rpg/baldurs-gate-ee: bump to 2.5.23121

Package-Manager: Portage-2.3.49, Repoman-2.3.10
Closes: https://github.com/gentoo/gentoo/pull/9747

games-rpg/baldurs-gate-ee/Manifest

@@ -1 +1,2 @@
+DIST baldur_s_gate_enhanced_edition_en_2_5_23121.sh 2892168067 BLAKE2B 7e20922f539be65cf7371f7f1706873e5a147313e3aa0335bfa5d6c4456a40665260a36abab6e73361c5f9c0a0bc2faff6e719dd72fb0ddd8b0e1c22d6eaedd8 SHA512 b5b84148b35984109454e1299ee29d287750172e617fb97e65c46b2c9419173348b37d54587bd44a3eacb6380c9b13e4be91af5625009cba797843483be7165d
 DIST gog_baldur_s_gate_enhanced_edition_2.5.0.9.sh 2877124067 BLAKE2B 244e93ae089703c9fae3dcfcad4fb9c1eb32695e7288f7a05b3f2996887f90d6912e745e9b47a93ba45ee3ddda8363e69d22e62c57258ee54c24c47f07b2f619 SHA512 56d4796a959658f29cabef6e7339db5ba9fa792d9fd899ebc375c9b5cf94305b6d11c21d41a8809fcb1cbe38ecb4bc7152158ef19c87395374ab9060f48756a6

games-rpg/baldurs-gate-ee/baldurs-gate-ee-2.5.23121.ebuild

@@ -0,0 +1,53 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop eutils unpacker
+
+DESCRIPTION="Baldur's Gate: Enhanced Edition"
+HOMEPAGE="https://www.baldursgate.com/"
+SRC_URI="baldur_s_gate_enhanced_edition_en_${PV//./_}.sh"
+
+LICENSE="GOG-EULA"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+RESTRICT="bindist fetch"
+
+DEPEND="app-arch/unzip"
+RDEPEND="dev-libs/expat
+	dev-libs/openssl:0
+	media-libs/openal
+	virtual/opengl
+	x11-libs/libX11"
+
+QA_PRESTRIPPED="/opt/${PN}/BaldursGate\(64\)\?"
+
+S="${WORKDIR}/data/noarch"
+
+pkg_nofetch() {
+	einfo "Please buy and download \"${SRC_URI}\" from"
+	einfo "https://www.gog.com/game/baldurs_gate_enhanced_edition"
+	einfo "and place it in your DISTDIR directory."
+}
+
+src_unpack() {
+	unpack_zip ${A}
+}
+
+src_install() {
+	local dir="/opt/${PN}"
+
+	dodoc -r "game/Manuals/."
+	rm -r "game/Manuals" || die "rm failed"
+
+	insinto "${dir}"
+	doins -r "game/."
+	fperms +x "${dir}/BaldursGate"{,64}
+
+	use amd64 && make_wrapper ${PN} "./BaldursGate64" "${dir}"
+	use x86 && make_wrapper ${PN} "./BaldursGate" "${dir}"
+
+	newicon "support/icon.png" "${PN}.png"
+	make_desktop_entry "${PN}" "Baldur's Gate: Enhanced Edition" "${PN}"
+}