mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-09 06:37:10 -08:00
app-editors/nano: Bump to version 4.4
Package-Manager: Portage-2.3.73, Repoman-2.3.17 Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
This commit is contained in:
@@ -1,2 +1,3 @@
|
||||
DIST nano-4.2.tar.gz 2928595 BLAKE2B 42bb0ccbf4961706c6c645eb2310a646a7decd3617117a079ffe9e3718c8054ab823a5aff3e543c06c4c398f83579a679267a9ad6f113ba451b76d67e14b07cc SHA512 a5dd9ce96cd09d12c65108ea6a18b2cf1c2b055929e58d3e84beb0725607b4b5a3f8ae3fda0ab658c853cc4cac70c089fee716e1bb5a700f2506a7a3e1bea1bd
|
||||
DIST nano-4.3.tar.gz 2939418 BLAKE2B 2464118a1cd16477637a8e98c1d179cbea1f33cc1548eff09b3b77b613b5b2b628915da1d11c04064f7211a0254461eab09ddae6dda582004d77adea9dff2360 SHA512 2fb76e61079efb0a16f3ea27fdc7da749c71d61a752d96beee4f8376ad0071792ecaa5f3dc627fbcce175227ca48c60c1a4a3e17bfbc89180aa484c28fe37746
|
||||
DIST nano-4.4.tar.gz 2947594 BLAKE2B 20cdc21e136ff213ecc2dd64531e51c552547633a422566c325b8d777800d5f77691751d3acae3b9489eeec40c0893fe913dd8669b29ab985cdf0ac4a3381192 SHA512 14f23de002f5919a3b75ef8c0cfb93a45c8b8ba6c87d8b7c472ab2106fb4c1c17a3846f99ad6e2d2d160aa14aea44c23067fa58b2e668a41616f5cff2feea50f
|
||||
|
||||
@@ -0,0 +1,80 @@
|
||||
# Copyright 1999-2019 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=7
|
||||
|
||||
inherit flag-o-matic
|
||||
if [[ ${PV} == "9999" ]] ; then
|
||||
EGIT_REPO_URI="git://git.sv.gnu.org/nano.git"
|
||||
inherit git-r3 autotools
|
||||
else
|
||||
MY_P="${PN}-${PV/_}"
|
||||
SRC_URI="https://www.nano-editor.org/dist/v${PV:0:1}/${MY_P}.tar.gz"
|
||||
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
|
||||
fi
|
||||
|
||||
DESCRIPTION="GNU GPL'd Pico clone with more functionality"
|
||||
HOMEPAGE="https://www.nano-editor.org/ https://wiki.gentoo.org/wiki/Nano/Basics_Guide"
|
||||
|
||||
LICENSE="GPL-3"
|
||||
SLOT="0"
|
||||
IUSE="debug justify +magic minimal ncurses nls slang +spell +split-usr static unicode"
|
||||
|
||||
LIB_DEPEND=">=sys-libs/ncurses-5.9-r1:0=[unicode?]
|
||||
sys-libs/ncurses:0=[static-libs(+)]
|
||||
magic? ( sys-apps/file[static-libs(+)] )
|
||||
nls? ( virtual/libintl )
|
||||
!ncurses? ( slang? ( sys-libs/slang[static-libs(+)] ) )"
|
||||
RDEPEND="!static? ( ${LIB_DEPEND//\[static-libs(+)]} )"
|
||||
DEPEND="${RDEPEND}
|
||||
static? ( ${LIB_DEPEND} )"
|
||||
BDEPEND="
|
||||
nls? ( sys-devel/gettext )
|
||||
virtual/pkgconfig
|
||||
"
|
||||
src_prepare() {
|
||||
default
|
||||
if [[ ${PV} == "9999" ]] ; then
|
||||
eautoreconf
|
||||
fi
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
use static && append-ldflags -static
|
||||
local myconf=(
|
||||
--bindir="${EPREFIX}"/bin
|
||||
--htmldir=/trash
|
||||
$(use_enable !minimal color)
|
||||
$(use_enable !minimal multibuffer)
|
||||
$(use_enable !minimal nanorc)
|
||||
$(use_enable magic libmagic)
|
||||
$(use_enable spell speller)
|
||||
$(use_enable justify)
|
||||
$(use_enable debug)
|
||||
$(use_enable nls)
|
||||
$(use_enable unicode utf8)
|
||||
$(use_enable minimal tiny)
|
||||
$(usex ncurses --without-slang $(use_with slang))
|
||||
)
|
||||
econf "${myconf[@]}"
|
||||
}
|
||||
|
||||
src_install() {
|
||||
default
|
||||
# don't use "${ED}" here or things break (#654534)
|
||||
rm -r "${D}"/trash || die
|
||||
|
||||
dodoc doc/sample.nanorc
|
||||
docinto html
|
||||
dodoc doc/faq.html
|
||||
insinto /etc
|
||||
newins doc/sample.nanorc nanorc
|
||||
if ! use minimal ; then
|
||||
# Enable colorization by default.
|
||||
sed -i \
|
||||
-e '/^# include /s:# *::' \
|
||||
"${ED}"/etc/nanorc || die
|
||||
fi
|
||||
|
||||
use split-usr && dosym ../../bin/nano /usr/bin/nano
|
||||
}
|
||||
Reference in New Issue
Block a user