mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-21 10:37:22 -08:00
dev-vcs/tig: add 2.5.6
Signed-off-by: Patrick McLean <chutzpah@gentoo.org>
This commit is contained in:
@@ -2,3 +2,4 @@ DIST tig-2.5.1.tar.gz 1144666 BLAKE2B f8e96b1e27286ebebd3e3f374b28ed31a69b10bab1
|
||||
DIST tig-2.5.3.tar.gz 1165632 BLAKE2B 398174578b9723d7825c7162b59d2a1a92da161b3f3b8896c1d121ed36c8a0a1c52f676325b3a3fdd0cea9961c7f4234bd1ac594d9057cf6707cad22a3eda35b SHA512 2339c6c93808b6fbcda4ae29e014e7f4edda5f16df46e466d1d14a9f65dba10bff9df6363f37c369418336f362d5e38dbaf7fc4d99761997cc39722ba6132aec
|
||||
DIST tig-2.5.4.tar.gz 1167930 BLAKE2B 620dea0d5c4cd670b11e143195145dd268ba4762ce5b3e56a393bc6af6e508349c5f3581dff9f118d047ab8e7b431b64c85431f5af5719cbb9c63117394b265b SHA512 8c2c1d3aa980d3a6619501a770bb5210db445200e46939e2c122db1fd684ae9857eee4a06a8b6622d5d683457f11629522b121e0b429eec6d11dce4f4020dfb3
|
||||
DIST tig-2.5.5.tar.gz 1175752 BLAKE2B c77ff0990e5984df6a247cddb1729532719617178fb89143f1f78817f686cb357bc80678e8a1c245c338a40c20c69473b554d8af83381386821358495ed26f29 SHA512 63f617dfcbd89de715573caa92ca83906cefa6a5229876f1d5390b4b58442b0bec958065b798d4e81729dc87bf6dcd2a392fbbab2cd66ca16df6e2e9d6362ca3
|
||||
DIST tig-2.5.6.tar.gz 1176006 BLAKE2B eda766b32022fd6d849048107d9de90cb668ac594db1f46ee94984a5487f1a01c3109e3279c2c9e2260ef04ad7687b8c5eeb52ecf0b5e9d5c4b1f649aa23d46f SHA512 4d55061db43d64be9c97589d37305f6dcd85f1e7381012a9d61d21226dad456a86b16401fffe7763808dab62f07e17b2bcd17b9a30e1349e252be85f479e3741
|
||||
|
||||
@@ -0,0 +1,66 @@
|
||||
# Copyright 1999-2022 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
inherit bash-completion-r1
|
||||
|
||||
if [[ ${PV} == "9999" ]] ; then
|
||||
EGIT_REPO_URI="https://github.com/jonas/tig.git"
|
||||
inherit git-r3 autotools
|
||||
else
|
||||
SRC_URI="https://github.com/jonas/tig/releases/download/${P}/${P}.tar.gz"
|
||||
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
|
||||
fi
|
||||
|
||||
DESCRIPTION="text mode interface for git"
|
||||
HOMEPAGE="https://jonas.github.io/tig/"
|
||||
|
||||
LICENSE="GPL-2"
|
||||
SLOT="0"
|
||||
IUSE="pcre test unicode"
|
||||
REQUIRED_USE="test? ( unicode )"
|
||||
|
||||
DEPEND="
|
||||
sys-libs/ncurses:=[unicode(+)?]
|
||||
sys-libs/readline:0=
|
||||
pcre? ( dev-libs/libpcre2:= )
|
||||
"
|
||||
RDEPEND="
|
||||
${DEPEND}
|
||||
dev-vcs/git
|
||||
"
|
||||
[[ ${PV} == "9999" ]] && BDEPEND+=" app-text/asciidoc app-text/xmlto"
|
||||
|
||||
# encoding/env issues
|
||||
RESTRICT="test"
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
[[ ${PV} == "9999" ]] && eautoreconf
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
econf \
|
||||
$(use_with pcre) \
|
||||
$(use_with unicode ncursesw)
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
emake V=1
|
||||
[[ ${PV} == "9999" ]] && emake V=1 doc-man doc-html
|
||||
}
|
||||
|
||||
src_test() {
|
||||
# workaround parallel test failures
|
||||
LC_ALL=en_US.utf8 emake -j1 test
|
||||
}
|
||||
|
||||
src_install() {
|
||||
emake DESTDIR="${D}" install install-doc-man
|
||||
dodoc doc/manual.html README.html NEWS.html
|
||||
newbashcomp contrib/tig-completion.bash ${PN}
|
||||
|
||||
docinto examples
|
||||
dodoc contrib/*.tigrc
|
||||
}
|
||||
Reference in New Issue
Block a user