mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-21 22:47:14 -08:00
dev-vcs/git-cola: version bump to 3.11.0
use pytest/pytest-flake8 instead of nose for tests Closes: https://bugs.gentoo.org/822972 Signed-off-by: Martin Gysel <me@bearsh.org> Closes: https://github.com/gentoo/gentoo/pull/22892 Signed-off-by: Joonas Niilola <juippis@gentoo.org>
This commit is contained in:
@@ -1,3 +1,4 @@
|
||||
DIST git-cola-3.10.1.tar.gz 996036 BLAKE2B 2d705b853cf67a0f437d8dc77d46d5804124af600f872717c832843586d3c739e67a79ebe50ba2a8db38afd4217a7bb94db9cb8e27d51a00087ced340f4877d6 SHA512 79496023bfaa05049079eec2cdaf8449a6598faebedb4a13acf178209edc63e725eb1b003700a1dcfee09072d34e5a49d7053f070e45b498562cc124cd0582d4
|
||||
DIST git-cola-3.11.0.tar.gz 997046 BLAKE2B 7a8270c30e0cbd919dcd6f8e38ca420257630717e535ef11ed337fde2461b544453b20363906a5b769cd23d96ca77ce72d71729f46ae6abada83ae4d33628cbc SHA512 f05862b9b27ff5dfe9b220bbee4f3f455a7ce98acaa0bb0a8cdbb44f8cb97ce265df036ba48d5abb0bf46a91fd782cd73a67ca544b4662d36e8023e92c80b541
|
||||
DIST git-cola-3.8.tar.gz 980190 BLAKE2B 0502701c63f370b304a83094b2154757d1810216e82882472c7eac9633ac26eaa75974af05c32c18203d03b67a027655ea85c0e335915f204f668fcc86ed9c3f SHA512 9ae04dfef3b5bc64452a8df43e7afa93091f282097447208dadbd17522b62e5c43f7afce3eecc59fc4e38863496cdb41ac8b0453bbf327121629fbde20e45bb0
|
||||
DIST git-cola-3.9.tar.gz 992335 BLAKE2B ab591d953173aa69773a82eb91ebcc6fa5bc5e31efa78ad27f3e1e57e22c4222d70914f059dffb0b05b2b366d3208e127ad123ccfeb1b4c1b648daae0bf53352 SHA512 91f4bb40c166669e05136985920113d7482a396a46adf45fcf05e8ee56677fee7ebfb6a793face79737a17be42aa5e32b216a30847e8e4a5b8dc5b3b4eba5395
|
||||
|
||||
@@ -0,0 +1,109 @@
|
||||
# Copyright 1999-2021 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
PYTHON_COMPAT=( python3_{8..10} )
|
||||
DISTUTILS_SINGLE_IMPL=true
|
||||
DISTUTILS_USE_SETUPTOOLS=no
|
||||
inherit distutils-r1 readme.gentoo-r1 virtualx xdg-utils
|
||||
|
||||
DESCRIPTION="The highly caffeinated git GUI"
|
||||
HOMEPAGE="https://git-cola.github.io/"
|
||||
SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
|
||||
|
||||
LICENSE="GPL-2"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~x86"
|
||||
IUSE="doc test"
|
||||
|
||||
RESTRICT="!test? ( test )"
|
||||
|
||||
RDEPEND="
|
||||
$(python_gen_cond_dep '
|
||||
dev-python/numpy[${PYTHON_USEDEP}]
|
||||
dev-python/pygments[${PYTHON_USEDEP}]
|
||||
dev-python/QtPy[gui,network,${PYTHON_USEDEP}]
|
||||
dev-python/send2trash[${PYTHON_USEDEP}]
|
||||
')
|
||||
dev-vcs/git
|
||||
"
|
||||
BDEPEND="sys-devel/gettext
|
||||
$(python_gen_cond_dep "
|
||||
doc? ( dev-python/sphinx[\${PYTHON_USEDEP}] )
|
||||
test? (
|
||||
${VIRTUALX_DEPEND}
|
||||
dev-python/pytest[\${PYTHON_USEDEP}]
|
||||
dev-python/pytest-flake8[\${PYTHON_USEDEP}]
|
||||
dev-python/mock[\${PYTHON_USEDEP}]
|
||||
dev-python/PyQt5[\${PYTHON_USEDEP},gui,widgets]
|
||||
)
|
||||
")
|
||||
"
|
||||
|
||||
python_prepare_all() {
|
||||
# make sure that tests also use the system provided QtPy
|
||||
rm -r qtpy || die
|
||||
|
||||
rm share/git-cola/bin/*askpass* || die
|
||||
|
||||
# don't install docs into wrong location
|
||||
sed -i -e '/doc/d' setup.py || die
|
||||
|
||||
# fix doc directory reference
|
||||
sed -i \
|
||||
-e "s/'doc', 'git-cola'/'doc', '${PF}'/" \
|
||||
cola/resources.py || die
|
||||
|
||||
# fix ssh-askpass directory reference
|
||||
sed -i -e 's/resources\.share/resources\.prefix/' cola/app.py || die
|
||||
|
||||
distutils-r1_python_prepare_all
|
||||
}
|
||||
|
||||
python_configure_all() {
|
||||
DISTUTILS_ARGS=( --no-vendor-libs --no-private-libs )
|
||||
}
|
||||
|
||||
python_compile_all() {
|
||||
cd share/doc/${PN}/ || die
|
||||
if use doc ; then
|
||||
emake all
|
||||
else
|
||||
sed \
|
||||
-e '/^install:/s:install-html::g' \
|
||||
-e '/^install:/s:install-man::g' \
|
||||
-i Makefile || die
|
||||
fi
|
||||
}
|
||||
|
||||
python_test() {
|
||||
GIT_CONFIG_NOSYSTEM=true \
|
||||
PYTHONPATH="${S}:${S}/build/lib:${PYTHONPATH}" LC_ALL="C.utf8" \
|
||||
virtx epytest cola test
|
||||
}
|
||||
|
||||
python_install_all() {
|
||||
cd share/doc/${PN}/ || die
|
||||
emake \
|
||||
DESTDIR="${D}" \
|
||||
docdir="${EPREFIX}/usr/share/doc/${PF}" \
|
||||
prefix="${EPREFIX}/usr" \
|
||||
install
|
||||
|
||||
# remove empty bin folder
|
||||
rm -R "${ED}"/usr/share/git-cola/bin || die
|
||||
|
||||
use doc || HTML_DOCS=( "${FILESDIR}"/index.html )
|
||||
|
||||
distutils-r1_python_install_all
|
||||
readme.gentoo_create_doc
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
xdg_desktop_database_update
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
xdg_desktop_database_update
|
||||
}
|
||||
Reference in New Issue
Block a user