gui-libs/libpanel: new package, version 1.0.1

Signed-off-by: Guillermo Joandet <gjoandet@gmail.com>
Signed-off-by: Matt Turner <mattst88@gentoo.org>
This commit is contained in:
Guillermo Joandet
2022-10-12 20:26:55 -04:00
committed by Matt Turner
parent d6f9cebe09
commit 4dcd7d3bf3
3 changed files with 64 additions and 0 deletions
+1
View File
@@ -0,0 +1 @@
DIST libpanel-1.0.1.tar.xz 100852 BLAKE2B a55ac6c7c441f5c487553052dca66dd4c1efe1cc010c7202c3400df1d3fc3cfc8f886afdd796981cf14800ad34e49b8efbd274f2f97bce19600b8935a2f1f595 SHA512 5592b01e3a8c532d40e2190d1b2c332d8a104946c0813156119be98d433cd946ad839308b166ebdc399b853809e2fde90be8ea3acced053c2f11b86807163627
+55
View File
@@ -0,0 +1,55 @@
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit gnome.org meson vala xdg
DESCRIPTION="A dock/panel library for GTK 4"
HOMEPAGE="https://gitlab.gnome.org/GNOME/libpanel"
LICENSE="LGPL-3+"
SLOT="1"
KEYWORDS="~amd64"
IUSE="examples gtk-doc +introspection +vala"
REQUIRED_USE="
gtk-doc? ( introspection )
vala? ( introspection )
"
RDEPEND="
>=dev-libs/glib-2.72:2
>=gui-libs/gtk-4.6:4[introspection?]
>=gui-libs/libadwaita-1.0:1
introspection? ( >=dev-libs/gobject-introspection-1.54:= )
"
DEPEND="${RDEPEND}"
BDEPEND="
gtk-doc? ( >=dev-util/gi-docgen-2021.1 )
vala? ( $(vala_depend) )
"
src_prepare() {
default
use vala && vala_setup
xdg_environment_reset
}
src_configure() {
local emesonargs=(
$(meson_use examples install-examples)
$(meson_feature introspection)
$(meson_feature gtk-doc docs)
$(meson_use vala vapi)
)
meson_src_configure
}
src_install() {
meson_src_install
if use gtk-doc; then
mkdir "${ED}"/usr/share/gtk-doc || die
mv "${ED}"/usr/share/doc/panel-1.0 "${ED}"/usr/share/gtk-doc/ || die
fi
}
+8
View File
@@ -0,0 +1,8 @@
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<maintainer type="project">
<email>gnome@gentoo.org</email>
<name>Gentoo GNOME Desktop</name>
</maintainer>
</pkgmetadata>