xfce-base/xfdesktop: Bump to 4.19.5

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-base/xfdesktop/Manifest

@@ -1,2 +1,3 @@
 DIST xfdesktop-4.18.1.tar.bz2 2133258 BLAKE2B 3d4f54b64a6adc5f52bf6b48862b1fbf9b9608113035fdce89a2cb08a674f773f42edc0e1d05a27e89de7df71f7d53f400b794a2a79888cf51570c3ab060db8b SHA512 cafb1e274bbabf1704a6452532fc79657af26eaf92a58374f87a70f31c35fbf213319c6658b3d18bfca2d555b69e07e46949407d1f80e5a37f48e76bbde9dc3e
 DIST xfdesktop-4.19.4.tar.bz2 1917525 BLAKE2B eac15e57c4e711bbdbd7aa1a8037ffa2e9e7709557c477254107dbca8f68d8dc61ef653991aaed06c50a439ad81759a6fb9987dddbf94da27cf3e2a5fa9f444b SHA512 a3d323f60fc8edd2f3c83ffef95421e8af93c30dcbc85ce0a3ca5f2e9c1e42e121e608e9e0f29b8f7809495a90a29e4c1bfaa4dc4fe76b26c69b928eba2e0753
+DIST xfdesktop-4.19.5.tar.bz2 1933511 BLAKE2B 54dda17602639e5ec8760dd9ded44a011a1d9325d577685e4396260d59c2549019fd737d10fc23e3470e78d88b5b7aca6d02faa695f0d6c25e6e6e7e9e2417f5 SHA512 f5d9c2b8c11e141a5b9767150618c5eb07e904ecf0cb930ce242e354b0f48fe7a9237cc2b6cb35365cad63439937377c5e5d8861abb6645800b3e849a433b6e6

xfce-base/xfdesktop/xfdesktop-4.19.5.ebuild

@@ -0,0 +1,71 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit xdg-utils
+
+DESCRIPTION="Desktop manager for the Xfce desktop environment"
+HOMEPAGE="
+	https://docs.xfce.org/xfce/xfdesktop/start
+	https://gitlab.xfce.org/xfce/xfdesktop/
+"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+# CC for /usr/share/backgrounds, see backgrounds/README.md
+LICENSE="GPL-2+ CC-BY-SA-4.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="libnotify +thunar wayland X"
+REQUIRED_USE="|| ( wayland X )"
+
+DEPEND="
+	>=x11-libs/cairo-1.16
+	>=dev-libs/glib-2.72.0
+	>=x11-libs/gtk+-3.24.0:3[wayland?,X?]
+	>=xfce-base/exo-0.11:=
+	>=xfce-base/garcon-0.6:=
+	>=xfce-base/libxfce4ui-4.18.0:=
+	>=xfce-base/libxfce4util-4.13:=
+	>=xfce-base/libxfce4windowing-4.19.7:=[X?]
+	>=xfce-base/xfconf-4.18.0:=
+	libnotify? ( >=x11-libs/libnotify-0.7:= )
+	thunar? (
+		>=dev-libs/libyaml-0.2.5:=
+		>=xfce-base/thunar-4.17.10:=
+	)
+	wayland? ( >=gui-libs/gtk-layer-shell-0.7.0 )
+	X? ( >=x11-libs/libX11-1.6.7 )
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-libs/glib
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local myconf=(
+		$(use_enable wayland)
+		$(use_enable X x11)
+		$(use_enable thunar file-icons)
+		$(use_enable thunar thunarx)
+		$(use_enable libnotify notifications)
+		# these aren't run via make check, they are only for manual use
+		--disable-tests
+	)
+
+	econf "${myconf[@]}"
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}