media-libs/sdl3-mixer: add 3.2.4

Enable midi and fluidsynth by default

This prevents users from encountering unsatisfied dependency errors
when installing games that require this support. Choosing fluidsynth
also helps administrators select between providers.

Drop the obsolete warning about SDL_SOUNDFONTS: since commit
1320a491168d43f176f67af8a19decdc5cf24b30 it automatically searches for
sane defaults.

Bug: https://bugs.gentoo.org/421337
Signed-off-by: Pacho Ramos <pacho@gentoo.org>
This commit is contained in:
Pacho Ramos
2026-06-13 13:06:11 +02:00
parent 2fedb31d0f
commit 4d8ad8d1e2
2 changed files with 105 additions and 0 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST sdl3-mixer-3.0.0_pre20250404.tar.gz 3372186 BLAKE2B d874679a7b5a04c510b94564344d5d409f72ad24869a9c1e5789f4c33ee6e3518711b7c4ea299ee2c05cc4e832ea81042afd58db1113406a724e933f76fc7571 SHA512 077c32783540a0b430a84d2320322b136e9c327aca2af4f0588459c404e1814a064a6a448868fefb6d300575581e2546a24ed3eb917f9a6af93a7176642ea870
DIST sdl3-mixer-3.1.2_rc1.tar.gz 3550260 BLAKE2B 20da97f78d2247d009d6649ae54ad35604f66ffa8dc18ca16ed3fab35ce05f8db66b661a0c0d165028378a2ebb3ec7c9036fe917928ac166041345206ad69ae8 SHA512 3059ccf7d69861cec325a7d52fcfae7ac7760d4d97236ee4252d0587c0638df8e1d4a22d537e56438fc48668a4ac368c1db3599493821a5267d98d22e7449c18
DIST sdl3-mixer-3.2.4.tar.gz 5200314 BLAKE2B 75d65e8bd56bfbd0527f1ade94732537a4d6c9401a3600096f909943ee01534c3baedf4eda3d46b3d298cc1c3c5943d493748ffa9ae00dd48e75cd545e14b482 SHA512 f173ff0346c1645f665fc17c78021b0487fcb2742a6228663872afc0ff926c1f19e3e3c150f352020b7523bb5de924390980dd8978c4b223cde83a16048f0d2d
@@ -0,0 +1,104 @@
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake-multilib
DESCRIPTION="Simple Direct Media Layer Mixer Library"
HOMEPAGE="https://github.com/libsdl-org/SDL_mixer"
# Upstream use release- and prerelease- prefixed tags.
GIT_TAG=release-${PV}
if [[ ${PV} == *_rc* ]]; then
GIT_TAG=prerelease-${PV%%_rc*}
fi
SRC_URI="https://github.com/libsdl-org/SDL_mixer/archive/refs/tags/${GIT_TAG}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/SDL_mixer-${GIT_TAG}"
LICENSE="ZLIB"
SLOT="0"
KEYWORDS="~amd64 ~arm64"
IUSE="drlibs flac +fluidsynth gme +midi mod modplug mp3 opus playtools"
IUSE+=" +libvorbis timidity tremor +vorbis +wav wavpack xmp"
REQUIRED_USE="
drlibs? ( || ( flac mp3 ) )
midi? ( || ( fluidsynth timidity ) )
fluidsynth? ( midi )
timidity? ( midi )
vorbis? ( ^^ ( libvorbis tremor ) )
libvorbis? ( vorbis )
tremor? ( vorbis )
"
RDEPEND="
media-libs/libsdl3[${MULTILIB_USEDEP}]
!drlibs? (
flac? ( media-libs/flac:=[${MULTILIB_USEDEP}] )
mp3? ( media-sound/mpg123-base[${MULTILIB_USEDEP}] )
)
gme? ( media-libs/game-music-emu[${MULTILIB_USEDEP}] )
midi? (
fluidsynth? ( media-sound/fluidsynth:=[${MULTILIB_USEDEP}] )
timidity? ( media-sound/timidity++ )
)
mod? ( media-libs/libxmp[${MULTILIB_USEDEP}] )
opus? ( media-libs/opusfile[${MULTILIB_USEDEP}] )
playtools? (
!media-libs/sdl-mixer[playtools]
!media-libs/sdl2-mixer[playtools]
)
libvorbis? ( media-libs/libvorbis[${MULTILIB_USEDEP}] )
tremor? ( media-libs/tremor[${MULTILIB_USEDEP}] )
gme? ( media-libs/game-music-emu[${MULTILIB_USEDEP}] )
wavpack? ( media-sound/wavpack[${MULTILIB_USEDEP}] )
"
DEPEND="${RDEPEND}"
multilib_src_configure() {
local mycmakeargs=(
-DSDLMIXER_DEPS_SHARED=no # aka, no dlopen() (bug #950965)
-DSDLMIXER_FLAC=$(usex flac)
-DSDLMIXER_FLAC_LIBFLAC=$(usex flac $(usex drlibs no yes) no)
-DSDLMIXER_FLAC_DRFLAC=$(usex drlibs)
-DSDLMIXER_GME=$(usex gme)
-DSDLMIXER_GME_SHARED=no
-DSDLMIXER_INSTALL_MAN=yes
-DSDLMIXER_MIDI=$(usex midi)
-DSDLMIXER_MIDI_FLUIDSYNTH=$(usex fluidsynth)
-DSDLMIXER_MIDI_FLUIDSYNTH_SHARED=no
-DSDLMIXER_MIDI_TIMIDITY=$(usex timidity)
-DSDLMIXER_MOD=$(usex mod)
-DSDLMIXER_MOD_XMP=$(usex mod)
-DSDLMIXER_MOD_XMP_LITE=no
-DSDLMIXER_MOD_XMP_SHARED=no
-DSDLMIXER_MP3=$(usex mp3)
-DSDLMIXER_MP3_DRMP3=$(usex drlibs)
-DSDLMIXER_MP3_MPG123=$(usex mp3 $(usex drlibs no yes) no)
-DSDLMIXER_OPUS=$(usex opus)
-DSDLMIXER_OPUS_SHARED=no
-DSDLMIXER_STRICT=yes # Fail when a dependency could not be found
-DSDLMIXER_VENDORED=no # Use vendored third-party libraries
-DSDLMIXER_VORBIS_STB=no # Only available vendored, as per SDL_mixer#434 distros should prefer an external lib
-DSDLMIXER_VORBIS_VORBISFILE=$(usex vorbis $(usex libvorbis) no)
-DSDLMIXER_VORBIS_TREMOR=$(usex vorbis $(usex tremor) no)
-DSDLMIXER_WAVE=$(usex wav)
-DSDLMIXER_WAVPACK=$(usex wavpack)
-DSDLMIXER_WAVPACK_DSD=$(usex wavpack) # seems to be default-enabled in wavpack
)
cmake_src_configure
}
multilib_src_install_all() {
rm -r "${ED}"/usr/share/licenses || die
}
# There are no automated tests included with SDL_mixer.
# Theoretically we could use `-DSLDMIXER_TESTS{,_INSTALL}=yes` to build and install test binaries
# However they're not particularly useful standalone - runtime testing will have to do.
src_test() {
:
}