net-misc/electrum: Bump to 4.4.6

Signed-off-by: Michał Górny <mgorny@gentoo.org>

net-misc/electrum/Manifest

@@ -1 +1,2 @@
 DIST electrum-4.4.5.gh.tar.gz 5631717 BLAKE2B d780f3f466a337476e235bdb1eb6cd2eddb30bb3f4d9e28510f46594dab444e96d0515cea93ceb7ad4fcaa4b6372aaa80625cdfd3c137fe12e5410489582f5e6 SHA512 6eb91e51a2a0de440e0fe5407a6081a6e5ddd833b528f4a175d17d1b8799eb372f0ef0fa3f66a9b0136e39a7e83f238d33edc33c9bcc32e080f3fa9ac0166e24
+DIST electrum-4.4.6.gh.tar.gz 5637532 BLAKE2B c6b7667c7699f9eb11013c446e203ac4205df1d78e2fb8d44309bd6340c85bd9b4f6aef364f9bf9da4f262b58c74a7830c290c0659cd388b4a50863926dffa67 SHA512 e643a7119a8746d0f9ae02888bcdcf5ab4216ea19483113cf270b2cf23c8c615f0013a2aaf2c5f488655bf52cd190ab76761fa54f4b851039bc7add0c05ad320

net-misc/electrum/electrum-4.4.6.ebuild

@@ -0,0 +1,113 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+PYTHON_REQ_USE="ncurses?"
+
+inherit distutils-r1 xdg-utils
+
+DESCRIPTION="User friendly Bitcoin client"
+HOMEPAGE="
+	https://electrum.org/
+	https://github.com/spesmilo/electrum/
+"
+SRC_URI="
+	https://github.com/spesmilo/electrum/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cli ncurses qrcode +qt5"
+REQUIRED_USE="|| ( cli ncurses qt5 )"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	<dev-libs/libsecp256k1-0.4
+	>=dev-python/aiohttp-socks-0.3[${PYTHON_USEDEP}]
+	=dev-python/aiorpcX-0.22*[${PYTHON_USEDEP}]
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	dev-python/bitstring[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	>=dev-python/dnspython-2[${PYTHON_USEDEP}]
+	dev-python/pbkdf2[${PYTHON_USEDEP}]
+	dev-python/pyperclip[${PYTHON_USEDEP}]
+	dev-python/PySocks[${PYTHON_USEDEP}]
+	dev-python/qrcode[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	>=dev-python/protobuf-python-3.20[${PYTHON_USEDEP}]
+	qrcode? ( media-gfx/zbar[v4l] )
+	qt5? (
+		dev-python/PyQt5[gui,widgets,${PYTHON_USEDEP}]
+	)
+	ncurses? ( $(python_gen_impl_dep 'ncurses') )
+"
+BDEPEND="
+	test? (
+		dev-python/pyaes[${PYTHON_USEDEP}]
+		dev-python/pycryptodome[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# use backwards-compatible cryptodome API
+	sed -i -e 's:Cryptodome:Crypto:' electrum/crypto.py || die
+
+	# make qdarkstyle dep optional
+	sed -i -e '/qdarkstyle/d' contrib/requirements/requirements.txt || die
+
+	# remove upper bounds from deps
+	sed -i -e 's:,<[0-9.]*::' contrib/requirements/requirements.txt || die
+
+	local bestgui
+	if use qt5; then
+		bestgui=qt
+	elif use ncurses; then
+		bestgui=text
+	else
+		bestgui=stdio
+	fi
+	sed -i 's/^\([[:space:]]*\)\(config_options\['\''cwd'\''\] = .*\)$/\1\2\n\1config_options.setdefault("gui", "'"${bestgui}"'")\n/' ${PN}/${PN} || die
+
+	eapply_user
+
+	xdg_environment_reset
+	distutils-r1_src_prepare
+}
+
+src_install() {
+	dodoc RELEASE-NOTES
+	distutils-r1_src_install
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+
+	local v
+	for v in ${REPLACING_VERSIONS}; do
+		ver_test "${v}" -ge 4.3.4 && return
+	done
+
+	ewarn "If you are new to BitCoin, please be aware that:"
+	ewarn "1. Cryptocurrencies are volatile.  BTC has been subject to rapid"
+	ewarn "   changes of value in the past."
+	ewarn "2. Cryptocurrency ownership is determined solely by the access to"
+	ewarn "   the private key.  If the key is lost or stolen, BTC are unrevocably"
+	ewarn "   lost."
+	ewarn "3. Proof-of-work based cryptocurrencies have negative environmental"
+	ewarn "   impact.  BTC mining is consuming huge amounts of electricity."
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}