dev-util/sysdig: Merge "version bump to 0.1.104, #559218"

Pull-Request: https://github.com/gentoo/gentoo/pull/111

dev-util/sysdig/Manifest

@@ -1,2 +1,3 @@
+DIST sysdig-0.1.104.tar.gz 459784 SHA256 05a7ed95a1b73053cae0a77de199e84d7c9804014166527e3b211ed637c3fbab SHA512 5b2a3daeee5ce1860c3feb0e21796157f7228286df86432ec201d3ff6568458f2c2d77010b72de2f6c9cea0e7eb53ea112e988c9e83eb4df084754e0cd91b126 WHIRLPOOL b873e977403d9c36a10e77b85cbdb1bf72a70bd03b846a82c844964a57d8e84fded357e7ef7ec0ffff33c2724810eca8e19ba4c4265405f6ead446d09e41d409
 DIST sysdig-0.1.92.tar.xz 244728 SHA256 794ae6cef6ab8dae029979f5985b72c15f209e927518a3881e8a7624d77d5132 SHA512 661af8eece353ba0b0ea518496da89f4525f767c2797ff9f9e5caf670b6b3e7fa0c5cb14c3852971f563b665b42105a143d458a041b270d7107a403b2ec98b11 WHIRLPOOL bb47d717bcb3c5c948f4344a56e45996cfe275a48ea19f0fa12c2fce91f81fad317c9b5c05812e9c2aaf02240b597fb85f60a5ad3ee391a1a825de62a7eab57c
 DIST sysdig-0.1.98.tar.xz 263328 SHA256 5d60896ad2997f3dcf5d7252a53f5f7808ded11bd7c63f3a8c2aaaa1421f018f SHA512 8e4ab622fd0d69567e63054df256bfddda5765e2cf4d89490cd871625e4bb16d3d25ecbf0965f00e312d03ef3044615a7fd94d2f704b1a833ae1da9e2f66f33a WHIRLPOOL a96f8e8635d03351e4f42e8b3959c890a63a1232df5c9cc03f9359e18a926e23561e4f4fb10986285ff757e3ee47305a7fde01905541984e5582ba740962db70

dev-util/sysdig/sysdig-0.1.104.ebuild

@@ -0,0 +1,86 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit linux-mod bash-completion-r1 cmake-utils
+
+DESCRIPTION="A system exploration and troubleshooting tool"
+HOMEPAGE="http://www.sysdig.org/"
+SRC_URI="https://github.com/draios/sysdig/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+modules"
+
+RDEPEND="dev-lang/luajit:2=
+	>=dev-libs/jsoncpp-0.6_pre:0=
+	sys-libs/ncurses:0=
+	sys-libs/zlib:0="
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	virtual/os-headers"
+
+# needed for the kernel module
+CONFIG_CHECK="HAVE_SYSCALL_TRACEPOINTS TRACEPOINTS"
+
+pkg_pretend() {
+	use modules && linux-mod_pkg_setup
+}
+
+pkg_setup() {
+	use modules && linux-mod_pkg_setup
+}
+
+src_prepare() {
+	sed -i -e 's:-ggdb::' CMakeLists.txt || die
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# we will use linux-mod for that
+		-DBUILD_DRIVER=OFF
+		# libscap examples are not installed or really useful
+		-DBUILD_LIBSCAP_EXAMPLES=OFF
+
+		# unbundle the deps
+		-DUSE_BUNDLED_LUAJIT=OFF
+		-DLUAJIT_PREFIX="${EPREFIX}"/usr
+		-DLUAJIT_INCLUDE="${EPREFIX}"/usr/include/luajit-2.0
+		-DUSE_BUNDLED_JSONCPP=OFF
+		-DJSONCPP_PREFIX="${EPREFIX}"/usr
+		-DJSONCPP_INCLUDE="${EPREFIX}"/usr/include/jsoncpp
+		-DUSE_BUNDLED_ZLIB=OFF
+		-DUSE_BUNDLED_NCURSES=OFF
+		-DZLIB_PREFIX="${EPREFIX}"/usr
+	)
+
+	cmake-utils_src_configure
+
+	# setup linux-mod ugliness
+	MODULE_NAMES="sysdig-probe(extra:${BUILD_DIR}/driver:)"
+	BUILD_TARGETS="driver"
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	use modules && linux-mod_src_compile
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	use modules && linux-mod_src_install
+
+	# remove sources
+	rm -r "${ED%/}"/usr/src || die
+
+	# move bashcomp to the proper location
+	dobashcomp "${ED%/}"/usr/etc/bash_completion.d/sysdig || die
+	rm -r "${ED%/}"/usr/etc || die
+}