dev-python/pyatspi: bump to 2.32.1

Package-Manager: Portage-2.3.69, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

dev-python/pyatspi/Manifest

@@ -1 +1,2 @@
 DIST pyatspi-2.30.0.tar.xz 310672 BLAKE2B 76d51e6ce2f39305bcda8f706b5207738d3a2c0fd7480efb77c4dab8baf8ed6eb71263375ff0c16be0087e47f7f6b5eab99c6fc8992b83bdea6e64c92c381043 SHA512 a7af81bb55dff45d1bceced645f6aeb1adc1fa2a2b61fc39d9e97b6659e474636e5ac1af9923588311e651fee57b5e31a62ea5b2977b341eda43a5a736bf27ed
+DIST pyatspi-2.32.1.tar.xz 310896 BLAKE2B acf4a0211015daf5a19a796de9e267637ae77b2f79f0c6af20bfa5eb5a0fa0d4a62cf23524348299daebd515cccb7a4a1c18226e8c04356ea6439840613242a7 SHA512 6cdddc4275770a4f89e66355e18518f5cbf1ceeee1f27298be1fb5bb8b67676eeeb81ce7f4fbb5ad617573f574e5fd5858d363c77a0e5727d637ae7275429b03

dev-python/pyatspi/pyatspi-2.32.1.ebuild

@@ -0,0 +1,57 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_5,3_6} )
+
+inherit gnome2 python-r1
+
+DESCRIPTION="Python binding to at-spi library"
+HOMEPAGE="https://wiki.gnome.org/Accessibility"
+
+# Note: only some of the tests are GPL-licensed, everything else is LGPL
+LICENSE="LGPL-2 GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="" # test
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=dev-libs/atk-2.11.2
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	>=dev-python/pygobject-2.90.1:3[${PYTHON_USEDEP}]
+"
+RDEPEND="${COMMON_DEPEND}
+	>=sys-apps/dbus-1
+	>=app-accessibility/at-spi2-core-2.32[introspection]
+	!<gnome-extra/at-spi-1.32.0-r1
+"
+DEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	# https://bugzilla.gnome.org/show_bug.cgi?id=689957
+	"${FILESDIR}/${PN}-2.6.0-examples-python3.patch"
+)
+
+src_prepare() {
+	gnome2_src_prepare
+	python_copy_sources
+}
+
+src_configure() {
+	python_foreach_impl run_in_build_dir gnome2_src_configure --disable-tests
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir gnome2_src_compile
+}
+
+src_install() {
+	python_foreach_impl run_in_build_dir gnome2_src_install
+
+	docinto examples
+	dodoc examples/*.py
+}