dev-libs/librelp: bump to v1.2.18

Signed-off-by: Thomas Deutschmann <whissi@gentoo.org>
Package-Manager: Portage-2.3.50, Repoman-2.3.11

dev-libs/librelp/Manifest

@@ -1,2 +1,3 @@
 DIST librelp-1.2.16.tar.gz 474456 BLAKE2B b528aaa66e9d52d5304510f86400067e1baea44be487f8cb176aeb146924bc35af24a403e849376e74614fb060093b48a3afe9d6c5da56bbf4dc37a6740478cc SHA512 54c101281c94046e4f8d6f77e73ab52874408e62c77f3dfa29ec0b294f39c216637674cc0bf1b7e04173557b3f21bfa74b7be1aafa3ff2771acd41d1d067d3a3
 DIST librelp-1.2.17.tar.gz 506426 BLAKE2B 998d2845263655a43d0cb002c4538663047f2e07f62d6a870bf93e435c4b2d100a3cc9e4ab711233e9c1f73aedd8771e116b7c7139d2ad6d1baa7c483b2867a1 SHA512 4f69d3e4bc3052c0488a01def49dab16b54fc4a092e06f8776415cb1eca2282702a37497e43baf98fc038853d373116d6b58515c9ad91fae91fb3eb84706890f
+DIST librelp-1.2.18.tar.gz 506766 BLAKE2B 939bd2279e03a6431fbdfb787aa3d62b3f622ec3248dfc7c0a0a141294c27319081092a624c328374cdba0cbd51659301a77ad41bed27ba13f47601f7a607944 SHA512 7193438238b7019e7a4944d6d900a1fa5a369ff8a6b97a6dca7e82b6637c0f391ec3554eeeaa285881457cb2abe72fa1a893244ec9a36cc9d2e2592d58c5462a

dev-libs/librelp/librelp-1.2.18.ebuild

@@ -0,0 +1,75 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit autotools
+
+DESCRIPTION="An easy to use library for the RELP protocol"
+HOMEPAGE="http://www.librelp.com/"
+SRC_URI="http://download.rsyslog.com/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+ doc? ( FDL-1.3 )"
+
+# subslot = soname version
+SLOT="0/0.4.0"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~sparc ~x86"
+IUSE="debug doc +ssl +gnutls libressl openssl static-libs"
+REQUIRED_USE="ssl? ( ^^ ( gnutls openssl ) )
+	gnutls? ( ssl )
+	openssl? ( ssl )
+	libressl? ( openssl )"
+
+RDEPEND="ssl? (
+		gnutls? ( >=net-libs/gnutls-3.3.17.1:0= )
+		openssl? (
+			!libressl? ( dev-libs/openssl:0= )
+			libressl? ( dev-libs/libressl:0= )
+		)
+	)"
+
+DEPEND="ssl? (
+		gnutls? ( >=net-libs/gnutls-3.3.17.1:0= )
+		openssl? (
+			!libressl? ( dev-libs/openssl:0= )
+			libressl? ( dev-libs/libressl:0= )
+		)
+	)
+	virtual/pkgconfig"
+
+src_prepare() {
+	sed -i \
+		-e 's/ -g"/"/g' \
+		configure.ac || die "sed failed"
+
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-valgrind
+		$(use_enable debug)
+		$(use_enable gnutls tls)
+		$(use_enable openssl tls-openssl)
+		$(use_enable static-libs static)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_test() {
+	emake -j1 check
+}
+
+src_install() {
+	local DOCS=( ChangeLog )
+	use doc && local HTML_DOCS=( doc/relp.html )
+	default
+
+	if ! use static-libs; then
+		find "${ED%/}"/usr/lib* -name '*.la' -delete || die
+	fi
+}