dev-libs/liborcus: add 0.17.0

Signed-off-by: James Beddek <telans@posteo.de>
Signed-off-by: Sam James <sam@gentoo.org>

dev-libs/liborcus/Manifest

@@ -1 +1,2 @@
 DIST liborcus-0.16.1.tar.xz 1805436 BLAKE2B 7df89da5a175daa6fcf759d28f8a0eaebf3db6405af3b06a01b8dad41c7706acedc74876a0b68ff9cabd5780bb7cb311cd7c98390c9ecd265e62513eadde81eb SHA512 6d75591820af65181dd3a418f051a359695083f29c7d9c77edbcab3e89d9ea367824be0b19f27a31267525f446936145f5780a0ce3c6ee2d89823742837d4739
+DIST liborcus-0.17.0.tar.xz 1826696 BLAKE2B 4cab8696f698510de6c995aa6a3e59a8407297d6a60bac89ca7ffa1f74576de555c69a38de97eac63e2aed1817a3377ec7e15b1da7b5c01b49d049092d8756ff SHA512 1ac24f3c10973d0e0f6e3db7982391434631ec998ae07bb011fa8e000e48ca430c07a0c2588871a93b6d9bf7a19e30d4f05d34aef699dfce1f59a4556c7727e8

dev-libs/liborcus/liborcus-0.17.0.ebuild

@@ -0,0 +1,67 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8,9} )
+
+inherit autotools python-single-r1
+
+DESCRIPTION="Standalone file import filter library for spreadsheet documents"
+HOMEPAGE="https://gitlab.com/orcus/orcus/blob/master/README.md"
+
+if [[ ${PV} == *9999* ]]; then
+	MDDS_SLOT="1/9999"
+	EGIT_REPO_URI="https://gitlab.com/orcus/orcus.git"
+	inherit git-r3
+else
+	MDDS_SLOT="1/2.0"
+	SRC_URI="https://kohei.us/files/orcus/src/${P}.tar.xz"
+	# Unkeyworded while libreoffice has no release making use of this slot
+	# KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0/0.17" # based on SONAME of liborcus.so
+IUSE="python +spreadsheet-model test tools"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/boost:=[zlib(+)]
+	sys-libs/zlib
+	python? ( ${PYTHON_DEPS} )
+	spreadsheet-model? ( dev-libs/libixion:${SLOT} )
+"
+DEPEND="${RDEPEND}
+	dev-util/mdds:${MDDS_SLOT}
+"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	# bug 713586
+	use test && eapply "${FILESDIR}/${P}-test-fix.patch"
+
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-static
+		--disable-werror
+		$(use_enable python)
+		$(use_enable spreadsheet-model)
+		$(use_with tools)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -type f -delete || die
+}

dev-libs/liborcus/liborcus-9999.ebuild

@@ -1,10 +1,11 @@
 # Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
 PYTHON_COMPAT=( python3_{8..10} )
-inherit python-single-r1
+
+inherit autotools python-single-r1
 
 DESCRIPTION="Standalone file import filter library for spreadsheet documents"
 HOMEPAGE="https://gitlab.com/orcus/orcus/blob/master/README.md"
@@ -12,7 +13,7 @@ HOMEPAGE="https://gitlab.com/orcus/orcus/blob/master/README.md"
 if [[ ${PV} == *9999* ]]; then
 	MDDS_SLOT="1/9999"
 	EGIT_REPO_URI="https://gitlab.com/orcus/orcus.git"
-	inherit git-r3 autotools
+	inherit git-r3
 else
 	MDDS_SLOT="1/1.5"
 	SRC_URI="https://kohei.us/files/orcus/src/${P}.tar.xz"
@@ -20,7 +21,7 @@ else
 fi
 
 LICENSE="MIT"
-SLOT="0/0.16" # based on SONAME of liborcus.so
+SLOT="0/0.17" # based on SONAME of liborcus.so
 IUSE="python +spreadsheet-model tools"
 
 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
@@ -41,7 +42,7 @@ pkg_setup() {
 
 src_prepare() {
 	default
-	[[ ${PV} == *9999 ]] && eautoreconf
+	eautoreconf
 }
 
 src_configure() {