sci-geosciences/folium: add 0.16.0

Signed-off-by: Alfredo Tupone <tupone@gentoo.org>

sci-geosciences/folium/Manifest

@@ -1 +1,2 @@
 DIST folium-0.15.1.tar.gz 8400799 BLAKE2B c01c4029882aed5c1390be05a358c6c9e321e1562573bb1ae7246b462bc9183c21ba7631ca6b9a0e51311375f90f06bac5651c28505fa0d73c65942267ab2ce4 SHA512 fdc0b7bb0c864337b10d92e60090382d67d29e9158bb92c22ae53e749612d88427db95d34990c8895a04017ca1a5870330c6d9da3abb94e19ff6141b94f503c0
+DIST folium-0.16.0.tar.gz 8403284 BLAKE2B 443d8fc54ecdad8921d4467623ea4b8f6c22744df79ed25071e7937d38b1204f076432fc99f10ae23ddfebf89d4f7db19101e4aa54ceb1902bdad01af6f3ba2b SHA512 7dbaf3acdc0f5efbee8332bbc33ee002f1af22d53c662d434ace50e091dbaa9dde190d1f5f212be2a9d8abdcd5e5dbce0a916033c672c2327cc8b72f74eb69f4

sci-geosciences/folium/folium-0.16.0.ebuild

@@ -0,0 +1,49 @@
+# Copyright 2021-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+DISTUTILS_USE_PEP517=setuptools
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+inherit distutils-r1
+
+DESCRIPTION="Python Data, Leaflet.js Maps"
+HOMEPAGE="https://github.com/python-visualization/folium"
+SRC_URI="https://github.com/python-visualization/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.15.1-gentoo.patch
+)
+
+RDEPEND="sci-geosciences/xyzservices[${PYTHON_USEDEP}]
+	sci-libs/branca[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-python/setuptools-scm
+	test? (
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	rm -r tests/selenium || die # require chromedriver
+	rm tests/test_folium.py || die # require geopandas
+	rm tests/test_raster_layers.py || die # require xyzservices
+	rm tests/plugins/test_time_slider_choropleth.py || die # require geopandas
+	rm tests/test_repr.py || die # require geckodriver
+	default
+}
+
+python_test() {
+	epytest -m 'not web'
+}