gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-08-25 07:08:13 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/hatchling: Bump to 1.5.0

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2022-07-11 08:20:27 +02:00
parent 95b675b6d5
commit 4988afb790
2 changed files with 75 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/hatchling/Manifest
View File

@@ -1,3 +1,4 @@
DIST hatch-hatchling-v1.3.1.gh.tar.gz 220023 BLAKE2B db336126d8c5235eab57ca53e2f8832b9590513f40215ff4b51d1b60c43b0d971b472dc4434cfcf77406143a4ed3172a2fcd95d4c7d11a6f39ccd937f9eff9e6 SHA512 21fa8bd4ffe0bec5ae9f8b9716ce3b7ece45c6a62bc74f0cd49f759baaa5b21343bcc9f2a8e505f0b724b7d73a4c1f84c863a29e064e95f4aa1a288098adc8d3
DIST hatch-hatchling-v1.4.0.gh.tar.gz 229007 BLAKE2B 5a288a9de356fb06646ebb3eab95aee319d3e7d15a67d4a36cf52d0865a4ecd7ddd1e18db203c55136e950221f79572b152f9edf9398f52ecc927819e5a2f2fd SHA512 a104e092b2078eaeadfd6ea70b65bd8aabc91044e4e9fef4e1a54a61c138629e2a3963f26773e303f3cca0839ea63530849260b2d8c51b50fe67a3cdc5707029
DIST hatch-hatchling-v1.4.1.gh.tar.gz 229194 BLAKE2B 9d7b11244ce67d64a05f4a737966a8f037031275ae5b2ecde395c172232eb5bbf0f38df4f0048c6732641bafbf524670bc1e6dd9d441cc4297ef74126b56971b SHA512 b8dc8dfdc7e251cad4161f59acc724122f8f7083a1ce170722b7b5c31ccf22488e3871be76ea3fad058be2cce263752099c9b548759e16ba644daaba0eca63ba
DIST hatch-hatchling-v1.5.0.gh.tar.gz 232265 BLAKE2B 4fd57f7610831a025b9b0dddb89c4fe484d32d0b76a2d0cdafb76730b37c54af42ef27dc1c4d73061d888ce75806bd8f0fc70f5d39a077bd534716cf4e4a4db8 SHA512 9e5498b9da3a1f756e0f3e40daa63e45017588332da4197ac83b8402219bb9501b9c498dd881c5812b2b8903af591e4c6146aaf6dea8cc7b6bc664a85dee74e6

74
dev-python/hatchling/hatchling-1.5.0.ebuild Normal file
View File

@@ -0,0 +1,74 @@
# Copyright 2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=standalone
PYTHON_TESTED=( pypy3 python3_{8..11} )
PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
inherit distutils-r1
TAG=${P/-/-v}
MY_P=hatch-${TAG}
DESCRIPTION="Modern, extensible Python build backend"
HOMEPAGE="
https://pypi.org/project/hatchling/
https://github.com/pypa/hatch/
"
SRC_URI="
https://github.com/pypa/hatch/archive/${TAG}.tar.gz
-> ${MY_P}.gh.tar.gz
"
S=${WORKDIR}/${MY_P}/backend
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
RDEPEND="
>=dev-python/editables-0.2[${PYTHON_USEDEP}]
>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
>=dev-python/pathspec-0.9[${PYTHON_USEDEP}]
>=dev-python/pluggy-1.0.0[${PYTHON_USEDEP}]
>=dev-python/tomli-1.2.2[${PYTHON_USEDEP}]
"
BDEPEND="
${RDEPEND}
test? (
$(python_gen_cond_dep '
dev-python/atomicwrites[${PYTHON_USEDEP}]
dev-python/click[${PYTHON_USEDEP}]
dev-python/httpx[${PYTHON_USEDEP}]
dev-python/platformdirs[${PYTHON_USEDEP}]
dev-python/rich[${PYTHON_USEDEP}]
dev-python/tomli-w[${PYTHON_USEDEP}]
dev-python/virtualenv[${PYTHON_USEDEP}]
' "${PYTHON_TESTED[@]}")
)
"
distutils_enable_tests pytest
python_test() {
if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
einfo "Skipping tests on ${EPYTHON}"
return
fi
local -x EPYTEST_DESELECT=(
# these run pip to install stuff
tests/backend/dep/test_core.py::test_dependency_found
tests/backend/dep/test_core.py::test_extra_met
tests/backend/dep/test_core.py::test_extra_no_dependencies
tests/backend/dep/test_core.py::test_extra_unmet
tests/backend/dep/test_core.py::test_unknown_extra
tests/backend/dep/test_core.py::test_version_unmet
)
# top-level "tests" directory contains tests both for hatch
# and hatchling
cd "${WORKDIR}/${MY_P}" || die
local -x PYTHONPATH="src:${PYTHONPATH}"
epytest tests/backend
}