dev-vcs/tig: version bump to 2.3.3

dev-vcs/tig/Manifest

@@ -1,3 +1,4 @@
 DIST tig-2.2.2.tar.gz 1046910 BLAKE2B b88b48fd24257f32a5892a8a60cf13a51e553c4f0e18918e36fc6afea68befa6d12155f143bcebf37e1beab513cf1a39d50254ac76e406d97b5552389c048222 SHA512 e43cf8b4e7938342b581a1238222d5cbf62e242208cd65fc9b3261c4076b7c60c182f9a80613538fcf8b50187cc2844c22f6d1aeaaa8b23864670667a91dbfcd
 DIST tig-2.3.0.tar.gz 1080956 BLAKE2B 48eaa4803a189df8dd8456b58687d4a7cd3b13c003165fba3f705a3e15eb19d4d1e23f9cc1306c5463e21501ee547ce9551c2278d10a6b069cb49e7af93d449f SHA512 d5e8bf04689fdbeab4f2ee60eef1e8e7686827228dc2f87b20c40a3a1c31aa3476d5088423ba8bcb72616a9f0f211a2dbb631a72cc946553e41cb225ea60ab37
 DIST tig-2.3.2.tar.gz 1083036 BLAKE2B 382e17486e79348b72ec67b71db2c09276262b8a9b092e657814f9d3693f2c70c46dc54a7b05ef890497f55fbc41f2232603c936f16d26a0c4d9b73d0d9281fc SHA512 092e1ea876b077a5026ee7b820e908d1d7aaa340805eb4ff975791f88ba1983eab13af669f5e663b28dfdd9e014cb92ef8c164a335705b777be417e3a7d1d5fb
+DIST tig-2.3.3.tar.gz 1082818 BLAKE2B 0e9bcd02726b004c233a5efd7f58e4fda478dc1d2b738a7f8c086a3d71807d319ac8bd296b0f7c7569ed69a5b2b1db18e5c957cc5ce890a67b8f6ee7ead29551 SHA512 1d1cdf7184eeb3fea301c1959023f4aa97c4f8e25fc96cd61933ca39cf7549b6c7e1d9517f7ffd45d212ae9542ea4be07370b41c623cf6d0db8d025634b1d6d1

dev-vcs/tig/tig-2.3.3.ebuild

@@ -0,0 +1,60 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit bash-completion-r1
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://github.com/jonas/tig.git"
+	inherit git-r3 autotools
+else
+	SRC_URI="https://github.com/jonas/tig/releases/download/${P}/${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+fi
+
+DESCRIPTION="text mode interface for git"
+HOMEPAGE="https://jonas.github.io/tig/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="test unicode"
+REQUIRED_USE="test? ( unicode )"
+
+DEPEND="
+	sys-libs/ncurses:0=[unicode?]
+	sys-libs/readline:0="
+RDEPEND="${DEPEND}
+	dev-vcs/git"
+[[ ${PV} == "9999" ]] && DEPEND+=" app-text/asciidoc app-text/xmlto"
+
+# encoding/env issues
+RESTRICT="test"
+
+src_prepare() {
+	default
+	[[ ${PV} == "9999" ]] && eautoreconf
+}
+
+src_configure() {
+	econf $(use_with unicode ncursesw)
+}
+
+src_compile() {
+	emake V=1
+	[[ ${PV} == "9999" ]] && emake V=1 doc-man doc-html
+}
+
+src_test() {
+	# workaround parallel test failures
+	emake -j1 test
+}
+
+src_install() {
+	emake DESTDIR="${D}" install install-doc-man
+	dodoc doc/manual.html README.html NEWS.html
+	newbashcomp contrib/tig-completion.bash ${PN}
+
+	docinto examples
+	dodoc contrib/*.tigrc
+}

dev-vcs/tig/tig-9999.ebuild

@@ -1,4 +1,4 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
@@ -18,7 +18,8 @@ HOMEPAGE="https://jonas.github.io/tig/"
 
 LICENSE="GPL-2"
 SLOT="0"
-IUSE="unicode"
+IUSE="test unicode"
+REQUIRED_USE="test? ( unicode )"
 
 DEPEND="
 	sys-libs/ncurses:0=[unicode?]
@@ -27,6 +28,9 @@ RDEPEND="${DEPEND}
 	dev-vcs/git"
 [[ ${PV} == "9999" ]] && DEPEND+=" app-text/asciidoc app-text/xmlto"
 
+# encoding/env issues
+RESTRICT="test"
+
 src_prepare() {
 	default
 	[[ ${PV} == "9999" ]] && eautoreconf