x11-misc/mugshot: bump to version 0.4.2

Also added python3.7 support and bumped to EAPI=7.

Closes: https://bugs.gentoo.org/696564
Package-Manager: Portage-2.3.76, Repoman-2.3.17
Signed-off-by: Conrad Kostecki <conrad@kostecki.com>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

x11-misc/mugshot/Manifest

@@ -1 +1,2 @@
 DIST mugshot-0.4.1.tar.gz 121660 BLAKE2B ce0c0d4b76184f35e4ba5204b984393412924c0288b09fe51ec0e6635b1556e24ed98ce4a893ae57f25810bb39ce035fb40b6990e1b6516406cb0f670acdbac0 SHA512 f7790b3f80fc98d9b19e9b9dd74eafc41ae7598e38f70e148502056b4bd375922271cc72cf4664280f1449b2f5e1d89052ecc5d37c6dc453041e5312f736bbbe
+DIST mugshot-0.4.2.tar.gz 121020 BLAKE2B c092e25273dbd8ef9cbfbc001fb5f86b134ed8f9bf5d84993d5f46664f17eb74eda5c121ee70b5f0c4b0adb5aa1fc4d21d8c59d3f0cf4a4f67991d06690f5aa5 SHA512 721629cf4a7e4d84fd8505279cf88c88ac88c7b6c995ac84a2fd6a9b978c92716bbe20d7b0301ca70e99c007698e4cddf41b6cf1111bf496eec4d39591cd9ed1

x11-misc/mugshot/mugshot-0.4.2.ebuild

@@ -0,0 +1,70 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+
+inherit distutils-r1 gnome2-utils xdg-utils
+
+DESCRIPTION="A lightweight user-configuration application"
+HOMEPAGE="https://github.com/bluesabre/mugshot"
+SRC_URI="https://github.com/bluesabre/${PN}/archive/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gnome libreoffice webcam"
+
+RDEPEND="
+	dev-libs/gobject-introspection
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	dev-python/pexpect[${PYTHON_USEDEP}]
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	sys-apps/accountsservice
+	x11-libs/gtk+:3
+	gnome? ( gnome-base/gnome-control-center )
+	libreoffice? (
+		|| (
+			app-office/libreoffice-bin
+			app-office/libreoffice
+		)
+	)
+	webcam? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-good:1.0
+		gnome? (
+			media-libs/clutter-gtk[introspection]
+			media-video/cheese[introspection]
+		)
+	)
+"
+
+DEPEND="
+	${RDEPEND}
+	dev-python/python-distutils-extra[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	dev-util/intltool
+"
+
+S="${WORKDIR}/${PN}-${P}"
+
+python_install() {
+	distutils-r1_python_install
+
+	# Since DOCS are installed twice, remove the wrong path
+	rm -r "${ED%/}"/usr/share/doc/mugshot || die
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_icon_cache_update
+}