dev-python/jupyter-client: Bump to 8.10.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/jupyter-client/Manifest

@@ -1 +1,2 @@
+DIST jupyter_client-8.10.0.tar.gz 360653 BLAKE2B 9eb7fb09de6d56d9ee0289c5a5a73edc24b11596ad0bf4b137ab666cadcf49136c383cecd8d0be2840505e50e20af872a7876742e274d6bd1391753c151fb315 SHA512 f8f1966b1aacd997fd3876dd4f213e782906db13d01e2a27a8f8ebaa9b3974887aab945288e0de52657b358ac5dfadbb8d7fe9bb6af16041739d7b3366a02fed
 DIST jupyter_client-8.9.1.tar.gz 359256 BLAKE2B e02afbe26352908302a48e552915c94a08087fbb271c5895a890c599853591f4d19f7b15687dfc1e32cf25ff837b8c2080e53b524274b7d5e85603adb789e35c SHA512 8a125344a458bfa4102a8895220a659b39fc72e2a0a9ee99ca3d25471c2bc4b09b307c17d6c1103501ad4eff058269ed0688239aa8f4d753ff079d9de014822b

dev-python/jupyter-client/jupyter-client-8.10.0.ebuild

@@ -0,0 +1,51 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{12..14} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Jupyter protocol implementation and client libraries"
+HOMEPAGE="
+	https://jupyter.org/
+	https://github.com/jupyter/jupyter_client/
+	https://pypi.org/project/jupyter-client/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+
+RDEPEND="
+	>=dev-python/jupyter-core-5.1[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.8.2[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-25.0[${PYTHON_USEDEP}]
+	>=dev-python/tornado-6.4.1[${PYTHON_USEDEP}]
+	dev-python/traitlets[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-4.13.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/ipykernel-6.14[${PYTHON_USEDEP}]
+		dev-python/msgpack[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_RERUNS=3
+EPYTEST_PLUGINS=( anyio pytest-{jupyter,timeout} )
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO: times out
+		tests/test_client.py::TestAsyncKernelClient::test_input_request
+		# TODO
+		tests/test_multikernelmanager.py::TestKernelManager::test_tcp_cinfo
+	)
+
+	epytest -o tmp_path_retention_policy=all
+}