www-client/epiphany: add 49.2

Signed-off-by: Pacho Ramos <pacho@gentoo.org>

www-client/epiphany/Manifest

@@ -1,3 +1,4 @@
 DIST epiphany-47.7.tar.xz 4100068 BLAKE2B e3238eb590e5c3850ff7c147cb5068496b3802a51a3d2b4732cbed06f0c4def6bd8ef7d152d281b22bdb8fa2f7f582bd1d703e71e87192212d88df69a56f72bf SHA512 147d3c60492d2e7fb469244ce6e47b6898cb9b6eef0856dd09341101a07579b9c5abf6f296c8083c9f1b1d64b642d05910c58f638f8003eda73c9236e1d8a5e2
 DIST epiphany-48.3.tar.xz 4119780 BLAKE2B cadacd8448f389e7971df7088905bd2f411c58a589d6f3c99e490d3f8bb1928c88c4df96d97180a2c292622c8d1d8c715b83329b1d3f60a55dcdcf8e81846016 SHA512 297df0d500477134c12877bc4255ea5f8e22b782a08fa5e06a1b012d4ff18f85f09850f7bf12ff61c35d0aba82cd87afd50dbdbecda62319cea86314c2947923
 DIST epiphany-48.5.tar.xz 4113932 BLAKE2B 648450e68b35d1bc7d6cb3680a6735d7c2da20e47c2da294bd6424fa574cad042ea1935cf1cd8634bd31e3651c53161a01359af36591c4f0523b9000487e695b SHA512 b70c387d1617cdcc81ff63c1c8ff08cf657220e6a5aad0ec07cbf90508e9270af9a2fead0f6a3b71905a70d3293c60230478d21b3b1d1fc2bdcbf2736289deca
+DIST epiphany-49.2.tar.xz 4207096 BLAKE2B 17111548dfa57e0d6a4ee7b30584439c180a0bf18b19748790c2d0fec0743c2941a8b975f59a407e340b22c12dff11c0b196cfd7ef51f15ffc497a67d2262050 SHA512 98ec4585718c1cef1afb99e9020d4e32228c8144f2f39a57bc117fd7f274a950a775f55c17ffd664dd6d80558e2d5401c3ead13111efbfe98a442daabff7a7fd

www-client/epiphany/epiphany-49.2.ebuild

@@ -0,0 +1,91 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson xdg virtualx
+
+DESCRIPTION="GNOME webbrowser based on Webkit"
+HOMEPAGE="https://apps.gnome.org/Epiphany/"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	>=x11-libs/cairo-1.2
+	>=app-crypt/gcr-3.9.0:4=[gtk]
+	>=x11-libs/gdk-pixbuf-2.36.5:2
+	>=dev-libs/glib-2.74.0:2
+	gnome-base/gsettings-desktop-schemas
+	media-libs/gstreamer:1.0
+	>=gui-libs/gtk-4.13.3:4
+	>=app-text/iso-codes-0.35
+	>=dev-libs/json-glib-1.6
+	app-arch/libarchive:=
+	>=gui-libs/libadwaita-1.8_alpha:1
+	>=app-crypt/libsecret-0.19
+	>=net-libs/libsoup-2.99.4:3.0
+	>=dev-libs/libxml2-2.6.12:2=
+	>=dev-libs/nettle-3.4:=
+	>=dev-libs/libportal-0.6:0=[gtk]
+	>=dev-db/sqlite-3.22:3
+	>=net-libs/webkit-gtk-2.43.4:6
+
+	dev-libs/gmp:0=
+"
+RDEPEND="${DEPEND}
+	x11-themes/adwaita-icon-theme
+"
+# appstream-glib needed for appdata.xml gettext translation
+BDEPEND="
+	dev-libs/appstream-glib
+	dev-python/docutils
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	# Test not ready to be run in sandboxed systems, also need
+	# mesa[zink]. Skip, as done by Debian.
+	# https://bugs.gentoo.org/928015
+	# https://bugs.gentoo.org/847862
+	# https://gitlab.gnome.org/GNOME/epiphany/-/issues/2209
+	# https://gitlab.gnome.org/GNOME/epiphany/-/issues/2271
+	"${FILESDIR}/${PN}-46.2-disable-web-view-test.patch"
+)
+
+src_prepare() {
+	default
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddeveloper_mode=false
+		-Dtech_preview=false
+		$(meson_feature test unit_tests)
+		-Dgranite=disabled
+		-Dman-pages=enabled
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}