dev-python/starlette: Add dependency on dev-python/python-multipart

It is an optional dependency but it is relatively small and starlette
is not widely used, so should be no big deal to pull it unconditionally.

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/starlette/starlette-0.21.0-r1.ebuild

@@ -0,0 +1,49 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="The little ASGI framework that shines"
+HOMEPAGE="
+	https://www.starlette.io/
+	https://github.com/encode/starlette/
+	https://pypi.org/project/starlette/
+"
+SRC_URI="
+	https://github.com/encode/starlette/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	<dev-python/anyio-5[${PYTHON_USEDEP}]
+	>=dev-python/anyio-3.4.0[${PYTHON_USEDEP}]
+	>=dev-python/httpx-0.22.0[${PYTHON_USEDEP}]
+	dev-python/itsdangerous[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/python-multipart[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/typing-extensions-3.10.0[${PYTHON_USEDEP}]
+	' 3.8 3.9)
+"
+BDEPEND="
+	test? (
+		dev-python/trio[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_IGNORE=(
+	# Unpackaged 'databases' dependency
+	tests/test_database.py
+)
+
+distutils_enable_tests pytest