dev-python/aesara: Bump to 2.6.4

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/aesara/Manifest

@@ -1,2 +1,3 @@
 DIST aesara-rel-2.5.3.tar.gz 8191431 BLAKE2B 698bc3b6f7e84288be3318796989d13d7de92f72c66abfa83b14c08f6310f974f7381d729e712c2bd5e76f398d74a3c5dc03d7515a22254261312e586e3fd461 SHA512 5c1ad9d6ad1fb58be1477713d863f2b1371544ea8293d8e9e1a690860a0483b83c9558827856a2546498bab26360f141a5ee97d4c7f3f2aad773e84f9766a59b
 DIST aesara-rel-2.6.3.tar.gz 7845423 BLAKE2B 66b84a10337efc01e37d82793da56b61b1825829d982e24e0f93ebb67cd3c22e5bb2e37c71ab8bd9648b039efaf4c667dc53df2a9613ba9370c2138eb74ca400 SHA512 e0a804c0c3c1cd24753a237c386df9600d2b01cf4991aeca3d794df4068f584a9ab5341b72fa5695ccb9d06f1e4954f450436e3a7ebe4c2efc1354a5c2e5979d
+DIST aesara-rel-2.6.4.tar.gz 7845688 BLAKE2B bfd0222c2a8d8e22abb56b785b73a121032832417562046445b8e0b2f6461326ba760d1839fd1acac2215a1547ed48d613998cb4915a07521f4d976a32a811b9 SHA512 a9f47bb4718fab974a35d7eab1b2a5ab8ea7d911dd9d92a791763a659f96b52b9832532e5e13aad10ac8e2f0927d2cc3e97c09e84046fee125925b3ac2898893

dev-python/aesara/aesara-2.6.4.ebuild

@@ -0,0 +1,80 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1 multiprocessing optfeature
+
+MY_P=aesara-rel-${PV}
+DESCRIPTION="Library for operating on mathematical expressions with multi-dimensional arrays"
+HOMEPAGE="
+	https://github.com/aesara-devs/aesara/
+	https://pypi.org/project/aesara/
+"
+SRC_URI="
+	https://github.com/aesara-devs/aesara/archive/rel-${PV}.tar.gz
+		-> ${MY_P}.tar.gz
+"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/cons[${PYTHON_USEDEP}]
+	dev-python/etuples[${PYTHON_USEDEP}]
+	dev-python/logical-unification[${PYTHON_USEDEP}]
+	dev-python/minikanren[${PYTHON_USEDEP}]
+	dev-python/filelock[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.17.0[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx doc 'dev-python/sphinx_rtd_theme'
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# speed tests are unreliable
+		tests/scan/test_basic.py::test_speed
+		tests/scan/test_basic.py::test_speed_rnn
+		tests/scan/test_basic.py::test_speed_batchrnn
+		tests/link/test_vm.py::test_speed
+		tests/link/test_vm.py::test_speed_lazy
+		tests/tensor/test_gc.py::test_merge_opt_runtime
+
+		# rounding problem?
+		# https://github.com/aesara-devs/aesara/issues/477
+		tests/tensor/test_math_scipy.py::TestGammaUBroadcast::test_good
+		tests/tensor/test_math_scipy.py::TestGammaUInplaceBroadcast::test_good
+	)
+	local EPYTEST_IGNORE=(
+		# we do not package numba
+		tests/link/test_numba.py
+		tests/link/test_numba_performance.py
+	)
+
+	epytest -n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
+}
+
+python_compile() {
+	esetup.py build_py
+	distutils-r1_python_compile
+	rm "${BUILD_DIR}/install$(python_get_sitedir)/bin/__init__.py" || die
+}
+
+pkg_postinst() {
+	optfeature "GPU code generation/execution on NVIDIA gpus" dev-util/nvidia-cuda-toolkit dev-util/nvidia-cuda-sdk
+	optfeature "GPU/CPU code generation on CUDA and OpenCL devices" dev-libs/libgpuarray dev-python/pycuda
+}