net-analyzer/tracebox: migrate to lua-single.eclass

Autoconf-based. With the eclass-created wrapper, builds and installs fine
against all Lua implementations currently in the tree.

Closes: https://bugs.gentoo.org/752786
Signed-off-by: Marek Szuba <marecki@gentoo.org>

net-analyzer/tracebox/tracebox-0.4.4-r100.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..4} luajit )
+
+inherit autotools lua-single
+
+DESCRIPTION="A Middlebox Detection Tool"
+HOMEPAGE="http://www.tracebox.org/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="curl sniffer"
+
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+RDEPEND="${LUA_DEPS}
+	>=net-libs/libcrafter-0.3_p20171019
+	dev-libs/json-c
+	net-libs/libpcap
+	curl? ( net-misc/curl )
+	sniffer? ( net-libs/libnetfilter_queue )
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	virtual/pkgconfig
+"
+RESTRICT="test"
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.4.4-deps.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i -e '/SUBDIRS/s|noinst||g' Makefile.am || die
+	sed -i -e '/DIST_SUBDIRS.*libcrafter/d' noinst/Makefile.am || die
+
+	sed -i \
+		-e '/[[:graph:]]*libcrafter[[:graph:]]*/d' \
+		-e '/dist_bin_SCRIPTS/d' \
+		src/${PN}/Makefile.am \
+		|| die
+
+	sed -i \
+		-e 's|"crafter.h"|<crafter.h>|g' \
+		src/${PN}/PacketModification.h \
+		src/${PN}/PartialHeader.h \
+		src/${PN}/script.h \
+		src/${PN}/${PN}.h \
+		|| die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable curl) \
+		$(use_enable sniffer)
+}

profiles/package.mask

@@ -548,6 +548,7 @@ kde-apps/kdebase-meta:5
 >=net-analyzer/rrdtool-1.7.2-r100
 >=net-analyzer/snort-2.9.16-r100
 >=net-analyzer/suricata-6.0.1-r100
+>=net-analyzer/tracebox-0.4.4-r100
 >=net-analyzer/wireshark-3.4.2-r100
 >=net-dns/dnsmasq-2.82-r100
 >=net-im/prosody-0.11.7-r100