mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-06 00:48:18 -07:00
sys-apps/fwupd: Bump to version 1.4.2
Package-Manager: Portage-2.3.99, Repoman-2.3.22 Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
This commit is contained in:
Lars Wendler
@@ -2,3 +2,4 @@ DIST fwupd-1.2.11.tar.gz 1945646 BLAKE2B 4eb6d5008d0e515880147a94b2632ed70b5f7ab
|
||||
DIST fwupd-1.3.8.tar.gz 2246170 BLAKE2B b55df322c64947bcccc7bf05daaec2c5b2f646a4e53d757482dcd4d33e94d725315e6456bf69d5dbca3ef870437e1cc2a861537fc7af9b059497f119f08477de SHA512 0f0aa380adc5e167e49db4261b50bee9c905786afcd44b5fe221f42a77306219d40888989e0b16448535eaf077baed12de56b6cca42f91fca09c4a8384f243e4
|
||||
DIST fwupd-1.3.9.tar.gz 2254260 BLAKE2B ead64be3eca00fd2d045fb6c5ccd42d8913fa056736e6ae039feef70b6edababe50fb0552db39bf057750d3f0d2224b18b7ecf5a5a408a1f1ac3023d89687f68 SHA512 b81ef1f683082e4c49ab8acd8848118fed1383d4e3e73967daaa68927e553a5bc4973004d3dd26b268b901c5deb1f9238a98537d24cfd957162f508c9622e1e4
|
||||
DIST fwupd-1.4.1.tar.gz 2301866 BLAKE2B 057c7cdc4449aa67540719e6b7b1f073e8b247aa80dd99cb4b1c4ebf7c368c5089ddc25200bb0a42706196e3025c21a5d09f5f507d52e5c0fc5fc6d5c1eacd46 SHA512 abec0c2d66bd7e256cefa5e0ce59bbf339ea2ffb6173671c7f6cf8893b0931c16c48c47153507bc1af3f31157dba8bddf566bba1b62b8a722fa1f50780a1f921
|
||||
DIST fwupd-1.4.2.tar.gz 2304086 BLAKE2B 9a725cc49479984c3a98b75e9c52211a26f81d4a7ecec3b261ff4486201a967a6c82df9a1dbd591b91d9cd6eb9d1a8cd8cccfd2c8dd98d5bb3f82cb03bbd0a52 SHA512 b092eedf3e5e84874de1fddb7f14ca87975d5895721ac4f87b6c88ec7c7b2367e573b30906588f9adad4cea52da5ebbaaa4a9c38a2273e8f31d26399e719166e
|
||||
|
||||
158
sys-apps/fwupd/fwupd-1.4.2.ebuild
Normal file
158
sys-apps/fwupd/fwupd-1.4.2.ebuild
Normal file
@@ -0,0 +1,158 @@
|
||||
# Copyright 1999-2020 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=7
|
||||
|
||||
PYTHON_COMPAT=( python3_{6,7,8} )
|
||||
|
||||
inherit linux-info meson python-single-r1 vala xdg toolchain-funcs
|
||||
|
||||
DESCRIPTION="Aims to make updating firmware on Linux automatic, safe and reliable"
|
||||
HOMEPAGE="https://fwupd.org"
|
||||
SRC_URI="https://github.com/hughsie/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
|
||||
|
||||
LICENSE="LGPL-2.1+"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~arm ~x86"
|
||||
IUSE="agent amt consolekit dell gtk-doc elogind minimal introspection +man nvme redfish synaptics systemd test thunderbolt tpm uefi"
|
||||
REQUIRED_USE="${PYTHON_REQUIRED_USE}
|
||||
^^ ( consolekit elogind minimal systemd )
|
||||
dell? ( uefi )
|
||||
minimal? ( !introspection )
|
||||
"
|
||||
RESTRICT="!test? ( test )"
|
||||
|
||||
BDEPEND="$(vala_depend)
|
||||
virtual/pkgconfig
|
||||
gtk-doc? ( dev-util/gtk-doc )
|
||||
introspection? ( dev-libs/gobject-introspection )
|
||||
man? (
|
||||
app-text/docbook-sgml-utils
|
||||
sys-apps/help2man
|
||||
)
|
||||
test? (
|
||||
thunderbolt? ( dev-util/umockdev )
|
||||
net-libs/gnutls[tools]
|
||||
)
|
||||
"
|
||||
DEPEND="${PYTHON_DEPS}
|
||||
>=app-arch/gcab-1.0
|
||||
app-arch/libarchive:=
|
||||
dev-db/sqlite
|
||||
>=dev-libs/glib-2.45.8:2
|
||||
dev-libs/json-glib
|
||||
dev-libs/libgpg-error
|
||||
dev-libs/libgudev:=
|
||||
>=dev-libs/libgusb-0.2.9[introspection?]
|
||||
>=dev-libs/libjcat-0.1.0[gpg,pkcs7]
|
||||
>=dev-libs/libxmlb-0.1.13
|
||||
$(python_gen_cond_dep '
|
||||
dev-python/pillow[${PYTHON_MULTI_USEDEP}]
|
||||
dev-python/pycairo[${PYTHON_MULTI_USEDEP}]
|
||||
dev-python/pygobject:3[cairo,${PYTHON_MULTI_USEDEP}]
|
||||
')
|
||||
>=net-libs/libsoup-2.51.92:2.4[introspection?]
|
||||
virtual/libelf:0=
|
||||
virtual/udev
|
||||
consolekit? ( >=sys-auth/consolekit-1.0.0 )
|
||||
dell? (
|
||||
sys-libs/efivar
|
||||
>=sys-libs/libsmbios-2.4.0
|
||||
)
|
||||
elogind? ( sys-auth/elogind )
|
||||
!minimal? (
|
||||
>=sys-auth/polkit-0.103
|
||||
)
|
||||
nvme? ( sys-libs/efivar )
|
||||
redfish? ( sys-libs/efivar )
|
||||
systemd? ( >=sys-apps/systemd-211 )
|
||||
tpm? ( app-crypt/tpm2-tss )
|
||||
uefi? (
|
||||
app-crypt/tpm2-tss
|
||||
media-libs/fontconfig
|
||||
media-libs/freetype
|
||||
sys-boot/gnu-efi
|
||||
sys-boot/efibootmgr
|
||||
>=sys-libs/efivar-33
|
||||
x11-libs/cairo
|
||||
)
|
||||
"
|
||||
# Block sci-chemistry/chemical-mime-data for bug #701900
|
||||
RDEPEND="
|
||||
!<sci-chemistry/chemical-mime-data-0.1.94-r4
|
||||
${DEPEND}
|
||||
sys-apps/dbus
|
||||
"
|
||||
|
||||
PATCHES=(
|
||||
"${FILESDIR}/${PN}-1.3.9-logind_plugin.patch"
|
||||
)
|
||||
|
||||
pkg_setup() {
|
||||
python-single-r1_pkg_setup
|
||||
if use nvme; then
|
||||
kernel_is -ge 4 4 || die "NVMe support requires kernel >= 4.4"
|
||||
fi
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
# c.f. https://github.com/fwupd/fwupd/issues/1414
|
||||
sed -e "/test('thunderbolt-self-test', e, env: test_env, timeout : 120)/d" \
|
||||
-i plugins/thunderbolt/meson.build || die
|
||||
vala_src_prepare
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local emesonargs=(
|
||||
--localstatedir "${EPREFIX}"/var
|
||||
-Dbuild="$(usex minimal standalone all)"
|
||||
$(meson_use agent)
|
||||
$(meson_use amt plugin_amt)
|
||||
$(meson_use consolekit)
|
||||
$(meson_use dell plugin_dell)
|
||||
$(meson_use elogind)
|
||||
$(meson_use gtk-doc gtkdoc)
|
||||
$(meson_use man)
|
||||
$(meson_use nvme plugin_nvme)
|
||||
$(meson_use redfish plugin_redfish)
|
||||
$(meson_use synaptics plugin_synaptics)
|
||||
$(meson_use systemd)
|
||||
$(meson_use test tests)
|
||||
$(meson_use thunderbolt plugin_thunderbolt)
|
||||
$(meson_use tpm plugin_tpm)
|
||||
$(meson_use uefi plugin_uefi)
|
||||
# Although our sys-apps/flashrom package now provides
|
||||
# libflashrom.a, meson still can't find it
|
||||
-Dplugin_flashrom="false"
|
||||
# Dependencies are not available (yet?)
|
||||
-Dplugin_modem_manager="false"
|
||||
)
|
||||
export CACHE_DIRECTORY="${T}"
|
||||
meson_src_configure
|
||||
}
|
||||
|
||||
src_install() {
|
||||
meson_src_install
|
||||
|
||||
if ! use minimal ; then
|
||||
sed "s@%SEAT_MANAGER%@$(usex elogind elogind consolekit)@" \
|
||||
"${FILESDIR}"/${PN}-r1 \
|
||||
> "${T}"/${PN} || die
|
||||
doinitd "${T}"/${PN}
|
||||
|
||||
if ! use systemd ; then
|
||||
# Don't timeout when fwupd is running (#673140)
|
||||
sed '/^IdleTimeout=/s@=[[:digit:]]\+@=0@' \
|
||||
-i "${ED}"/etc/${PN}/daemon.conf || die
|
||||
fi
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
xdg_pkg_postinst
|
||||
elog "In case you are using openrc as init system"
|
||||
elog "and you're upgrading from <fwupd-1.1.0, you"
|
||||
elog "need to start the fwupd daemon via the openrc"
|
||||
elog "init script that comes with this package."
|
||||
}
|
||||
Reference in New Issue
Block a user