x11-wm/lumina: bump to 1.6.0

Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Andrey Grozin <grozin@gentoo.org>

x11-wm/lumina/Manifest

@@ -1 +1,2 @@
 DIST lumina-1.5.0.tar.gz 20657364 BLAKE2B 62b064e1be3ce69c078e68524e011a8ce4d61c680a4732da7992a7b72833363fceb0a0895a228ec9de7921d989253c70c518810b91c23226aded1f54b23b1aea SHA512 37106d71a9ba7188c4ded0614d2d4424f732519e11288ae312dfcd9a0b5b26dd31dfa812e74a96c0e3e0fb99fae4dc00806fd7a24183746688c72d997054af7d
+DIST lumina-1.6.0.tar.gz 20662000 BLAKE2B c016f07fb86333e792d6a0a0ddaa9ea09f322d6de69d099abf9340d7db6cb9e23624b62882579ba6c13eec71fcf663f1688424fd940cd7e09e625f6fcc4b281f SHA512 e923961568ab9cc32206386066daef8cd1fd2db2d5c3e260e5c1da1dcda39a516576418f607cefbe5a1c47d8684591d0e595fb344e7d6aa2859fc3b326e73e30

x11-wm/lumina/lumina-1.6.0.ebuild

@@ -0,0 +1,96 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PLOCALES="af ar az bg bn bs ca cs cy da de el en_AU en_GB en_ZA es et eu fa fi fr fr_CA fur gl he hi hr hu id is it ja ka ko lt lv mk mn ms mt nb ne nl pa pl pt pt_BR ro ru sa sk sl sr sv sw ta tg th tr uk ur uz vi zh_CN zh_HK zh_TW zu"
+
+inherit qmake-utils l10n xdg-utils
+DESCRIPTION="Lumina desktop environment"
+HOMEPAGE="https://lumina-desktop.org/"
+SRC_URI="https://github.com/trueos/${PN}/archive/v${PV/_/-}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="desktop-utils"
+
+COMMON_DEPEND="dev-qt/qtcore:5
+	dev-qt/qtconcurrent:5
+	dev-qt/qtmultimedia:5[widgets]
+	dev-qt/qtsvg:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtgui:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtdbus:5
+	x11-libs/libxcb:0
+	x11-libs/xcb-util
+	x11-libs/xcb-util-image
+	x11-libs/xcb-util-wm
+	desktop-utils? ( app-text/poppler[qt5] )"
+
+DEPEND="$COMMON_DEPEND
+	dev-qt/linguist-tools:5"
+
+RDEPEND="$COMMON_DEPEND
+	sys-fs/inotify-tools
+	x11-misc/numlockx
+	x11-wm/fluxbox
+	|| ( x11-apps/xbacklight
+		sys-power/acpilight )
+	media-sound/alsa-utils
+	sys-power/acpi
+	app-admin/sysstat"
+
+S="${WORKDIR}/${P/_/-}"
+
+PATCHES=(
+	"${FILESDIR}/1.2.0-desktop-files.patch"
+)
+
+DOCS=( README.md )
+
+src_prepare(){
+	default
+
+	if use !desktop-utils ; then
+		rm -rf src-qt5/desktop-utils || die
+		sed -e "/desktop-utils/d" -i src-qt5/src-qt5.pro || die
+	fi
+
+	l10n_find_plocales_changes "${S}/src-qt5/core/${PN}-desktop/i18n" "${PN}-desktop_" '.ts'
+}
+
+src_configure(){
+	eqmake5 PREFIX="${EPREFIX}/usr" LIBPREFIX="${EPREFIX}/usr/$(get_libdir)" \
+		CONFIG+=WITH_I18N QMAKE_CFLAGS_ISYSTEM=
+}
+
+src_install(){
+	emake install INSTALL_ROOT="${D}"
+	einstalldocs
+	mkdir -p "${D}"/usr/share/icons/hicolor/64x64/apps || die "cannot create the icons dir"
+	mv "${D}"/usr/share/icons/hicolor/scalable/apps/*.png "${D}"/usr/share/icons/hicolor/64x64/apps || die "cannot mv png icons"
+	exeinto /etc/X11/Sessions
+	newexe "${FILESDIR}/lumina-session" lumina ||die
+
+	remove_locale() {
+		rm -f "${ED%/}"/usr/share/${PN}-desktop/i18n/l*_${1}.qm
+
+	}
+	l10n_for_each_disabled_locale_do remove_locale
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+	xdg_icon_cache_update
+}