mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-21 22:47:14 -08:00
dev-python/ruamel-yaml: Bump to 0.17.18
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
@@ -1 +1,2 @@
|
||||
DIST ruamel.yaml-0.17.17.tar.xz 184120 BLAKE2B 05bd1dd719677918a49798f377c5e52bd1b8c7e3bd38a416626330baec90f3e7a71509f236151be73b1773e48ae02d25ac01ef970ebe6cf15ccca49a01a996d1 SHA512 72fbdda33c193dfb556367d79b50e148d2aecd4f2b04cf5b48f2dcf4b690e0796b40273995badec655891408bb8ba6a7e84992e6911e55e75ab453403da3397f
|
||||
DIST ruamel.yaml-0.17.18.tar.xz 184412 BLAKE2B 47fc39b8811b19507a99a88408660ed9eef0182a91cdc86976d04f055361b9cf296e4761433207d47c8343c184c2f6358cb4541af4efce19be6865f492d11939 SHA512 dc11868522904463aba8d7d85e4c44d0d72c6fa84381089647546bde5ab091f733476d04f088611222ad4cac818dbbc7b24c51f721f34d94bdeae82fe0c627ae
|
||||
|
||||
@@ -0,0 +1,47 @@
|
||||
# Copyright 1999-2021 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
PYTHON_COMPAT=( pypy3 python3_{8..10} )
|
||||
inherit distutils-r1
|
||||
|
||||
MY_P="${P/-/.}"
|
||||
DESCRIPTION="YAML parser/emitter that supports roundtrip comment preservation"
|
||||
HOMEPAGE="
|
||||
https://pypi.org/project/ruamel.yaml/
|
||||
https://sourceforge.net/p/ruamel-yaml/"
|
||||
# PyPI tarballs do not include tests
|
||||
SRC_URI="mirror://sourceforge/ruamel-dl-tagged-releases/${MY_P}.tar.xz"
|
||||
S="${WORKDIR}"/${MY_P}
|
||||
|
||||
LICENSE="MIT"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
|
||||
|
||||
RDEPEND="
|
||||
dev-python/namespace-ruamel[${PYTHON_USEDEP}]
|
||||
dev-python/ruamel-yaml-clib[${PYTHON_USEDEP}]"
|
||||
BDEPEND="
|
||||
test? (
|
||||
dev-python/ruamel-std-pathlib[${PYTHON_USEDEP}]
|
||||
)"
|
||||
|
||||
distutils_enable_tests pytest
|
||||
|
||||
# Old PyYAML tests from lib/ require special set-up and are invoked indirectly
|
||||
# via test_z_olddata, tell pytest itself to leave the subdir alone.
|
||||
python_test() {
|
||||
local deselect=()
|
||||
|
||||
[[ ${EPYTHON} == pypy3 ]] && deselect+=(
|
||||
_test/test_deprecation.py::test_collections_deprecation
|
||||
)
|
||||
|
||||
epytest --ignore _test/lib/ ${deselect[@]/#/--deselect }
|
||||
}
|
||||
|
||||
python_install() {
|
||||
distutils-r1_python_install --single-version-externally-managed
|
||||
find "${ED}" -name '*.pth' -delete || die
|
||||
}
|
||||
Reference in New Issue
Block a user