kde-apps/ark: 25.04.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-apps/ark/Manifest

@@ -1 +1,2 @@
 DIST ark-24.12.3.tar.xz 3010672 BLAKE2B 5e38c807d8906455f09532b1c58d491c25a162cbdd907c27c29febfab5b6afe7f1c56d30d6511064004ab7afd7485541da6742ae9b22eb94650bc5d98dd37cc5 SHA512 a3663b22219f0f8f619b10a4c9f676e3a72f5260ecfb45f1068e830b159128ebadf3eb19c6d43bbfb8e02380d0798360089dda61e00fefd29bf3d8318734859a
+DIST ark-25.04.0.tar.xz 3017272 BLAKE2B 0a3e8fcdb493325ca53dc4b9e32ee2491eede64293ba1756f4b923a692e61f8adbf0692eba08bba66c534ba8e39c5eefe70ecd875a1a3946e7ee86188304a014 SHA512 d46a32138d037f982c237a0ec7735ffdda28b01e392fed1f6600ae743221deaa5809653202151b64c11ee0c67527a5d9de5c127d3658b6f036326ceb2a491c5a

kde-apps/ark/ark-25.04.0.ebuild

@@ -0,0 +1,80 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+KFMIN=6.9.0
+QTMIN=6.7.2
+inherit ecm gear.kde.org optfeature xdg
+
+DESCRIPTION="File archiver by KDE"
+HOMEPAGE="https://apps.kde.org/ark/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="zip"
+
+RDEPEND="
+	>=app-arch/libarchive-3.5.3:=[bzip2,lzma]
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,widgets]
+	>=kde-frameworks/kcompletion-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/kfilemetadata-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kjobwidgets-${KFMIN}:6
+	>=kde-frameworks/kparts-${KFMIN}:6
+	>=kde-frameworks/kpty-${KFMIN}:6
+	>=kde-frameworks/kservice-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	sys-libs/zlib
+	zip? ( >=dev-libs/libzip-1.6.0:= )
+"
+DEPEND="${RDEPEND}
+	>=kde-frameworks/kiconthemes-${KFMIN}:6
+	>=dev-qt/qtbase-${QTMIN}:6[concurrent]
+	test? ( >=dev-libs/libzip-1.6.0:= )
+"
+# app-arch/rar is binary only
+BDEPEND="
+	sys-devel/gettext
+	elibc_glibc? ( test? ( amd64? ( app-arch/rar ) x86? ( app-arch/rar ) ) )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package zip LibZip)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	local myctestargs=(
+		# bug 822177: kerfuffle-addtoarchivetest: may segfault or hang indefinitely
+		# bug 827840: plugins-clirartest: continuously broken with translations installed
+		-E "(kerfuffle-addtoarchivetest|plugins-clirartest)"
+	)
+
+	ecm_src_test
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "rar archive creation/extraction" "app-arch/rar"
+		optfeature "rar archive extraction only" "app-arch/unar" "app-arch/unrar"
+		optfeature "7-Zip archive support" "app-arch/p7zip"
+		optfeature "lrz archive support" "app-arch/lrzip"
+		optfeature "Markdown support in text previews" "kde-misc/markdownpart:${SLOT}"
+	fi
+	xdg_pkg_postinst
+}