dev-util/pkgcheck: add 0.10.49

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>
This commit is contained in:
Arthur Zamarin
2026-10-24 22:28:45 +03:00
parent 7ba33a1dfb
commit 4522fc8ea9
2 changed files with 100 additions and 0 deletions
+1
View File
@@ -1,3 +1,4 @@
DIST pkgcheck-0.10.45.tar.gz 442907 BLAKE2B 9ba7a30b878ee9b73390ce7be49d1e7fe805b63c3f4344748389075fcbca4f1091eed2a4cf6695e83ece1e12f178b7553debf9823b348d8c41e94ca9c50b141d SHA512 4cb901058842cba0dcb374e08873a7f48e7325f4ad429060cf1be489b5142a177471f7433f39f088c94ff2d49e16dc06cb74d9586af6dd15d5831e7d91117ff7
DIST pkgcheck-0.10.47.tar.gz 447369 BLAKE2B 73560645d13b03cc04f5b63c9583ce9141ca1b2a8af4444fb03f580ed606281a4830e934aa81a4e1485dc3f464e1f091a7b1d3121fb8e1b49b3296a13af749dc SHA512 52041d9872f918310e0eb705aa874fa95758a131892b295f15fa445b18ba9fef26e13172e83646ded4dad8ca15fab721d68f27ac08d9ad26ad5e3f7357c652aa
DIST pkgcheck-0.10.48.tar.gz 446100 BLAKE2B a66c4be77b574656e881ca3813121294abf5c752c73bcf172f31040723f35c96bb813ac9f2b3545dac90978be8f100dc8ce61bf5c79482fec7b448c1d01db6d3 SHA512 5f7811decc17369ab858ec1cc9fd9062c898b1e51daaae3ee57157049a2fd5d6efa49ce7d8430f2d575c69c7295e46b61ff5d834eccd2e3f3e7fb405eb965982
DIST pkgcheck-0.10.49.tar.gz 448428 BLAKE2B 9fc4ef285610718aa630b638f1d28e0c8577c4bbc67efa318d5512c9b86f79ab6e85be60dbfe4b754e5036481dc25fabf77800e61a3e70c8de268e86d5834359 SHA512 0c5751604294666616166ebba8185b82b434b96c34ba2bfdfdab82bc68b220d5867b6a5dbee2d0f658e4667cbe9b8a2edf778b4f8bd09e8fa6798186532ef3a7
+99
View File
@@ -0,0 +1,99 @@
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=standalone
PYTHON_COMPAT=( python3_{12..15} )
inherit elisp-common distutils-r1 optfeature
if [[ ${PV} == *9999 ]] ; then
EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/pkgcore/pkgcheck.git
https://github.com/pkgcore/pkgcheck.git"
inherit git-r3
else
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
inherit pypi
fi
DESCRIPTION="pkgcore-based QA utility for ebuild repos"
HOMEPAGE="https://github.com/pkgcore/pkgcheck"
LICENSE="BSD MIT"
SLOT="0"
IUSE="emacs"
if [[ ${PV} == *9999 ]]; then
RDEPEND="
~dev-python/snakeoil-9999[${PYTHON_USEDEP}]
~sys-apps/pkgcore-9999[${PYTHON_USEDEP}]"
else
RDEPEND="
>=dev-python/snakeoil-0.11.6[${PYTHON_USEDEP}]
>=sys-apps/pkgcore-0.12.48[${PYTHON_USEDEP}]"
fi
RDEPEND+="
app-arch/zstd
>=dev-libs/tree-sitter-bash-0.25.1[python,${PYTHON_USEDEP}]
dev-python/charset-normalizer[${PYTHON_USEDEP}]
dev-python/lxml[${PYTHON_USEDEP}]
>=dev-python/pathspec-1.0.0[${PYTHON_USEDEP}]
>=dev-python/tree-sitter-0.26.0[${PYTHON_USEDEP}]
emacs? (
>=app-editors/emacs-24.1:*
app-emacs/ebuild-mode
app-emacs/flycheck
)
"
BDEPEND="${RDEPEND}
>=dev-python/flit-core-3.8[${PYTHON_USEDEP}]
test? (
dev-python/pytest[${PYTHON_USEDEP}]
dev-python/requests[${PYTHON_USEDEP}]
dev-vcs/git
)
"
SITEFILE="50${PN}-gentoo.el"
EPYTEST_PLUGINS=( pkgcore )
distutils_enable_tests pytest
src_prepare() {
distutils-r1_src_prepare
# unpin dependencies
sed -i -e 's:~=:>=:' pyproject.toml || die
}
src_compile() {
distutils-r1_src_compile
if use emacs ; then
pushd "${S}"/contrib/emacs >/dev/null || die
elisp-compile *.el
popd >/dev/null || die
fi
}
python_install_all() {
local DOCS=( NEWS.rst )
[[ ${PV} == *9999 ]] || doman build/sphinx/man/*
distutils-r1_python_install_all
if use emacs ; then
elisp-install ${PN} "${S}"/contrib/emacs/*.el{,c}
elisp-site-file-install "${FILESDIR}/${SITEFILE}"
fi
}
pkg_postinst() {
use emacs && elisp-site-regen
optfeature "Network check support" dev-python/requests
optfeature "Perl module version check support" dev-perl/Gentoo-PerlMod-Version
}
pkg_postrm() {
use emacs && elisp-site-regen
}