dev-util/systemtap: make dependency on libvirt explicit

Package-Manager: Portage-2.3.3, Repoman-2.3.1
Closes: gentoo/gentoo#3427

dev-util/systemtap/metadata.xml

@@ -4,4 +4,7 @@
 <maintainer type="person">
   <email>swegener@gentoo.org</email>
 </maintainer>
+  <use>
+    <flag name="libvirt">Support probing of libvirt domains.</flag>
+  </use>
 </pkgmetadata>

dev-util/systemtap/systemtap-3.1-r1.ebuild

@@ -0,0 +1,75 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit linux-info autotools eutils python-single-r1
+
+DESCRIPTION="A linux trace/probe tool"
+HOMEPAGE="http://www.sourceware.org/systemtap/"
+SRC_URI="http://www.sourceware.org/${PN}/ftp/releases/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
+IUSE="libvirt sqlite"
+
+RDEPEND=">=dev-libs/elfutils-0.142
+	sys-libs/libcap
+	${PYTHON_DEPS}
+	libvirt? ( >=app-emulation/libvirt-1.0.2 )
+	sqlite? ( dev-db/sqlite:3 )"
+DEPEND="${RDEPEND}
+	>=sys-devel/gettext-0.18.2"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+CONFIG_CHECK="~KPROBES ~RELAY ~DEBUG_FS"
+ERROR_KPROBES="${PN} requires support for KProbes Instrumentation (KPROBES) - this can be enabled in 'Instrumentation Support -> Kprobes'."
+ERROR_RELAY="${PN} works with support for user space relay support (RELAY) - this can be enabled in 'General setup -> Kernel->user space relay support (formerly relayfs)'."
+ERROR_DEBUG_FS="${PN} works best with support for Debug Filesystem (DEBUG_FS) - this can be enabled in 'Kernel hacking -> Debug Filesystem'."
+
+DOCS="AUTHORS HACKING NEWS README"
+
+pkg_setup() {
+	linux-info_pkg_setup
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	python_fix_shebang .
+
+	sed -i \
+		-e 's:-Werror::g' \
+		configure.ac \
+		Makefile.am \
+		staprun/Makefile.am \
+		stapdyn/Makefile.am \
+		buildrun.cxx \
+		testsuite/systemtap.unprivileged/unprivileged_probes.exp \
+		testsuite/systemtap.unprivileged/unprivileged_myproc.exp \
+		testsuite/systemtap.base/stmt_rel_user.exp \
+		testsuite/systemtap.base/sdt_va_args.exp \
+		testsuite/systemtap.base/sdt_misc.exp \
+		testsuite/systemtap.base/sdt.exp \
+		scripts/kprobes_test/gen_code.py \
+		|| die "Failed to clean up sources"
+
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--docdir="${EPREFIX}/usr/share/doc/${PF}" \
+		--without-rpm \
+		--disable-server \
+		--disable-docs \
+		--disable-refdocs \
+		--disable-grapher \
+		$(use_enable libvirt virt) \
+		$(use_enable sqlite)
+}