gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/hypothesis: Bump to 5.43.3

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2020-12-11 08:09:59 +01:00
parent 0e50d5f2d7
commit 44aee51546
2 changed files with 65 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/hypothesis/Manifest
View File

@@ -6,3 +6,4 @@ DIST hypothesis-python-5.41.5.tar.gz 9098660 BLAKE2B 6caa742d34a3a2aeb6c6fdec3f8
DIST hypothesis-python-5.43.0.tar.gz 9103047 BLAKE2B c9c8262fb32dfdb48b52ad11cd18f907d488802f1af04d7677e260abf24598afd5f89bf3f1a42c919460d5ea48b1d6979da5215ef9877260c601b133076bbd05 SHA512 129760a9c58f264e25c403fcacf9e1ab41267faee637856230341a91d6965a6c2fd05b9a8a12b6977377f8abc26ed7151384ad08195b03ddf62e8445b216eacf
DIST hypothesis-python-5.43.1.tar.gz 9103292 BLAKE2B aa718b98c7a0e16322cbde38f0768e5ccf6716e2cd08aa97b5ed4d36c7ed9565e5ccba76443d74d253adff557918400ec384ee39c630523a31356c80dce15622 SHA512 428a7f1cfb379ebb3d3bea01727ad1633d2e591bea00de15d7967856af8b1aaa9371d278e51be9a0a902adaeff63215a2e87205309f058e371f6ad331737a11f
DIST hypothesis-python-5.43.2.tar.gz 9103806 BLAKE2B 7ef4bfdcd12782a3445d5094ab5111b305743c1c11afd33f3f615e6fd863192cff37c9df7b42052a83d55ee16d570adfb08f1e1c610697f2c2a3295cf09528fa SHA512 c348568f00ce66c6cb53398a7f9b471ffa686cb9c4a4180ac00ba0edae76404c0a7e182f5df8a3c0738b9379f79bfb4b89fdb94bfe3529313a9a3c243a2658ae
DIST hypothesis-python-5.43.3.tar.gz 9103991 BLAKE2B e374edf17571c33e48dc8d259db2fb23b9cc358f56189ebd60f3e9141ade7759eede1bdbd91d924f144a20b1ea0b7ec19817559b7f82a90f026ac101a7feeabd SHA512 392fb794fc5ba06acd1e465cf1500f742d8b056148540778f1ec9c5065be66c0f514f0fa6872337869079636c71235d51d4c6722a63b03037b689edd6f09809f

64
dev-python/hypothesis/hypothesis-5.43.3.ebuild Normal file
View File

@@ -0,0 +1,64 @@
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
DISTUTILS_USE_SETUPTOOLS=rdepend
PYTHON_COMPAT=( python3_{6,7,8,9} pypy3 )
PYTHON_REQ_USE="threads(+),sqlite"
inherit distutils-r1 eutils multiprocessing optfeature
DESCRIPTION="A library for property based testing"
HOMEPAGE="https://github.com/HypothesisWorks/hypothesis https://pypi.org/project/hypothesis/"
SRC_URI="https://github.com/HypothesisWorks/${PN}/archive/${PN}-python-${PV}.tar.gz"
S="${WORKDIR}/${PN}-${PN}-python-${PV}/${PN}-python"
LICENSE="MPL-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
IUSE="cli test"
RESTRICT="!test? ( test )"
RDEPEND="
>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
cli? (
$(python_gen_cond_dep '
dev-python/black[${PYTHON_USEDEP}]
dev-python/click[${PYTHON_USEDEP}]
' python3_{6..9})
)
"
BDEPEND="
test? (
${RDEPEND}
dev-python/mock[${PYTHON_USEDEP}]
dev-python/pexpect[${PYTHON_USEDEP}]
>=dev-python/pytest-5.3.5[${PYTHON_USEDEP}]
dev-python/pytest-xdist[${PYTHON_USEDEP}]
!!<dev-python/typing-3.7.4.1
)
"
python_prepare() {
if ! use cli || [[ ${EPYTHON} != python* ]]; then
sed -i -e '/console_scripts/d' setup.py || die
fi
}
python_test() {
distutils_install_for_testing --via-root
pytest -vv tests/cover tests/pytest tests/quality \
-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")" ||
die "Tests fail with ${EPYTHON}"
}
pkg_postinst() {
optfeature "datetime support" dev-python/pytz
optfeature "dateutil support" dev-python/python-dateutil
optfeature "numpy support" dev-python/numpy
optfeature "django support" dev-python/django dev-python/pytz
optfeature "pandas support" dev-python/pandas
optfeature "pytest support" dev-python/pytest
}