app-backup/dar: add 2.8.5

Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>

app-backup/dar/Manifest

@@ -1 +1,2 @@
 DIST dar-2.8.4.tar.gz 2385736 BLAKE2B ac03cfe081fc127b0d5f46f201e0e6e599b5726ecf4977b6366defee01c03c98331b68443b241d53f2ea19d8a899f33941c7b313bdf8420ac60b0d202e709e04 SHA512 409684e7e4c125556408e989129043be97685945bf3788f4507968309e84feb982d40c8be24127e64b874575d429c5622ae753e905b6202a20c0b424f43eee25
+DIST dar-2.8.5.tar.gz 2392024 BLAKE2B ae6768225373b4e0086bb97b2cca2eff1cc7436f9a40465edfb4416a0deb773a805d13481cec18cd24da50e7698d585a765bcc7e2b8937dd0fd1c6112a801e4f SHA512 642f6f4a1c9bd05521a4c28d4e8c389d0da9ddbc73cfb7062779476a5b7696e4fba1361ab7ff65f61ffa1e198f58eb526eb52e04f148e445b604dce4fc0d49ff

app-backup/dar/dar-2.8.5.ebuild

@@ -0,0 +1,97 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic
+
+DESCRIPTION="A full featured backup tool, aimed for disks"
+HOMEPAGE="http://dar.linux.free.fr/"
+SRC_URI="https://downloads.sourceforge.net/project/dar/dar/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="argon2 curl dar32 dar64 doc gcrypt gpg lz4 lzo nls rsync sftp whirlpool xattr"
+
+REQUIRED_USE="
+	?? ( dar32 dar64 )
+	gpg? ( gcrypt )
+"
+
+RESTRICT="test" # need to be run as root
+
+RDEPEND="
+	app-arch/bzip2:=
+	app-arch/xz-utils
+	app-arch/zstd:=
+	>=dev-libs/libthreadar-1.5.0
+	sys-libs/libcap
+	>=virtual/zlib-1.2.3:=
+	argon2? ( app-crypt/argon2:= )
+	curl? ( net-misc/curl )
+	gcrypt? (
+		dev-libs/libgcrypt:0=
+		dev-libs/libgpg-error
+	)
+	gpg? ( app-crypt/gpgme:= )
+	lz4? ( app-arch/lz4:= )
+	lzo? ( dev-libs/lzo:2 )
+	nls? ( virtual/libintl )
+	rsync? ( net-libs/librsync:= )
+	sftp? ( net-libs/libssh:=[sftp] )
+	whirlpool? ( app-crypt/rhash:= )
+	xattr? ( sys-apps/attr )
+"
+
+DEPEND="${RDEPEND}"
+
+BDEPEND="
+	doc? ( app-text/doxygen )
+	nls? ( sys-devel/gettext )
+"
+# Bug #862025 - upstream has a different numbering scheme for libdar
+QA_PKGCONFIG_VERSION=""
+
+src_configure() {
+	# configure.ac is totally funked up regarding the AC_ARG_ENABLE logic.
+	# For example "--enable-dar-static" causes configure to DISABLE static
+	# builds of dar.
+	# Do _not_ use $(use_enable) until you have verified that the logic has
+	# been fixed by upstream.
+	local myconf=(
+		--disable-dar-static
+		--disable-python-binding
+		--disable-upx
+		$(usev !argon2 --disable-libargon2-linking)
+		$(usev !curl --disable-libcurl-linking)
+		$(usev dar32 --enable-mode=32)
+		$(usev dar64 --enable-mode=64)
+		$(usev !doc --disable-build-html)
+		$(usev !gcrypt --disable-libgcrypt-linking)
+		$(usev !gpg --disable-gpgme-linking)
+		$(usev !lz4 --disable-liblz4-linking)
+		$(usev !lzo --disable-liblzo2-linking)
+		$(usev !nls --disable-nls)
+		$(usev !rsync --disable-librsync-linking)
+		$(usev !sftp --disable-libssh-linking)
+		$(usev !whirlpool --disable-librhash-linking)
+		$(usev !xattr --disable-ea-support)
+	)
+
+	# Bug 103741
+	filter-flags -fomit-frame-pointer
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" pkgdatadir="${EPREFIX}"/usr/share/doc/${PF}/html install
+
+	einstalldocs
+
+	find "${ED}" -name "*.la" -delete || die
+
+	# Bug 729150
+	rm "${ED}/usr/share/doc/${PF}/html/samples/MyBackup.sh.tar.gz" || die
+}